media-gfx/gimp: drop old 2.10.32-r4, 2.99.14-r3

Signed-off-by: Sergey Torokhov <torokhov-s-a@yandex.ru>
Signed-off-by: Sam James <sam@gentoo.org>

4 files changed, 0 insertions, 484 deletions

diff --git a/media-gfx/gimp/Manifest b/media-gfx/gimp/Manifest
index 78f4652a6f68..c49d93a6a20e 100644
--- a/media-gfx/gimp/Manifest
+++ b/media-gfx/gimp/Manifest
@@ -1,4 +1,2 @@
-DIST gimp-2.10.32.tar.bz2 31397425 BLAKE2B 3887e2e29ebfd5dcfa671a9d1549180d11bd5e3656c6854ff4130c6c6e6ca9479df075981e09b9b6b97e47dd1fcd939fea726ca09c08c040ebd1998d80e61771 SHA512 aa999c1ec388154965f84d995a9b5517e9c38608d03a0d0bb6ec9fa55de946f9da106e7d6f7c02052b61d2b6806e7a378e786539f0de5b5ffaa2fcd1bbd9c7f1
 DIST gimp-2.10.34.tar.bz2 31405329 BLAKE2B 0b2d3a81abf89684bb90e2101896db3479a25c5da76738543dba8d0378e64608eee9aeb24888e15f5e347f72fa1df3e9b82aa27e503ee61d1c4d45d44fa7bddc SHA512 4802ce3758daba868570f1ac97a3f1cb41e1130fcc6376f9bf4c999441f8fd25937aa71b6f726d82d7c780f4153b11d2595bb76bc2356a42266909fbcc0bd34a
-DIST gimp-2.99.14.tar.xz 24346236 BLAKE2B 087e28621c736a6ad8241c0f36334c6c5af53cb945711b089d15b54292ffcb7713be229591b8ccf79d06f7c7ede0919ceecad4deb511b20822a4f68ccfa1df49 SHA512 6ea3ca27cb0c830042ad42789d3017989dda195ebbdff38793afbee720f2986d489bec39c077b84889c847c0afc1bc7a2fec2e916574ae08aec42019715cb204
 DIST gimp-2.99.16.tar.xz 24969172 BLAKE2B 45050c0e45e7c9e64ee92ac9b3985c05f528205f74f442979dee8b326f41b35de403a2de93edad090dd87987ef446531e01a67ca857ef03403414fc9ac1464dd SHA512 b0da0529b000a7309c9d601977518cd19a7bf50ab41952fa36b83c027042d6901c39d0a6870c16e8a8ad3318207c93d34ee3d50d0e5f35bcabeaa17d91e060ee
