media-gfx/sane-airscan: new ebuild

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Jason A. Donenfeld <zx2c4@gentoo.org>

1 files changed, 43 insertions, 0 deletions

diff --git a/media-gfx/sane-airscan/sane-airscan-0.99.27.ebuild b/media-gfx/sane-airscan/sane-airscan-0.99.27.ebuild
new file mode 100644
index 000000000000..f1d4d9176344
--- /dev/null
+++ b/media-gfx/sane-airscan/sane-airscan-0.99.27.ebuild
@@ -0,0 +1,43 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="SANE backend for AirScan (eSCL) and WSD document scanners"
+HOMEPAGE="https://github.com/alexpevzner/sane-airscan"
+SRC_URI="https://github.com/alexpevzner/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	net-dns/avahi
+	net-libs/gnutls
+	dev-libs/libxml2
+	virtual/jpeg
+	media-libs/libpng
+"
+RDEPEND="${DEPEND}
+	media-gfx/sane-backends
+"
+
+src_prepare() {
+	default
+	sed -i 's/ar cru/$(AR) cru/' Makefile || die "Unable to patch makefile"
+}
+
+src_compile() {
+	emake \
+		CFLAGS="${CFLAGS}" \
+		CPPFLAGS="${CPPFLAGS}" \
+		LDFLAGS="${LDFLAGS}" \
+		CC="$(tc-getCC)" \
+		AR="$(tc-getAR)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" COMPRESS= STRIP= install
+}