media-libs/sdl-image: add 1.2.12_p20220527

Closes: https://bugs.gentoo.org/729554
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/media-libs/sdl-image/Manifest b/media-libs/sdl-image/Manifest
index 681f41c3d6ed..a2cee3b639b3 100644
--- a/media-libs/sdl-image/Manifest
+++ b/media-libs/sdl-image/Manifest
@@ -1 +1,2 @@
 DIST SDL_image-1.2.12_p20210314.tar.gz 10890897 BLAKE2B ddc3e0a49e4ce8fc3c46c5dabe277f9bd2db81f43880aadc8fbd3b6fa09254669fdac90ee4c3c7b92d5c7ec97747944c3953ea2dca065e646416391730cb22dd SHA512 f087472593cbaa9e65c5d643d7801e2ff5e49bee66502d8c094ea18bcd5f66e6da153d39bff7bc81ed20556c909fc4cce279275ff55ee00aebf07d39c27fd543
+DIST sdl-image-1.2.12_p20220527.tar.gz 10888198 BLAKE2B 413e130794ca3c59226e18f4380bc34fb497aadbe01da67ce2c9c76ebbaa5d3e47bad31043d823510ff62ef4bfaa4834d57799b7ea733f11ab66e58b37007583 SHA512 e0a091e1f1a646409c2f636b6e913b6532f31fa498a234fc669dd56b75dda34234818a22d7c3b5385cb50eb3af53316fa2f658a6739b40e4dd5d9513118143c6
diff --git a/media-libs/sdl-image/sdl-image-1.2.12_p20220527.ebuild b/media-libs/sdl-image/sdl-image-1.2.12_p20220527.ebuild
new file mode 100644
index 000000000000..8e95df6875f8
--- /dev/null
+++ b/media-libs/sdl-image/sdl-image-1.2.12_p20220527.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# We may want to grab backports from the SDL-1.2 branch upstream or
+# or take new snapshots every so often as no SDL 1 / 1.2.x releases
+# will be made anymore.
+
+inherit toolchain-funcs multilib-minimal
+
+SDL_IMAGE_COMMIT="633dc522f5114f6d473c910dace62e8ca27a1f7d"
+
+MY_PN=${PN/sdl-/SDL_}
+DESCRIPTION="Image file loading library"
+HOMEPAGE="https://github.com/libsdl-org/SDL_image"
+SRC_URI="https://github.com/libsdl-org/SDL_image/archive/${SDL_IMAGE_COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}"/${MY_PN}-${SDL_IMAGE_COMMIT}
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"
+IUSE="gif jpeg png static-libs tiff webp"
+
+RDEPEND="
+	>=media-libs/libsdl-1.2.15-r4[${MULTILIB_USEDEP}]
+	sys-libs/zlib[${MULTILIB_USEDEP}]
+	png? ( media-libs/libpng[${MULTILIB_USEDEP}] )
+	jpeg? ( media-libs/libjpeg-turbo:=[${MULTILIB_USEDEP}] )
+	tiff? ( media-libs/tiff[${MULTILIB_USEDEP}] )
+	webp? ( media-libs/libwebp:=[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--disable-jpg-shared
+		--disable-png-shared
+		--disable-tif-shared
+		--disable-webp-shared
+		$(use_enable static-libs static)
+		$(use_enable gif)
+		$(use_enable jpeg jpg)
+		$(use_enable tiff tif)
+		$(use_enable png)
+		$(use_enable webp)
+		--enable-bmp
+		--enable-lbm
+		--enable-pcx
+		--enable-pnm
+		--enable-tga
+		--enable-xcf
+		--enable-xpm
+		--enable-xv
+	)
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_compile() {
+	emake OBJC="$(tc-getCC)"
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+	dobin .libs/showimage
+}
+
+multilib_src_install_all() {
+	dodoc CHANGES README
+	use static-libs || find "${ED}" -type f -name "*.la" -delete || die
+}