media-gfx/gthumb: bump to 3.10.0

Bug: https://bugs.gentoo.org/712932
Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

2 files changed, 90 insertions, 0 deletions

diff --git a/media-gfx/gthumb/Manifest b/media-gfx/gthumb/Manifest
index 1e06d2b3619a..5d943f080fff 100644
--- a/media-gfx/gthumb/Manifest
+++ b/media-gfx/gthumb/Manifest
@@ -1 +1,2 @@
+DIST gthumb-3.10.0.tar.xz 7550040 BLAKE2B 183ffa4c567728375c34a3f84c72d44f266a893fa8d4be7b8270faa2a120bf2e6c61d5e35494aa5e4d4e14366017adbb020f7a3dc8c51b6f012e8f18cee1a72f SHA512 d7bcac6b260bf7d5816af69ea89953517cbc43ea289227ccceebd0700b753a7d97349e6a30ec6bbb42690c56abff5b69dc3fc073f1ee2831ae1aa7d220722efd
 DIST gthumb-3.6.2.tar.xz 3423044 BLAKE2B ff5fd805c07c969f8e50960cdd36df9b3ef9ddedcaca66578416fc4f602fedf4f1698fec54cda77521c88774e8e309b996123ade9a633df1ffc34bb60cef0ff5 SHA512 5fc5cc43b16b51438403fbb986286d5e66575162be7b4cf35931dd0c41273933f78c210aaf2379e0a2574df6f7f7b2d532d87ce37fbc6369b65331bac338a454
diff --git a/media-gfx/gthumb/gthumb-3.10.0.ebuild b/media-gfx/gthumb/gthumb-3.10.0.ebuild
new file mode 100644
index 000000000000..92fddec51aa5
--- /dev/null
+++ b/media-gfx/gthumb/gthumb-3.10.0.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Image viewer and browser for Gnome"
+HOMEPAGE="https://wiki.gnome.org/Apps/gthumb"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="cdr colord exif gnome-keyring gstreamer http lcms raw slideshow svg tiff webp"
+
+RDEPEND="
+	>=dev-libs/glib-2.54.0:2
+	>=x11-libs/gtk+-3.16.0:3
+	exif? ( >=media-gfx/exiv2-0.21:= )
+	slideshow? (
+		>=media-libs/clutter-1.12.0:1.0
+		>=media-libs/clutter-gtk-1:1.0 )
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		media-plugins/gst-plugins-gtk:1.0 )
+	raw? ( >=media-libs/libraw-0.14:= )
+	http? ( >=net-libs/libsoup-2.42.0:2.4
+		>=dev-libs/json-glib-0.15.0
+		>=net-libs/webkit-gtk-1.10.0:4 )
+	gnome-keyring? ( >=app-crypt/libsecret-0.11 )
+	cdr? ( >=app-cdr/brasero-3.2.0 )
+	svg? ( >=gnome-base/librsvg-2.34:2 )
+	webp? ( >=media-libs/libwebp-0.2.0:= )
+	lcms? ( >=media-libs/lcms-2.6:2 )
+	colord? ( >=x11-misc/colord-1.3
+		>=media-libs/lcms-2.6:2 )
+
+	sys-libs/zlib
+	virtual/jpeg:0=
+	tiff? ( media-libs/tiff:= )
+	media-libs/libpng:0=
+	>=gnome-base/gsettings-desktop-schemas-0.1.4
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	dev-util/itstool
+	sys-devel/bison
+	sys-devel/flex
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		-Drun-in-place=false
+		$(meson_use exif exiv2)
+		$(meson_use slideshow clutter)
+		$(meson_use gstreamer)
+		-Dlibchamplain=false # Upstream still doesn't seem to consider this ready
+		$(meson_use colord)
+		$(meson_use tiff libtiff)
+		$(meson_use webp libwebp)
+		$(meson_use raw libraw)
+		$(meson_use svg librsvg)
+		$(meson_use gnome-keyring libsecret)
+		$(meson_use http webservices)
+		$(meson_use cdr libbrasero)
+	)
+
+	# colord pulls in lcms2 anyway, so enable lcms with USE="colord -lcms"; some of upstream HAVE_COLORD code depends on HAVE_LCMS2
+	if use lcms || use colord; then
+		emesonargs+=( -Dlcms2=true )
+	else
+		emesonargs+=( -Dlcms2=false )
+	fi
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}