net-irc/kvirc: add 5.2.6

Bug: https://bugs.gentoo.org/936931
Closes: https://bugs.gentoo.org/934767
Signed-off-by: Alexey Sokolov <alexey+gentoo@asokolov.org>
Closes: https://github.com/gentoo/gentoo/pull/38964
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

3 files changed, 166 insertions, 16 deletions

diff --git a/net-irc/kvirc/Manifest b/net-irc/kvirc/Manifest
index 670edde31f44..d53c5e1561ed 100644
--- a/net-irc/kvirc/Manifest
+++ b/net-irc/kvirc/Manifest
@@ -1 +1,2 @@
 DIST kvirc-5.2.4.tar.gz 6333384 BLAKE2B e9e85c90cd66bda6b53aac14f807e487c1b65b3a4e463462ea768227a28f774db40e0dce63387aa934b3366db376be945e76682c5a14aae638e4f6470741f5e4 SHA512 7658bdf5258d822164d8b38b6f4baa1814ad49a9ecc7dc0013fc0e9dbd952aca0ba9ab8e90dbcfa0c9db43c756e862989b04cedcfba00f2751371955ffea6503
+DIST kvirc-5.2.6.tar.gz 6336310 BLAKE2B ef86dd65cfb3ffe4de528fcbb0c3a1ce845f7108279d67590699e86a515fd62cfdadce360224020f77e4285c6cfe93897c69ac2d6d23da44be49753e41908e7c SHA512 54c845287d69be0e777a812b47212e061ae74b85c129fe97091ada554a320f4ae6ef65643a2a8238c8f938d1e1d7b02236d76e0950a41e6376288ac1b9070de5
diff --git a/net-irc/kvirc/kvirc-5.2.6.ebuild b/net-irc/kvirc/kvirc-5.2.6.ebuild
new file mode 100644
index 000000000000..2831208694a0
--- /dev/null
+++ b/net-irc/kvirc/kvirc-5.2.6.ebuild
@@ -0,0 +1,151 @@
+# Copyright 2009-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+PYTHON_COMPAT=( python3_{10..13} )
+inherit cmake flag-o-matic python-single-r1 xdg
+
+DESCRIPTION="Advanced IRC Client"
+HOMEPAGE="https://www.kvirc.net/ https://github.com/kvirc/KVIrc"
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/kvirc/KVIrc"
+else
+	SRC_URI="https://github.com/kvirc/KVIrc/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/KVIrc-${PV}"
+	KEYWORDS="~amd64 ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="audiofile +dbus debug doc gsm kde +nls oss +perl profile +python spell +ssl theora webengine"
+REQUIRED_USE="audiofile? ( oss ) python? ( ${PYTHON_REQUIRED_USE} )"
+
+BDEPEND="
+	dev-lang/perl:0
+	virtual/pkgconfig
+	doc? ( app-text/doxygen )
+	kde? ( kde-frameworks/extra-cmake-modules:0 )
+	nls? ( sys-devel/gettext )"
+DEPEND="
+	dev-qt/qtbase:6[concurrent,gui,network,sql,widgets,xml]
+	dev-qt/qtmultimedia:6
+	sys-libs/zlib:0=
+	x11-libs/libX11
+	audiofile? ( media-libs/audiofile )
+	dbus? ( dev-qt/qtbase:6[dbus] )
+	kde? (
+		kde-frameworks/kconfig:6
+		kde-frameworks/kcoreaddons:6
+		kde-frameworks/kio:6
+		kde-frameworks/ki18n:6
+		kde-frameworks/knotifications:6
+		kde-frameworks/kparts:6
+		kde-frameworks/kservice:6
+		kde-frameworks/kstatusnotifieritem:6
+		kde-frameworks/kwindowsystem:6[X]
+		kde-frameworks/kxmlgui:6
+	)
+	perl? ( dev-lang/perl:0= )
+	python? ( ${PYTHON_DEPS} )
+	spell? ( app-text/enchant:2 )
+	ssl? ( dev-libs/openssl:0= )
+	theora? (
+		media-libs/libogg
+		media-libs/libtheora
+		media-libs/libvorbis
+	)
+	webengine? ( dev-qt/qtwebengine:6[widgets] )"
+RDEPEND="${DEPEND}
+	gsm? ( media-sound/gsm )"
+
+DOCS=()
+
+pkg_setup() {
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	if [[ ${PV} == *9999* ]]; then
+		KVIRC_GIT_REVISION="$(git show -s --format=%H)"
+		KVIRC_GIT_SOURCES_DATE="$(git show -s --format=%cd --date=short)"
+		einfo "Setting of revision number to ${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE}"
+		sed -e "/#define KVI_DEFAULT_FRAME_CAPTION/s/KVI_VERSION/& \" (${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE})\"/" \
+			-i src/kvirc/ui/KviMainWindow.cpp || die "Setting of revision number failed"
+	fi
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+
+	local libdir="$(get_libdir)"
+	local mycmakeargs=(
+		-DLIB_SUFFIX=${libdir#lib}
+		-DWANT_ENV_FLAGS=ON
+		-DWANT_VERBOSE=ON
+
+		-DWANT_CRYPT=ON
+		-DWANT_DCC_VOICE=ON
+		-DWANT_IPC=ON
+		-DWANT_IPV6=ON
+		-DWANT_TRANSPARENCY=ON
+
+		-DWANT_AUDIOFILE=$(usex audiofile)
+		-DWANT_DEBUG=$(usex debug)
+		-DWANT_DOXYGEN=$(usex doc)
+		-DWANT_GETTEXT=$(usex nls)
+		-DWANT_GSM=$(usex gsm)
+		-DWANT_KDE=$(usex kde)
+		-DWANT_MEMORY_PROFILE=$(usex profile)
+		-DWANT_OGG_THEORA=$(usex theora)
+		-DWANT_OPENSSL=$(usex ssl)
+		-DWANT_OSS=$(usex oss)
+		-DWANT_PERL=$(usex perl)
+		-DWANT_PYTHON=$(usex python)
+		-DWANT_QTDBUS=$(usex dbus)
+		-DWANT_QTWEBENGINE=$(usex webengine)
+		-DWANT_SPELLCHECKER=$(usex spell)
+		-DQT_VERSION_MAJOR=6
+
+		-DWANT_DCC_VIDEO=OFF
+		-DWANT_PHONON=OFF
+		-DWANT_QTSVG=OFF # COMPILE_SVG_SUPPORT not used in source code.
+	)
+	if use python; then
+		mycmakeargs+=(
+			-DPython3_INCLUDE_DIR="$(python_get_includedir)"
+			-DPython3_LIBRARY="$(python_get_library_path)"
+		)
+	fi
+	if [[ ${PV} == *9999* ]]; then
+		mycmakeargs+=(
+			-DMANUAL_REVISION=${KVIRC_GIT_REVISION}
+			-DMANUAL_SOURCES_DATE=${KVIRC_GIT_SOURCES_DATE//-/}
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	if use doc; then
+		cmake_src_compile devdocs
+	fi
+}
+
+src_install() {
+	cmake_src_install
+
+	if use doc; then
+		docinto html
+		dodoc -r "${BUILD_DIR}/doc/api/html/"*
+	fi
+}
diff --git a/net-irc/kvirc/kvirc-9999.ebuild b/net-irc/kvirc/kvirc-9999.ebuild
index 27dced2fcd5d..2831208694a0 100644
--- a/net-irc/kvirc/kvirc-9999.ebuild
+++ b/net-irc/kvirc/kvirc-9999.ebuild
@@ -2,19 +2,20 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI="8"
-DESCRIPTION="Advanced IRC Client"
-HOMEPAGE="https://www.kvirc.net/ https://github.com/kvirc/KVIrc"
-PYTHON_COMPAT=( python3_{10..12} )
 
+PYTHON_COMPAT=( python3_{10..13} )
 inherit cmake flag-o-matic python-single-r1 xdg
 
-if [[ "${PV}" == "9999" ]]; then
+DESCRIPTION="Advanced IRC Client"
+HOMEPAGE="https://www.kvirc.net/ https://github.com/kvirc/KVIrc"
+
+if [[ ${PV} == *9999* ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/kvirc/KVIrc"
 else
 	SRC_URI="https://github.com/kvirc/KVIrc/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~ppc ~ppc64 ~riscv ~x86"
 	S="${WORKDIR}/KVIrc-${PV}"
+	KEYWORDS="~amd64 ~ppc ~ppc64 ~riscv ~x86"
 fi
 
 LICENSE="GPL-2+"
@@ -44,7 +45,7 @@ DEPEND="
 		kde-frameworks/kparts:6
 		kde-frameworks/kservice:6
 		kde-frameworks/kstatusnotifieritem:6
-		kde-frameworks/kwindowsystem:6
+		kde-frameworks/kwindowsystem:6[X]
 		kde-frameworks/kxmlgui:6
 	)
 	perl? ( dev-lang/perl:0= )
@@ -71,7 +72,7 @@ pkg_setup() {
 src_prepare() {
 	cmake_src_prepare
 
-	if [[ "${PV}" == "9999" ]]; then
+	if [[ ${PV} == *9999* ]]; then
 		KVIRC_GIT_REVISION="$(git show -s --format=%H)"
 		KVIRC_GIT_SOURCES_DATE="$(git show -s --format=%cd --date=short)"
 		einfo "Setting of revision number to ${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE}"
@@ -96,7 +97,6 @@ src_configure() {
 		-DWANT_TRANSPARENCY=ON
 
 		-DWANT_AUDIOFILE=$(usex audiofile)
-		-DWANT_DCC_VIDEO=OFF
 		-DWANT_DEBUG=$(usex debug)
 		-DWANT_DOXYGEN=$(usex doc)
 		-DWANT_GETTEXT=$(usex nls)
@@ -107,15 +107,15 @@ src_configure() {
 		-DWANT_OPENSSL=$(usex ssl)
 		-DWANT_OSS=$(usex oss)
 		-DWANT_PERL=$(usex perl)
-		-DWANT_PHONON=OFF
 		-DWANT_PYTHON=$(usex python)
 		-DWANT_QTDBUS=$(usex dbus)
 		-DWANT_QTWEBENGINE=$(usex webengine)
 		-DWANT_SPELLCHECKER=$(usex spell)
 		-DQT_VERSION_MAJOR=6
 
-		# COMPILE_SVG_SUPPORT not used in source code.
-		-DWANT_QTSVG=OFF
+		-DWANT_DCC_VIDEO=OFF
+		-DWANT_PHONON=OFF
+		-DWANT_QTSVG=OFF # COMPILE_SVG_SUPPORT not used in source code.
 	)
 	if use python; then
 		mycmakeargs+=(
@@ -123,7 +123,7 @@ src_configure() {
 			-DPython3_LIBRARY="$(python_get_library_path)"
 		)
 	fi
-	if [[ "${PV}" == "9999" ]]; then
+	if [[ ${PV} == *9999* ]]; then
 		mycmakeargs+=(
 			-DMANUAL_REVISION=${KVIRC_GIT_REVISION}
 			-DMANUAL_SOURCES_DATE=${KVIRC_GIT_SOURCES_DATE//-/}
@@ -145,9 +145,7 @@ src_install() {
 	cmake_src_install
 
 	if use doc; then
-		(
-			docinto html
-			dodoc -r "${BUILD_DIR}/doc/api/html/"*
-		)
+		docinto html
+		dodoc -r "${BUILD_DIR}/doc/api/html/"*
 	fi
 }