games-arcade/gnujump: EAPI6->8, misc fixes

* update dead homepage
* run eautoreconf so ./configure is not missing macros wrt bug #818814
* depend on libsdl[opengl] to pull SDL's headers deps wrt bug #739078,
  and also depend on GLU directly given gnujump uses glu.h too
* depend on gettext/libintl
* GPL-3 -> GPL-3+
* include potentially missing locale.h, e.g. with musl wrt bug #831726

Closes: https://bugs.gentoo.org/739078
Closes: https://bugs.gentoo.org/818814
Closes: https://bugs.gentoo.org/831726
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

3 files changed, 62 insertions, 35 deletions

diff --git a/games-arcade/gnujump/files/gnujump-1.0.8-musl.patch b/games-arcade/gnujump/files/gnujump-1.0.8-musl.patch
new file mode 100644
index 000000000000..83bb4214e722
--- /dev/null
+++ b/games-arcade/gnujump/files/gnujump-1.0.8-musl.patch
@@ -0,0 +1,10 @@
+locale.h is always needed, include here rather than rely on
+conditional macros which lead to failure with musl
+
+https://bugs.gentoo.org/831726
+--- a/src/gnujump.h
++++ b/src/gnujump.h
+@@ -38,2 +38,3 @@
+ #include <time.h>
++#include <locale.h>
+ 
diff --git a/games-arcade/gnujump/gnujump-1.0.8-r1.ebuild b/games-arcade/gnujump/gnujump-1.0.8-r1.ebuild
deleted file mode 100644
index 271171a2cf0a..000000000000
--- a/games-arcade/gnujump/gnujump-1.0.8-r1.ebuild
+++ /dev/null
@@ -1,35 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit desktop flag-o-matic
-
-DESCRIPTION="Xjump clone with added features"
-HOMEPAGE="http://gnujump.es.gnu.org"
-SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE=""
-
-DEPEND="media-libs/libsdl[sound,video]
-	media-libs/sdl-image[png]
-	media-libs/sdl-mixer[vorbis]
-	virtual/opengl
-	x11-libs/libX11
-"
-RDEPEND="${DEPEND}"
-
-src_prepare() {
-	default
-	append-libs -lm
-}
-
-src_install() {
-	default
-	einstalldocs
-
-	newicon skins/xjump/hero1.0.png ${PN}.png
-	make_desktop_entry ${PN} "GNUjump"
-}
diff --git a/games-arcade/gnujump/gnujump-1.0.8-r2.ebuild b/games-arcade/gnujump/gnujump-1.0.8-r2.ebuild
new file mode 100644
index 000000000000..dfae59b48abd
--- /dev/null
+++ b/games-arcade/gnujump/gnujump-1.0.8-r2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools desktop flag-o-matic
+
+DESCRIPTION="Xjump clone with added features"
+HOMEPAGE="https://jump.gnu.sinusoid.es/"
+SRC_URI="mirror://gnu/gnujump/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	media-libs/libglvnd[X]
+	media-libs/libsdl[opengl,sound,video]
+	media-libs/sdl-image[png]
+	media-libs/sdl-mixer[vorbis]
+	virtual/glu
+	virtual/libintl"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/autoconf-archive
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-musl.patch
+)
+
+src_prepare() {
+	default
+
+	# change ac_unique_file given eautoreconf will move configure.in
+	sed -i 's/(configure.in)//' configure.in || die
+
+	# regenerate due to missing macros, ensure have autoconf-archive for GLU
+	# and remove acinclude.m4 which does unnecessary checks (bug #818814)
+	rm acinclude.m4 || die
+	eautoreconf
+
+	append-libs -lm #496924
+}
+
+src_install() {
+	default
+
+	newicon skins/xjump/hero1.0.png ${PN}.png
+	make_desktop_entry ${PN} "GNUjump"
+}