dev-tcltk/itk: add a symlink to build iwidgets

Bug: https://bugs.gentoo.org/916006
Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

2 files changed, 69 insertions, 2 deletions

diff --git a/dev-tcltk/itk/itk-4.1.0-r1.ebuild b/dev-tcltk/itk/itk-4.1.0-r1.ebuild
new file mode 100644
index 000000000000..86f5abce75fe
--- /dev/null
+++ b/dev-tcltk/itk/itk-4.1.0-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools virtualx
+
+MY_PV=${PV/_beta/b}
+
+DESCRIPTION="Object Oriented Enhancements for Tcl/Tk"
+HOMEPAGE="http://incrtcl.sourceforge.net/"
+SRC_URI="mirror://sourceforge/project/incrtcl/%5Bincr%20Tcl_Tk%5D-4-source/itk%20${MY_PV}/${PN}${MY_PV}.tar.gz"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm64 ~ia64 ~ppc ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=dev-lang/tk-8.6:=
+	>=dev-tcltk/itcl-4.1"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${PN}${MY_PV}"
+
+QA_CONFIG_IMPL_DECL_SKIP=(
+	stat64 # used to test for Large File Support
+)
+
+src_prepare() {
+	mv configure.{in,ac} || die
+	AT_M4DIR=.. eautoconf
+	sed 's:-pipe::g' -i configure || die
+	default
+}
+
+src_configure() {
+	local ITCL_VERSION=$(best_version dev-tcltk/itcl)
+	ITCL_VERSION=${ITCL_VERSION:15} # remove category, package name and dash
+	source "${EPREFIX}"/usr/$(get_libdir)/itcl${ITCL_VERSION}*/itclConfig.sh || die
+	econf \
+		--with-tcl="${EPREFIX}"/usr/$(get_libdir) \
+		--with-tclinclude="${EPREFIX}"/usr/include \
+		--with-tk="${EPREFIX}"/usr/$(get_libdir) \
+		--with-tkinclude="${EPREFIX}"/usr/include \
+		--with-itcl="${ITCL_SRC_DIR}" \
+		--with-x
+}
+
+src_compile() {
+	emake CFLAGS_DEFAULT="${CFLAGS}"
+}
+
+src_test() {
+	virtx default
+}
+
+src_install() {
+	default
+
+	dodoc license.terms
+
+	cat >> "${T}"/34${PN} <<- EOF
+	LDPATH="${EPREFIX}/usr/$(get_libdir)/${PN}${MY_PV}/"
+	EOF
+	doenvd "${T}"/34${PN}
+	dosym . /usr/$(get_libdir)/${PN}${MY_PV}/library
+}
diff --git a/dev-tcltk/itk/itk-4.1.0.ebuild b/dev-tcltk/itk/itk-4.1.0.ebuild
index 5e9a1a0d1b2d..ccff38c36326 100644
--- a/dev-tcltk/itk/itk-4.1.0.ebuild
+++ b/dev-tcltk/itk/itk-4.1.0.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -11,7 +11,6 @@ DESCRIPTION="Object Oriented Enhancements for Tcl/Tk"
 HOMEPAGE="http://incrtcl.sourceforge.net/"
 SRC_URI="mirror://sourceforge/project/incrtcl/%5Bincr%20Tcl_Tk%5D-4-source/itk%20${MY_PV}/${PN}${MY_PV}.tar.gz"
 
-IUSE=""
 SLOT="0"
 LICENSE="BSD"
 KEYWORDS="amd64 ~arm64 ~ia64 ppc ~riscv sparc x86 ~amd64-linux ~x86-linux"