gnome-base/gnome-desktop: Version bump to 43.2

Signed-off-by: Matt Turner <mattst88@gentoo.org>

3 files changed, 142 insertions, 0 deletions

diff --git a/gnome-base/gnome-desktop/Manifest b/gnome-base/gnome-desktop/Manifest
index 9abc3f34ff6a..7c44df11e185 100644
--- a/gnome-base/gnome-desktop/Manifest
+++ b/gnome-base/gnome-desktop/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-desktop-43.1.tar.xz 764876 BLAKE2B b7f19a14e69450fc7cf9e0fe404cc0b78c5478d58b4f278b4c2eaeb20d8a43103c07458a68836d912a9576c2819790cd84002e196c2f1dbc4b5db0f34914cc2c SHA512 6b6c9597629ec32453ba1823a3508616a951c0274400e4814cd5b39438ee2c752842cbd37a8dc4f19e9a667a7f171546895ebb15a2a79802171466e395e9b3a4
+DIST gnome-desktop-43.2.tar.xz 765508 BLAKE2B db54a18cace207e0044e35fa95cf149a51f6948c77db27963503fc1aa4aa3ec6d32da0dd517b83abfae770f81bab72e930d36e1de80ef5aa6bee1fa55f3aa7e9 SHA512 b1a84f75dd793ad856a4f4995cc2d87a5ed91e1bb498229587defb139b8b988b1087610026576c34a51f1f9439ae36efa01544857deed1c8b6ec25cd68f0bc30
 DIST gnome-desktop-43.tar.xz 764256 BLAKE2B 68e13477034bb16d1c8dbe22ae940bb6711c53f93230b93ac4b6be3e61a1b60f223c9177ab004d6cd0876feecb1a71d922779f9901f914359e7aac1650a55363 SHA512 01244bf397d8ef4d9424ef9289789efde148c38f4588fe3a9094cbdd4612c56fbbff079182d6c85083462d2f3ae9771e463c5cb86995a1aef29b2f5cfd023713
diff --git a/gnome-base/gnome-desktop/gnome-desktop-43.2-r300.ebuild b/gnome-base/gnome-desktop/gnome-desktop-43.2-r300.ebuild
new file mode 100644
index 000000000000..799b1e12fe58
--- /dev/null
+++ b/gnome-base/gnome-desktop/gnome-desktop-43.2-r300.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome.org meson xdg
+
+DESCRIPTION="Library with common API for various GNOME modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-desktop/"
+
+LICENSE="GPL-2+ LGPL-2+ FDL-1.1+"
+SLOT="3/20" # subslot = libgnome-desktop-3 soname version
+IUSE="debug +introspection seccomp systemd udev"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+COMMON_DEPEND="
+	>=x11-libs/gdk-pixbuf-2.36.5:2[introspection?]
+	>=x11-libs/gtk+-3.3.6:3[introspection?]
+	>=dev-libs/glib-2.53.0:2
+	>=gnome-base/gsettings-desktop-schemas-3.27.0[introspection?]
+	x11-misc/xkeyboard-config
+	x11-libs/libxkbcommon
+	app-text/iso-codes
+	systemd? ( sys-apps/systemd:= )
+	udev? ( virtual/libudev:= )
+	seccomp? ( sys-libs/libseccomp )
+
+	x11-libs/cairo:=
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${COMMON_DEPEND}
+	media-libs/fontconfig
+"
+RDEPEND="${COMMON_DEPEND}
+	seccomp? ( sys-apps/bubblewrap )
+	!<gnome-base/gnome-desktop-${PV}:4
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	# Don't build manual test programs that will never get run
+	sed -i -e "/'test-.*'/d" libgnome-desktop/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddesktop_docs=false
+		$(meson_use debug debug_tools)
+		$(meson_use introspection)
+		$(meson_feature udev)
+		$(meson_feature systemd)
+		-Dgtk_doc=false
+		-Dinstalled_tests=false
+		-Dbuild_gtk4=false
+		-Dlegacy_library=true
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	rm -r \
+		"${ED}"/usr/share/locale \
+		|| die
+}
diff --git a/gnome-base/gnome-desktop/gnome-desktop-43.2-r400.ebuild b/gnome-base/gnome-desktop/gnome-desktop-43.2-r400.ebuild
new file mode 100644
index 000000000000..4d067f32db74
--- /dev/null
+++ b/gnome-base/gnome-desktop/gnome-desktop-43.2-r400.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome.org meson xdg
+
+DESCRIPTION="Library with common API for various GNOME modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-desktop/"
+
+LICENSE="GPL-2+ LGPL-2+ FDL-1.1+"
+SLOT="4/2" # subslot = libgnome-desktop-4 soname version
+IUSE="debug gtk-doc seccomp systemd udev"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+COMMON_DEPEND="
+	>=x11-libs/gdk-pixbuf-2.36.5:2[introspection]
+	>=gui-libs/gtk-4.4.0:4[introspection]
+	>=dev-libs/glib-2.53.0:2
+	>=gnome-base/gsettings-desktop-schemas-3.27.0[introspection]
+	x11-misc/xkeyboard-config
+	x11-libs/libxkbcommon
+	app-text/iso-codes
+	systemd? ( sys-apps/systemd:= )
+	udev? ( virtual/libudev:= )
+	seccomp? ( sys-libs/libseccomp )
+
+	x11-libs/cairo:=
+	>=dev-libs/gobject-introspection-1.54:=
+"
+DEPEND="${COMMON_DEPEND}
+	media-libs/fontconfig
+"
+RDEPEND="${COMMON_DEPEND}
+	seccomp? ( sys-apps/bubblewrap )
+	!<gnome-base/gnome-desktop-${PV}:3
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	gtk-doc? ( >=dev-util/gtk-doc-1.14 )
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	# Don't build manual test programs that will never get run
+	sed -i -e "/'test-.*'/d" libgnome-desktop/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddesktop_docs=true
+		$(meson_use debug debug_tools)
+		$(meson_feature udev)
+		$(meson_feature systemd)
+		$(meson_use gtk-doc gtk_doc)
+		-Dinstalled_tests=false
+		-Dbuild_gtk4=true
+		-Dlegacy_library=false
+		-Dintrospection=true
+	)
+	meson_src_configure
+}