media-sound/jack2: sync live

Same as 1.9.21 minus dropping the now-missing tools options.

Closes: https://github.com/gentoo/gentoo/pull/28021
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

1 files changed, 47 insertions, 42 deletions

diff --git a/media-sound/jack2/jack2-9999.ebuild b/media-sound/jack2/jack2-9999.ebuild
index eb214ebbb404..49be304b89f7 100644
--- a/media-sound/jack2/jack2-9999.ebuild
+++ b/media-sound/jack2/jack2-9999.ebuild
@@ -1,97 +1,102 @@
 # Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-PYTHON_COMPAT=( python3_{8,9,10} )
+PYTHON_COMPAT=( python3_{8..11} )
 PYTHON_REQ_USE="threads(+)"
-inherit python-single-r1 waf-utils multilib-minimal
+inherit flag-o-matic python-single-r1 waf-utils multilib-minimal
 
-DESCRIPTION="Jackdmp jack implemention for multi-processor machine"
-HOMEPAGE="https://jackaudio.org/"
-
-if [[ "${PV}" = "9999" ]]; then
+if [[ ${PV} == 9999 ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/jackaudio/${PN}.git"
 else
-	MY_PV="${PV/_rc/-RC}"
-	MY_P="${PN}-${MY_PV}"
-	S="${WORKDIR}/${MY_P}"
-	SRC_URI="https://github.com/jackaudio/jack2/archive/v${MY_PV}/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+	SRC_URI="https://github.com/jackaudio/jack2/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
 	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
 fi
 
-LICENSE="GPL-2"
-SLOT="2"
-IUSE="alsa +classic dbus doc ieee1394 libsamplerate metadata opus pam readline sndfile"
+DESCRIPTION="Jackdmp jack implemention for multi-processor machine"
+HOMEPAGE="https://jackaudio.org/"
 
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="2"
+IUSE="+alsa +classic dbus doc ieee1394 libsamplerate metadata opus pam +tools"
 REQUIRED_USE="
 	${PYTHON_REQUIRED_USE}
 	|| ( classic dbus )"
 
-BDEPEND="
-	virtual/pkgconfig
-	doc? ( app-doc/doxygen )
-"
-DEPEND="${PYTHON_DEPS}
-	media-libs/libsamplerate
-	media-libs/libsndfile
-	sys-libs/readline:0=
+DEPEND="
 	alsa? ( media-libs/alsa-lib[${MULTILIB_USEDEP}] )
 	dbus? (
 		dev-libs/expat[${MULTILIB_USEDEP}]
 		sys-apps/dbus[${MULTILIB_USEDEP}]
 	)
-	ieee1394? ( media-libs/libffado:=[${MULTILIB_USEDEP}] )
-	metadata? ( sys-libs/db:* )
+	libsamplerate? ( media-libs/libsamplerate[${MULTILIB_USEDEP}] )
+	ieee1394? ( media-libs/libffado[${MULTILIB_USEDEP}] )
+	metadata? ( sys-libs/db:=[${MULTILIB_USEDEP}] )
 	opus? ( media-libs/opus[custom-modes,${MULTILIB_USEDEP}] )"
-RDEPEND="${DEPEND}
+RDEPEND="
+	${DEPEND}
 	dbus? (
+		${PYTHON_DEPS}
 		$(python_gen_cond_dep '
 			dev-python/dbus-python[${PYTHON_USEDEP}]
 		')
 	)
 	pam? ( sys-auth/realtime-base )
-	!media-sound/jack-audio-connection-kit:0"
+	!media-sound/jack-audio-connection-kit
+	!media-video/pipewire[jack-sdk(-)]"
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+# tools were formerly provided here, pull to maintain expectations
+PDEPEND="tools? ( media-sound/jack-example-tools )"
 
 DOCS=( AUTHORS.rst ChangeLog.rst README.rst README_NETJACK2 )
 
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.9.21-python3.11.patch
+)
+
 src_prepare() {
 	default
+
 	python_fix_shebang waf
 	multilib_copy_sources
 }
 
 multilib_src_configure() {
-	local mywafconfargs=(
-		--htmldir=/usr/share/doc/${PF}/html
-		$(usex dbus --dbus "")
-		$(usex classic --classic "")
-		--alsa=$(usex alsa yes no)
+	# clients crash if built with lto
+	# https://github.com/jackaudio/jack2/issues/485
+	filter-lto
+
+	local wafargs=(
+		--alsa=$(usex alsa)
 		--celt=no
-		--db=$(usex metadata yes no)
-		--doxygen=$(multilib_native_usex doc yes no)
-		--firewire=$(usex ieee1394 yes no)
+		$(usev classic --classic)
+		--db=$(usex metadata)
+		$(usev dbus --dbus)
+		--doxygen=$(multilib_native_usex doc)
+		--firewire=$(usex ieee1394)
 		--iio=no
-		--opus=$(usex opus yes no)
+		--opus=$(usex opus)
 		--portaudio=no
-		--readline=$(multilib_native_usex readline yes no)
-		--samplerate=$(multilib_native_usex libsamplerate yes no)
-		--sndfile=$(multilib_native_usex sndfile yes no)
+		--samplerate=$(usex libsamplerate)
 		--winmme=no
 	)
 
-	waf-utils_src_configure ${mywafconfargs[@]}
+	waf-utils_src_configure "${wafargs[@]}"
 }
 
 multilib_src_compile() {
-	WAF_BINARY="${BUILD_DIR}"/waf waf-utils_src_compile
+	waf-utils_src_compile
 }
 
 multilib_src_install() {
-	WAF_BINARY="${BUILD_DIR}"/waf waf-utils_src_install
+	waf-utils_src_install
 }
 
 multilib_src_install_all() {
-	python_fix_shebang "${ED}"
+	use dbus && python_fix_shebang "${ED}"/usr/bin/jack_control
 }