media-fonts/liberation-fonts: Version bump to 2.1.5

Signed-off-by: Matt Turner <mattst88@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/media-fonts/liberation-fonts/liberation-fonts-2.1.5.ebuild b/media-fonts/liberation-fonts/liberation-fonts-2.1.5.ebuild
new file mode 100644
index 000000000000..744f8cb7d675
--- /dev/null
+++ b/media-fonts/liberation-fonts/liberation-fonts-2.1.5.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit font python-any-r1
+
+DESCRIPTION="A Helvetica/Times/Courier replacement TrueType font set, courtesy of Red Hat"
+HOMEPAGE="https://github.com/liberationfonts/liberation-fonts"
+SRC_URI="fontforge? ( https://github.com/liberationfonts/liberation-fonts/files/7261483/${P}.tar.gz )
+	!fontforge? ( https://github.com/liberationfonts/liberation-fonts/files/7261482/${PN}-ttf-${PV}.tar.gz )
+"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~x64-solaris"
+SLOT="0"
+LICENSE="OFL-1.1"
+IUSE="fontforge X"
+
+FONT_SUFFIX="ttf"
+
+FONT_CONF=( "${FILESDIR}/60-liberation.conf" )
+
+BDEPEND="
+	fontforge? (
+		${PYTHON_DEPS}
+		media-gfx/fontforge
+		$(python_gen_any_dep 'dev-python/fonttools[${PYTHON_USEDEP}]')
+	)"
+
+python_check_deps() {
+	python_has_version "dev-python/fonttools[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	default
+	if use fontforge ; then
+		sed -i "s/= python3/= ${EPYTHON}/" Makefile || die
+	fi
+}
+
+pkg_setup() {
+	if use fontforge; then
+		FONT_S="${S}/${PN}-ttf-${PV}"
+		python-any-r1_pkg_setup
+	else
+		FONT_S="${WORKDIR}/${PN}-ttf-${PV}"
+		S="${FONT_S}"
+	fi
+	font_pkg_setup
+}