media-gfx/exiv2: drop 0.27.7, 0.28.1-r1

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

3 files changed, 0 insertions, 246 deletions

diff --git a/media-gfx/exiv2/Manifest b/media-gfx/exiv2/Manifest
index 1f7d36da6fde..e718292d55e6 100644
--- a/media-gfx/exiv2/Manifest
+++ b/media-gfx/exiv2/Manifest
@@ -1,2 +1 @@
-DIST exiv2-0.27.7-Source.tar.gz 32290404 BLAKE2B ac83c36dd15c7f6aa2d6607542a12b981d1b58bed671047d3dbfdc9eea64a977630863e4c4abe1e9c2e3e8af05adf6849a05d70e42cde4bb0d6f4a3fbb9b2e49 SHA512 8f12b056439867a05b6dfe4b93a82e02d9e5032554b590e399bcf38d73208a783f8349e66870cc030ad2a47650389d96522b60086b308145121646c9fa93d8ae
 DIST exiv2-0.28.1.tar.gz 45225200 BLAKE2B a26f8e54cf6284c56ff429c13d5a8985dc6181a36b4c13ea6f2e59bc00016a2a8d915ddbc0cedb441b8283e30f18312a500900ffd89ca984006ac84807a03852 SHA512 7b872a3c0cbe343014b1ca4618cecaf6ee8d78dec7ef83accfce95cb8eadc6b52116977a41e1f1be5c6149a47bdd9457fadc08d73708aa2a6ab69795fd3de23b