diff --git a/media-gfx/gimp/files/gimp-2.10_fix_file-dicom-return-value.patch b/media-gfx/gimp/files/gimp-2.10_fix_file-dicom-return-value.patch
deleted file mode 100644
index 8bc50cbcf18e..000000000000
--- a/media-gfx/gimp/files/gimp-2.10_fix_file-dicom-return-value.patch
+++ /dev/null
@@ -1,15 +0,0 @@
-Issue: https://bugs.gentoo.org/875413
-Upstream issue: https://gitlab.gnome.org/GNOME/gimp/-/issues/8807
-Upstream patch: https://gitlab.gnome.org/GNOME/gimp/-/commit/543f9e37e69b4e57b5e44092542c95bb2052f047
-
---- a/plug-ins/common/file-dicom.c
-+++ b/plug-ins/common/file-dicom.c
-@@ -602,7 +602,7 @@ load_image (const gchar  *filename,
-                                (gchar *) value, samples_per_pixel);
-                   g_free (dicominfo);
-                   fclose (DICOM);
--                  return NULL;
-+                  return -1;
-                 }
- 
-               break;
diff --git a/media-gfx/gimp/gimp-2.10.32-r4.ebuild b/media-gfx/gimp/gimp-2.10.32-r4.ebuild
deleted file mode 100644
index b1a59ff2e607..000000000000
--- a/media-gfx/gimp/gimp-2.10.32-r4.ebuild
+++ /dev/null
@@ -1,213 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-GNOME2_EAUTORECONF=yes
-WANT_AUTOMAKE=
-
-inherit autotools gnome2 toolchain-funcs virtualx
-
-DESCRIPTION="GNU Image Manipulation Program"
-HOMEPAGE="https://www.gimp.org/"
-SRC_URI="mirror://gimp/v$(ver_cut 1-2)/${P}.tar.bz2"
-LICENSE="GPL-3+ LGPL-3+"
-SLOT="0/2"
-KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~ia64 ~loong ~ppc ppc64 ~riscv x86"
-
-IUSE="aalib alsa aqua debug doc gnome heif jpeg2k jpegxl mng openexr postscript udev unwind vector-icons webp wmf xpm cpu_flags_ppc_altivec cpu_flags_x86_mmx cpu_flags_x86_sse"
-
-RESTRICT="!test? ( test )"
-
-COMMON_DEPEND="
-	>=app-accessibility/at-spi2-core-2.46.0
-	>=app-text/poppler-0.50[cairo]
-	>=app-text/poppler-data-0.4.7
-	>=dev-libs/glib-2.56.2:2
-	>=dev-libs/json-glib-1.2.6
-	dev-libs/libxml2:2
-	dev-libs/libxslt
-	>=gnome-base/librsvg-2.40.6:2
-	>=media-gfx/mypaint-brushes-2.0.2:=
-	>=media-libs/babl-0.1.90
-	>=media-libs/fontconfig-2.12.4
-	>=media-libs/freetype-2.1.7
-	>=media-libs/gegl-0.4.36:0.4[cairo]
-	>=media-libs/gexiv2-0.10.6
-	>=media-libs/harfbuzz-0.9.19:=
-	>=media-libs/lcms-2.8:2
-	media-libs/libjpeg-turbo:=
-	>=media-libs/libmypaint-1.6.1:=
-	>=media-libs/libpng-1.6.25:0=
-	>=media-libs/tiff-3.5.7:=
-	net-libs/glib-networking[ssl]
-	sys-libs/zlib
-	>=x11-libs/cairo-1.12.2
-	>=x11-libs/gdk-pixbuf-2.31:2
-	>=x11-libs/gtk+-2.24.32:2
-	x11-libs/libXcursor
-	>=x11-libs/pango-1.29.4
-	aalib? ( media-libs/aalib )
-	alsa? ( >=media-libs/alsa-lib-1.0.0 )
-	aqua? ( >=x11-libs/gtk-mac-integration-2.0.0 )
-	heif? ( >=media-libs/libheif-1.9.1:= )
-	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2= )
-	jpegxl? ( >=media-libs/libjxl-0.6.1:= )
-	mng? ( media-libs/libmng:= )
-	openexr? ( >=media-libs/openexr-1.6.1:= )
-	postscript? ( app-text/ghostscript-gpl:= )
-	udev? ( dev-libs/libgudev:= )
-	unwind? ( >=sys-libs/libunwind-1.1.0:= )
-	webp? ( >=media-libs/libwebp-0.6.0:= )
-	wmf? ( >=media-libs/libwmf-0.2.8 )
-	xpm? ( x11-libs/libXpm )
-"
-
-RDEPEND="
-	${COMMON_DEPEND}
-	x11-themes/hicolor-icon-theme
-	gnome? ( gnome-base/gvfs )
-"
-
-DEPEND="
-	${COMMON_DEPEND}
-	>=dev-lang/perl-5.10.0
-	dev-libs/appstream-glib
-	dev-util/gtk-update-icon-cache
-	>=dev-util/intltool-0.40.1
-	>=sys-devel/gettext-0.19
-	>=sys-devel/libtool-2.2
-	virtual/pkgconfig
-"
-
-DOCS=( "AUTHORS" "ChangeLog" "HACKING" "NEWS" "README" "README.i18n" )
-
-PATCHES=(
-	"${FILESDIR}/${PN}-2.10_fix_test-appdata.patch" # Bugs 685210 (and duplicate 691070)
-	"${FILESDIR}/${PN}-2.10_fix_file-dicom-return-value.patch" # Bug 875413 (duplicates 886481, 887587)
-)
-
-src_prepare() {
-	sed -i -e 's/mypaint-brushes-1.0/mypaint-brushes-2.0/' configure.ac || die #737794
-
-	sed -i -e 's/== "xquartz"/= "xquartz"/' configure.ac || die #494864
-	sed 's:-DGIMP_DISABLE_DEPRECATED:-DGIMP_protect_DISABLE_DEPRECATED:g' -i configure.ac || die #615144
-
-	gnome2_src_prepare  # calls eautoreconf
-
-	sed 's:-DGIMP_protect_DISABLE_DEPRECATED:-DGIMP_DISABLE_DEPRECATED:g' -i configure || die #615144
-	grep -F -q GIMP_DISABLE_DEPRECATED configure || die #615144, self-test
-
-	export CC_FOR_BUILD="$(tc-getBUILD_CC)"
-}
-
-_adjust_sandbox() {
-	# Bugs #569738 and #591214
-	local nv
-	for nv in /dev/nvidia-uvm /dev/nvidiactl /dev/nvidia{0..9} ; do
-		# We do not check for existence as they may show up later
-		# https://bugs.gentoo.org/show_bug.cgi?id=569738#c21
-		addwrite "${nv}"
-	done
-
-	addwrite /dev/dri/  # bugs #574038 and #684886
-	addwrite /dev/ati/  # bug #589198
-	addwrite /proc/mtrr  # bug #589198
-}
-
-src_configure() {
-	_adjust_sandbox
-
-	local myconf=(
-		GEGL="${EPREFIX}"/usr/bin/gegl-0.4
-		GDBUS_CODEGEN="${EPREFIX}"/bin/false
-
-		--enable-default-binary
-
-		--disable-check-update
-		--disable-python
-		--enable-mp
-		--with-appdata-test
-		--with-bug-report-url=https://bugs.gentoo.org/
-		--with-xmc
-		--without-libbacktrace
-		--without-webkit
-		--without-xvfb-run
-		$(use_enable cpu_flags_ppc_altivec altivec)
-		$(use_enable cpu_flags_x86_mmx mmx)
-		$(use_enable cpu_flags_x86_sse sse)
-		$(use_enable debug)
-		$(use_enable vector-icons)
-		$(use_with aalib aa)
-		$(use_with alsa)
-		$(use_with !aqua x)
-		$(use_with heif libheif)
-		$(use_with jpeg2k jpeg2000)
-		$(use_with jpegxl)
-		$(use_with mng libmng)
-		$(use_with openexr)
-		$(use_with postscript gs)
-		$(use_with udev gudev)
-		$(use_with unwind libunwind)
-		$(use_with webp)
-		$(use_with wmf)
-		$(use_with xpm libxpm)
-	)
-
-	gnome2_src_configure "${myconf[@]}"
-}
-
-src_compile() {
-	export XDG_DATA_DIRS="${EPREFIX}"/usr/share  # bug 587004
-	gnome2_src_compile
-}
-
-# for https://bugs.gentoo.org/664938
-_rename_plugins() {
-	einfo 'Renaming plug-ins to not collide with pre-2.10.6 file layout (bug #664938)...'
-	local prename=gimp-org-
-	(
-		cd "${ED}"/usr/$(get_libdir)/gimp/2.0/plug-ins || die
-		for plugin_slash in $(ls -d1 */); do
-		    plugin=${plugin_slash%/}
-		    if [[ -f ${plugin}/${plugin} ]]; then
-			# NOTE: Folder and file name need to match for Gimp to load that plug-in
-			#       so "file-svg/file-svg" becomes "${prename}file-svg/${prename}file-svg"
-			mv ${plugin}/{,${prename}}${plugin} || die
-			mv {,${prename}}${plugin} || die
-		    fi
-		done
-	)
-}
-
-src_test() {
-	virtx emake check
-}
-
-src_install() {
-	gnome2_src_install
-
-	# Workaround for bug #321111 to give GIMP the least
-	# precedence on PDF documents by default
-	mv "${ED}"/usr/share/applications/{,zzz-}gimp.desktop || die
-
-	find "${D}" -name '*.la' -type f -delete || die
-
-	# Prevent dead symlink gimp-console.1 from downstream man page compression (bug #433527)
-	local gimp_app_version=$(ver_cut 1-2)
-	mv "${ED}"/usr/share/man/man1/gimp-console{-${gimp_app_version},}.1 || die
-
-	# Remove gimp devel-docs html files if user doesn't need it
-	if ! use doc; then
-		rm -r "${ED}"/usr/share/gtk-doc || die
-	fi
-
-	_rename_plugins || die
-}
-
-pkg_postinst() {
-	gnome2_pkg_postinst
-}
-
-pkg_postrm() {
-	gnome2_pkg_postrm
-}
diff --git a/media-gfx/gimp/gimp-2.99.14-r3.ebuild b/media-gfx/gimp/gimp-2.99.14-r3.ebuild
deleted file mode 100644
index 3b7e1d2a2b7e..000000000000
--- a/media-gfx/gimp/gimp-2.99.14-r3.ebuild
+++ /dev/null
@@ -1,254 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-LUA_COMPAT=( luajit )
-PYTHON_COMPAT=( python3_{9..11} )
-VALA_USE_DEPEND=vapigen
-
-inherit lua-single meson python-single-r1 vala xdg
-
-DESCRIPTION="GNU Image Manipulation Program"
-HOMEPAGE="https://www.gimp.org/"
-SRC_URI="mirror://gimp/v$(ver_cut 1-2)/${P}.tar.xz"
-
-LICENSE="GPL-3+ LGPL-3+"
-SLOT="0/3"
-
-IUSE="X aalib alsa doc gnome heif javascript jpeg2k jpegxl lua mng openexr postscript python test udev unwind vala vector-icons webp wmf xpm"
-REQUIRED_USE="
-	lua? ( ${LUA_REQUIRED_USE} )
-	python? ( ${PYTHON_REQUIRED_USE} )
-"
-
-RESTRICT="!test? ( test )"
-
-# media-libs/{babl,gegl} are required to be built with USE="introspection"
-# to fix the compilation checking of /usr/share/gir-1.0/{Babl-0.1gir,Gegl-0.4.gir}
-COMMON_DEPEND="
-	>=app-accessibility/at-spi2-core-2.46.0
-	>=app-text/poppler-0.90.1[cairo]
-	>=app-text/poppler-data-0.4.9
-	>=dev-libs/appstream-glib-0.7.16
-	>=dev-libs/glib-2.68.0:2
-	>=dev-libs/json-glib-1.4.4
-	dev-libs/libxml2:2
-	dev-libs/libxslt
-	>=gnome-base/librsvg-2.40.21:2
-	>=media-gfx/mypaint-brushes-2.0.2:=
-	>=media-libs/babl-0.1.98[introspection,lcms,vala?]
-	>=media-libs/fontconfig-2.12.6
-	>=media-libs/freetype-2.10.2
-	>=media-libs/gegl-0.4.40:0.4[cairo,introspection,lcms,vala?]
-	>=media-libs/gexiv2-0.14.0
-	>=media-libs/harfbuzz-2.6.5:=
-	>=media-libs/lcms-2.13.1:2
-	media-libs/libjpeg-turbo:=
-	>=media-libs/libmypaint-1.6.1:=
-	>=media-libs/libpng-1.6.37:0=
-	>=media-libs/tiff-4.1.0:=
-	net-libs/glib-networking[ssl]
-	sys-libs/zlib
-	>=x11-libs/cairo-1.16.0
-	>=x11-libs/gdk-pixbuf-2.40.0:2[introspection]
-	>=x11-libs/gtk+-3.24.16:3[introspection]
-	>=x11-libs/pango-1.44.7
-	>=x11-libs/libXmu-1.1.4
-	aalib? ( media-libs/aalib )
-	alsa? ( >=media-libs/alsa-lib-1.0.0 )
-	heif? ( >=media-libs/libheif-1.13.0:= )
-	javascript? ( dev-libs/gjs )
-	jpeg2k? ( >=media-libs/openjpeg-2.3.1:2= )
-	jpegxl? ( >=media-libs/libjxl-0.6.1:= )
-	lua? (
-		${LUA_DEPS}
-		$(lua_gen_cond_dep '
-			dev-lua/lgi[${LUA_USEDEP}]
-		')
-	)
-	mng? ( media-libs/libmng:= )
-	openexr? ( >=media-libs/openexr-2.3.0:= )
-	postscript? ( app-text/ghostscript-gpl:= )
-	python? (
-		${PYTHON_DEPS}
-		$(python_gen_cond_dep '
-			>=dev-python/pygobject-3.0:3[${PYTHON_USEDEP}]
-		')
-	)
-	udev? ( >=dev-libs/libgudev-167:= )
-	unwind? ( >=sys-libs/libunwind-1.1.0:= )
-	webp? ( >=media-libs/libwebp-0.6.0:= )
-	wmf? ( >=media-libs/libwmf-0.2.8 )
-	X? ( x11-libs/libXcursor )
-	xpm? ( x11-libs/libXpm )
-"
-
-RDEPEND="
-	${COMMON_DEPEND}
-	x11-themes/hicolor-icon-theme
-	gnome? ( gnome-base/gvfs )
-"
-
-DEPEND="
-	${COMMON_DEPEND}
-	test? ( x11-misc/xvfb-run )
-	vala? ( $(vala_depend) )
-"
-
-# TODO: there are probably more atoms in DEPEND which should be in BDEPEND now
-BDEPEND="
-	>=dev-lang/perl-5.30.3
-	dev-util/gdbus-codegen
-	>=sys-devel/gettext-0.21
-	doc? (
-		app-text/yelp-tools
-		dev-libs/gobject-introspection[doctool]
-		dev-util/gi-docgen
-	)
-	virtual/pkgconfig
-"
-
-DOCS=( "AUTHORS" "devel-docs/HACKING.md" "NEWS" "README" "README.i18n" )
-
-PATCHES=(
-	"${FILESDIR}/${PN}-2.10_fix_musl_backtrace_backend_switch.patch" #900148
-)
-
-pkg_setup() {
-	use lua && lua-single_pkg_setup
-
-	if use python; then
-		python-single-r1_pkg_setup
-	fi
-}
-
-src_prepare() {
-	default
-
-	sed -i -e 's/mypaint-brushes-1.0/mypaint-brushes-2.0/' meson.build || die #737794
-
-	# Fix Gimp  and GimpUI devel doc installation paths
-	sed -i -e "s/'doc'/'gtk-doc'/" devel-docs/reference/gimp/meson.build || die
-	sed -i -e "s/'doc'/'gtk-doc'/" devel-docs/reference/gimp-ui/meson.build || die
-
-	# Fix pygimp.interp python implementation path.
-	# Meson @PYTHON_PATH@ use sandbox path e.g.:
-	# '/var/tmp/portage/media-gfx/gimp-2.99.12/temp/python3.10/bin/python3'
-	sed -i -e 's/@PYTHON_PATH@/'${EPYTHON}'/' plug-ins/python/pygimp.interp.in || die
-
-	# Set proper intallation path of documentation logo
-	sed -i -e "s/'gimp-@0@'.format(gimp_app_version)/'gimp-${PVR}'/" data/images/meson.build || die
-}
-
-_adjust_sandbox() {
-	# Bugs #569738 and #591214
-	local nv
-	for nv in /dev/nvidia-uvm /dev/nvidiactl /dev/nvidia{0..9} ; do
-		# We do not check for existence as they may show up later
-		# https://bugs.gentoo.org/show_bug.cgi?id=569738#c21
-		addwrite "${nv}"
-	done
-
-	addwrite /dev/dri/  # bugs #574038 and #684886
-	addwrite /dev/ati/  # bug #589198
-	addwrite /proc/mtrr  # bug #589198
-}
-
-src_configure() {
-	_adjust_sandbox
-
-	use vala && vala_setup
-
-	local emesonargs=(
-		-Denable-default-bin=true
-
-		-Dcheck-update=no
-		-Denable-multiproc=true
-		-Dappdata-test=disabled
-		-Dbug-report-url=https://bugs.gentoo.org/
-		-Dlibbacktrace=false
-		-Dwebkit-unmaintained=false
-		$(meson_feature aalib aa)
-		$(meson_feature alsa)
-		$(meson_feature doc gi-docgen)
-		$(meson_feature heif)
-		$(meson_feature jpeg2k jpeg2000)
-		$(meson_feature jpegxl jpeg-xl)
-		$(meson_feature mng)
-		$(meson_feature openexr)
-		$(meson_feature postscript ghostscript)
-		$(meson_feature test headless-tests)
-		$(meson_feature udev gudev)
-		$(meson_feature vala vala-plugins)
-		$(meson_feature webp)
-		$(meson_feature wmf)
-		$(meson_feature X xcursor)
-		$(meson_feature xpm)
-		$(meson_use doc g-ir-doc)
-		$(meson_use javascript)
-		$(meson_use lua)
-		$(meson_use python)
-		$(meson_use unwind libunwind)
-		$(meson_use vector-icons)
-	)
-
-	meson_src_configure
-}
-
-src_compile() {
-	export XDG_DATA_DIRS="${EPREFIX}"/usr/share  # bug 587004
-	meson_src_compile
-}
-
-# for https://bugs.gentoo.org/664938
-_rename_plugins() {
-	einfo 'Renaming plug-ins to not collide with pre-2.10.6 file layout (bug #664938)...'
-	local prename=gimp-org-
-	(
-		cd "${ED}"/usr/$(get_libdir)/gimp/2.99/plug-ins || exit 1
-		for plugin_slash in $(ls -d1 */); do
-			plugin=${plugin_slash%/}
-			if [[ -f ${plugin}/${plugin} ]]; then
-				# NOTE: Folder and file name need to match for Gimp to load that plug-in
-				#       so "file-svg/file-svg" becomes "${prename}file-svg/${prename}file-svg"
-				mv ${plugin}/{,${prename}}${plugin} || exit 1
-				mv {,${prename}}${plugin} || exit 1
-			fi
-		done
-	)
-}
-
-src_install() {
-	meson_src_install
-
-	if use python; then
-		python_optimize
-	fi
-
-	# Workaround for bug #321111 to give GIMP the least
-	# precedence on PDF documents by default
-	mv "${ED}"/usr/share/applications/{,zzz-}gimp.desktop || die
-
-	find "${D}" -name '*.la' -type f -delete || die
-
-	# Prevent dead symlink gimp-console.1 from downstream man page compression (bug #433527)
-	mv "${ED}"/usr/share/man/man1/gimp-console{-*,}.1 || die
-
-	# Create symlinks for Gimp exec in /usr/bin
-	dosym "${ESYSROOT}"/usr/bin/gimp-2.99 /usr/bin/gimp
-	dosym "${ESYSROOT}"/usr/bin/gimp-console-2.99 /usr/bin/gimp-console
-	dosym "${ESYSROOT}"/usr/bin/gimp-script-fu-interpreter-3.0 /usr/bin/gimp-script-fu-interpreter
-	dosym "${ESYSROOT}"/usr/bin/gimp-test-clipboard-2.99 /usr/bin/gimp-test-clipboard
-	dosym "${ESYSROOT}"/usr/bin/gimptool-2.99 /usr/bin/gimptool
-
-	_rename_plugins || die
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-}
-
-pkg_postrm() {
-	xdg_pkg_postrm
-}