net-analyzer/graphite-web-1.1.10: version bump, support for Python 3.10

Closes: https://bugs.gentoo.org/846107
Signed-off-by: Fabian Groffen <grobian@gentoo.org>

2 files changed, 101 insertions, 0 deletions

diff --git a/net-analyzer/graphite-web/Manifest b/net-analyzer/graphite-web/Manifest
index d34c717db751..28489bc090a5 100644
--- a/net-analyzer/graphite-web/Manifest
+++ b/net-analyzer/graphite-web/Manifest
@@ -1 +1,2 @@
+DIST graphite-web-1.1.10.tar.gz 1192965 BLAKE2B cd60e38a70c124c2be53c12394e994f4772a3fcdbae5fa8f26097e79de3de326ec90d5ee23b4e2e8c696e50d7d7ba897b6bb441a1fc7692d1b6e581c11a3da04 SHA512 fb0a2ed5cfa4a8c12bbb7f64f0c7846b439d8094a0b415e5750fe175bbcc2c047fccad50fdeda7696aee0ed9532eb75948f3a376ee34e188cacf226c02bbb3f9
 DIST graphite-web-1.1.8.tar.gz 1177214 BLAKE2B 20e058feff0fa7f12393cfd41acca7cf05ff6a3995aa5f6547764fae3b8824e8b424efb8d5d47227eb2b5591ae6b45ab960da30f810acb4f1fbd0b9ae78ec47b SHA512 4637a541e61f56c1ac69bf18e7eab88ecf93f59099dc3e8022d8bf8fb1b204672bc0a1b5302e5031701714db17aabb316ba40f4cfabb2bf4fb0dedb8f412e4a9
diff --git a/net-analyzer/graphite-web/graphite-web-1.1.10.ebuild b/net-analyzer/graphite-web/graphite-web-1.1.10.ebuild
new file mode 100644
index 000000000000..ca42298c3bf5
--- /dev/null
+++ b/net-analyzer/graphite-web/graphite-web-1.1.10.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..10} )
+DISTUTILS_USE_SETUPTOOLS=no  # export USE_SETUPTOOLS to activate
+
+inherit distutils-r1 prefix
+
+DESCRIPTION="Enterprise scalable realtime graphing"
+HOMEPAGE="https://graphiteapp.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+carbon ldap mysql memcached postgres +sqlite"
+
+DEPEND=""
+RDEPEND="
+	carbon? ( dev-python/carbon[${PYTHON_USEDEP}] )
+	ldap? ( dev-python/python-ldap[${PYTHON_USEDEP}] )
+	memcached? ( dev-python/python-memcached[${PYTHON_USEDEP}] )
+	mysql? ( dev-python/mysqlclient[${PYTHON_USEDEP}] )
+	postgres? ( dev-python/psycopg:2[${PYTHON_USEDEP}] )
+	>=dev-python/django-1.11.19[sqlite?,${PYTHON_USEDEP}]
+	<dev-python/django-4[sqlite?,${PYTHON_USEDEP}]
+	>=dev-python/django-tagging-0.4.6[${PYTHON_USEDEP}]
+	dev-python/cairocffi[${PYTHON_USEDEP}]
+	dev-python/pyparsing[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+	media-libs/fontconfig
+"
+
+PATCHES=(
+	# Do not install the configuration and data files. We install them
+	# somewhere sensible by hand.
+	"${FILESDIR}"/${PN}-1.1.7-fhs-paths.patch
+)
+
+python_prepare_all() {
+	# Use a less common name
+	mv bin/build-index bin/${PN}-build-index || die
+	# use FHS-style paths
+	export GRAPHITE_NO_PREFIX=yes
+	distutils-r1_python_prepare_all
+	eprefixify \
+		conf/graphite.wsgi.example \
+		webapp/graphite/local_settings.py.example
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	keepdir /var/{lib,log}/${PN}
+	docinto examples
+	docompress -x "/usr/share/doc/${PF}/examples"
+	dodoc \
+		examples/example-graphite-vhost.conf \
+		conf/dashboard.conf.example \
+		conf/graphite.wsgi.example
+}
+
+python_install() {
+	distutils-r1_python_install \
+		--install-data="${EPREFIX}"/usr/share/${PN}
+
+	# copy the file once, to keep the timestamps correct, #808863
+	if [[ ! -e ${ED}/etc/${PN}/local_settings.py ]] ; then
+		insinto /etc/${PN}
+		newins webapp/graphite/local_settings.py.example local_settings.py
+	fi
+	pushd "${D}/$(python_get_sitedir)"/graphite > /dev/null || die
+	ln -s ../../../../../etc/${PN}/local_settings.py local_settings.py || die
+	popd > /dev/null || die
+
+	python_optimize
+}
+
+pkg_config() {
+	"${EROOT}"/usr/bin/django-admin.py migrate \
+		--settings=graphite.settings --run-syncdb
+	"${EROOT}"/usr/bin/${PN}-build-index
+}
+
+pkg_postinst() {
+	# Only display this for new installs
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		elog "You need to configure ${PN} to run with a WSGI server of your choice."
+		elog "For example using Apache, you can use www-apache/mod_wsgi,"
+		elog "            using Nginx, you can use www-servers/uwsgi."
+		elog "Don't forget to edit local_settings.py in ${EPREFIX}/etc/${PN}"
+		elog "See https://graphite.readthedocs.org/en/latest/config-local-settings.html"
+		elog "Run emerge --config =${PN}-${PVR} if this is a fresh install."
+		elog ""
+		elog "If you want to update the search index regularily, you should consider running"
+		elog "the '${PN}-build-index' script in a crontab."
+	fi
+}