net-misc/kea: Bump to version 1.9.9. Removed old

Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

1 files changed, 71 insertions, 0 deletions

diff --git a/net-misc/kea/kea-1.9.9.ebuild b/net-misc/kea/kea-1.9.9.ebuild
new file mode 100644
index 000000000000..cc899fb2dce2
--- /dev/null
+++ b/net-misc/kea/kea-1.9.9.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PV="${PV//_p/-P}"
+MY_PV="${MY_PV/_/-}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="High-performance production grade DHCPv4 & DHCPv6 server"
+HOMEPAGE="http://www.isc.org/kea/"
+if [[ ${PV} = 9999* ]] ; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://github.com/isc-projects/kea.git"
+else
+	SRC_URI="https://downloads.isc.org/isc/kea/${MY_PV}/${PN}-${MY_PV}.tar.gz"
+	[[ "${PV}" == *_beta* ]] || [[ "${PV}" == *_rc* ]] || \
+		KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="ISC BSD SSLeay GPL-2" # GPL-2 only for init script
+SLOT="0"
+IUSE="mysql +openssl postgres samples"
+
+DEPEND="
+	dev-libs/boost:=
+	dev-cpp/gtest
+	dev-libs/log4cplus
+	mysql? ( dev-db/mysql-connector-c )
+	!openssl? ( dev-libs/botan:2= )
+	openssl? ( dev-libs/openssl:0= )
+	postgres? ( dev-db/postgresql:* )
+"
+RDEPEND="${DEPEND}
+	acct-group/dhcp
+	acct-user/dhcp"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+	[[ ${PV} = *9999 ]] && eautoreconf
+	# Brand the version with Gentoo
+	sed -i \
+		-e "/VERSION=/s:'$: Gentoo-${PR}':" \
+		configure || die
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-static
+		--enable-perfdhcp
+		--localstatedir="${EPREFIX}/var"
+		--without-werror
+		$(use_with mysql)
+		$(use_with openssl)
+		$(use_with postgres pgsql)
+		$(use_enable samples install-configurations)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	newconfd "${FILESDIR}"/${PN}-confd-r1 ${PN}
+	newinitd "${FILESDIR}"/${PN}-initd-r1 ${PN}
+	keepdir /var/lib/${PN} /var/log
+	rm -rf "${ED}"/var/run || die
+	find "${ED}" -type f -name "*.la" -delete || die
+}