kde-plasma/plasma-firewall: 5.25.5 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 64 insertions, 0 deletions

diff --git a/kde-plasma/plasma-firewall/Manifest b/kde-plasma/plasma-firewall/Manifest
index ff486ac6b0fc..5eedf144ed5b 100644
--- a/kde-plasma/plasma-firewall/Manifest
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -1,2 +1,3 @@
 DIST plasma-firewall-5.24.6.tar.xz 346668 BLAKE2B 857b90f383798961d32d9a65f65cec4f7b45dc17c56966bbe71ee4068c8bbadee941d0ce2a439dc99ec3a9327d5d1d4189d327a820ab618818090ff7661d4865 SHA512 b75442205d1b2eed986794ff6ea233e31e904de36e8acabc7ef2da83b94fdebcaf6a0fa26d5b0393921e9b0acc6d62bbd71f711e13f3e6ba455710970e5af26f
 DIST plasma-firewall-5.25.4.tar.xz 357344 BLAKE2B 47ad810ab97cff60ae410ca1b0e835a37f6c3323bbe4bc9283787f2b9df8630f08d251e073014aa79efc73b21a5ee129baf06d18dc615df61f7ef88e9b9fc5b6 SHA512 d4f28c577b54d3c4041a98acad7f7e98f8edce61b548cf96a0e034432c49da3f7431555c142e420103a910452e9230876c2fcddd52976d24c6a197d8fbfe5839
+DIST plasma-firewall-5.25.5.tar.xz 357380 BLAKE2B 37dcd280306a4b7674a78ce8a74f01ea804a136174725d228370427567b851dff6eeed01aaa687014d565c19694908f0f9aba4f811da8c7d8d2208b6d0250581 SHA512 b6059e732f34af49263ff0beecb9f11894420166a60ef0ebdce38fff9bb472c1c6d058f4ae6d3cae8194c5b6efe127971e6057564e887317250a4691df73e1e0
diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.25.5.ebuild b/kde-plasma/plasma-firewall/plasma-firewall-5.25.5.ebuild
new file mode 100644
index 000000000000..0161118e86d2
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.25.5.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+KFMIN=5.95.0
+QTMIN=5.15.5
+inherit ecm plasma.kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	firewalld? ( net-firewall/firewalld )
+	ufw? ( net-firewall/ufw )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# this kind of cmake magic doesn't work for us at all.
+	sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
+		-i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+		-DBUILD_UFW_BACKEND=$(usex ufw)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	if ! has_version sys-apps/systemd; then
+		ewarn "${PN} is not functional without sys-apps/systemd at this point."
+		ewarn "See also: https://bugs.gentoo.org/778527"
+	fi
+}