diff --git a/media-gfx/exiv2/exiv2-0.27.7.ebuild b/media-gfx/exiv2/exiv2-0.27.7.ebuild
deleted file mode 100644
index 8f4d81ffa87d..000000000000
--- a/media-gfx/exiv2/exiv2-0.27.7.ebuild
+++ /dev/null
@@ -1,113 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-if [[ ${PV} = *9999* ]]; then
-	EGIT_REPO_URI="https://github.com/Exiv2/exiv2.git"
-	inherit git-r3
-else
-	SRC_URI="https://github.com/${PN^}/${PN}/releases/download/v${PV}/${P}-Source.tar.gz"
-	KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~x64-solaris"
-	S="${WORKDIR}/${P}-Source"
-fi
-
-PYTHON_COMPAT=( python3_{10..11} )
-inherit cmake-multilib python-any-r1
-
-DESCRIPTION="EXIF, IPTC and XMP metadata C++ library and command line utility"
-HOMEPAGE="https://exiv2.org/"
-
-LICENSE="GPL-2"
-# In 0.27.5, ABI seemed to be broken for bmff functions
-SLOT="0/27.5"
-IUSE="+bmff doc examples nls +png test webready +xmp"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	>=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]
-	nls? ( >=virtual/libintl-0-r1[${MULTILIB_USEDEP}] )
-	png? ( sys-libs/zlib[${MULTILIB_USEDEP}] )
-	webready? (
-		>net-libs/libssh-0.9.1[sftp,${MULTILIB_USEDEP}]
-		net-misc/curl[${MULTILIB_USEDEP}]
-	)
-	xmp? ( dev-libs/expat[${MULTILIB_USEDEP}] )
-"
-DEPEND="${DEPEND}
-	test? ( dev-cpp/gtest )
-"
-BDEPEND="
-	doc? (
-		${PYTHON_DEPS}
-		app-text/doxygen
-		dev-libs/libxslt
-		media-gfx/graphviz
-		virtual/pkgconfig
-	)
-	nls? ( sys-devel/gettext )
-"
-
-DOCS=( README.md doc/ChangeLog doc/cmd.txt )
-
-pkg_setup() {
-	use doc && python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	# FIXME @upstream:
-	einfo "Converting doc/cmd.txt to UTF-8"
-	iconv -f LATIN1 -t UTF-8 doc/cmd.txt > doc/cmd.txt.tmp || die
-	mv -f doc/cmd.txt.tmp doc/cmd.txt || die
-
-	cmake_src_prepare
-
-	sed -e "/^include.*compilerFlags/s/^/#DONT /" -i CMakeLists.txt || die
-}
-
-multilib_src_configure() {
-	local mycmakeargs=(
-		-DCMAKE_CXX_STANDARD=14
-		-DEXIV2_BUILD_SAMPLES=NO
-		-DEXIV2_ENABLE_NLS=$(usex nls)
-		-DEXIV2_ENABLE_PNG=$(usex png)
-		-DEXIV2_ENABLE_CURL=$(usex webready)
-		-DEXIV2_ENABLE_SSH=$(usex webready)
-		-DEXIV2_ENABLE_WEBREADY=$(usex webready)
-		-DEXIV2_ENABLE_XMP=$(usex xmp)
-		-DEXIV2_ENABLE_BMFF=$(usex bmff)
-		$(multilib_is_native_abi || echo -DEXIV2_BUILD_EXIV2_COMMAND=NO)
-		$(multilib_is_native_abi && echo -DEXIV2_BUILD_DOC=$(usex doc))
-		$(multilib_is_native_abi && echo -DEXIV2_BUILD_UNIT_TESTS=$(usex test))
-		-DCMAKE_INSTALL_DOCDIR="${EPREFIX}"/usr/share/doc/${PF}/html
-	)
-
-	cmake_src_configure
-}
-
-multilib_src_compile() {
-	cmake_src_compile
-
-	if multilib_is_native_abi; then
-		use doc && eninja doc
-	fi
-}
-
-multilib_src_test() {
-	if multilib_is_native_abi; then
-		cd "${BUILD_DIR}"/bin || die
-		./unit_tests || die "Failed to run tests"
-	fi
-}
-
-multilib_src_install_all() {
-	use xmp && DOCS+=( doc/{COPYING-XMPSDK,README-XMP,cmdxmp.txt} )
-
-	einstalldocs
-	find "${D}" -name '*.la' -delete || die
-
-	if use examples; then
-		docinto examples
-		dodoc samples/*.cpp
-	fi
-}
diff --git a/media-gfx/exiv2/exiv2-0.28.1-r1.ebuild b/media-gfx/exiv2/exiv2-0.28.1-r1.ebuild
deleted file mode 100644
index 2543df2e47d4..000000000000
--- a/media-gfx/exiv2/exiv2-0.28.1-r1.ebuild
+++ /dev/null
@@ -1,132 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{10..11} )
-inherit cmake-multilib python-any-r1
-
-DESCRIPTION="EXIF, IPTC and XMP metadata C++ library and command line utility"
-HOMEPAGE="https://exiv2.org/"
-
-if [[ ${PV} == *9999* ]]; then
-	EGIT_REPO_URI="https://github.com/Exiv2/exiv2.git"
-	inherit git-r3
-else
-	SRC_URI="https://github.com/Exiv2/exiv2/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~x64-solaris"
-fi
-
-LICENSE="GPL-2"
-# Upstream hope to have stable ABI in 1.0. Until then, go off ${PV}.
-# We may be able to change it to $(ver_cut 1-2) once e.g.
-# https://github.com/Exiv2/exiv2/pull/917 is merged.
-SLOT="0/$(ver_cut 1-2)"
-IUSE="+bmff doc examples nls +png test webready +xmp"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	>=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]
-	nls? ( >=virtual/libintl-0-r1[${MULTILIB_USEDEP}] )
-	png? ( sys-libs/zlib[${MULTILIB_USEDEP}] )
-	webready? (
-		net-misc/curl[${MULTILIB_USEDEP}]
-	)
-	xmp? ( dev-libs/expat[${MULTILIB_USEDEP}] )
-"
-DEPEND="
-	${DEPEND}
-	test? ( dev-cpp/gtest )
-"
-BDEPEND="
-	doc? (
-		${PYTHON_DEPS}
-		app-text/doxygen
-		dev-libs/libxslt
-		media-gfx/graphviz
-		virtual/pkgconfig
-	)
-	test? ( ${PYTHON_DEPS} )
-	nls? ( sys-devel/gettext )
-"
-
-DOCS=( README.md doc/ChangeLog doc/cmd.txt )
-
-# https://github.com/Exiv2/exiv2/pull/2832
-PATCHES=( "${FILESDIR}/${P}-exiv2lib.patch" ) # bug 917483
-
-pkg_setup() {
-	if use doc || use test ; then
-		python-any-r1_pkg_setup
-	fi
-}
-
-src_prepare() {
-	# FIXME @upstream:
-	einfo "Converting doc/cmd.txt to UTF-8"
-	iconv -f LATIN1 -t UTF-8 doc/cmd.txt > doc/cmd.txt.tmp || die
-	mv -f doc/cmd.txt.tmp doc/cmd.txt || die
-
-	cmake_src_prepare
-
-	sed -e "/^include.*compilerFlags/s/^/#DONT /" -i CMakeLists.txt || die
-}
-
-multilib_src_configure() {
-	local mycmakeargs=(
-		-DEXIV2_BUILD_SAMPLES=NO
-		-DEXIV2_ENABLE_BROTLI=OFF
-		-DEXIV2_ENABLE_NLS=$(usex nls)
-		-DEXIV2_ENABLE_PNG=$(usex png)
-		-DEXIV2_ENABLE_CURL=$(usex webready)
-		-DEXIV2_ENABLE_INIH=OFF # multilib/libdir logic is broken
-		-DEXIV2_ENABLE_WEBREADY=$(usex webready)
-		-DEXIV2_ENABLE_XMP=$(usex xmp)
-		-DEXIV2_ENABLE_BMFF=$(usex bmff)
-
-		# We let users control this.
-		-DBUILD_WITH_CCACHE=OFF
-		# Our toolchain sets this by default.
-		-DBUILD_WITH_STACK_PROTECTOR=OFF
-
-		$(multilib_is_native_abi || echo -DEXIV2_BUILD_EXIV2_COMMAND=NO)
-		$(multilib_is_native_abi && echo -DEXIV2_BUILD_DOC=$(usex doc))
-		$(multilib_is_native_abi && echo -DEXIV2_BUILD_UNIT_TESTS=$(usex test))
-		-DCMAKE_INSTALL_DOCDIR="${EPREFIX}"/usr/share/doc/${PF}/html
-	)
-
-	if use doc || use test ; then
-		mycmakeargs+=(
-			-DPython3_EXECUTABLE="${PYTHON}"
-		)
-	fi
-
-	cmake_src_configure
-}
-
-multilib_src_compile() {
-	cmake_src_compile
-
-	if multilib_is_native_abi; then
-		use doc && eninja doc
-	fi
-}
-
-multilib_src_test() {
-	if multilib_is_native_abi; then
-		cd "${BUILD_DIR}"/bin || die
-		./unit_tests || die "Failed to run tests"
-	fi
-}
-
-multilib_src_install_all() {
-	use xmp && DOCS+=( doc/{COPYING-XMPSDK,README-XMP,cmdxmp.txt} )
-
-	einstalldocs
-	find "${D}" -name '*.la' -delete || die
-
-	if use examples; then
-		docinto examples
-		dodoc samples/*.cpp
-	fi
-}