dev-ruby/omniauth: add 2.1.1

Closes: https://bugs.gentoo.org/892623
Signed-off-by: Hans de Graaff <graaff@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-ruby/omniauth/omniauth-2.1.1.ebuild b/dev-ruby/omniauth/omniauth-2.1.1.ebuild
new file mode 100644
index 000000000000..955e12d41818
--- /dev/null
+++ b/dev-ruby/omniauth/omniauth-2.1.1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby27 ruby30 ruby31"
+
+RUBY_FAKEGEM_EXTRADOC="README.md"
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+RUBY_FAKEGEM_DOCDIR="doc"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A generalized Rack framework for multiple-provider authentication"
+HOMEPAGE="https://github.com/omniauth/omniauth"
+SRC_URI="https://github.com/omniauth/omniauth/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="MIT"
+KEYWORDS="~amd64"
+SLOT="$(ver_cut 1)"
+IUSE=""
+
+ruby_add_rdepend "
+	>=dev-ruby/rack-2.2.3
+	dev-ruby/rack-protection
+	>=dev-ruby/hashie-3.4.6:*"
+ruby_add_bdepend "doc? ( dev-ruby/yard )
+	test? ( dev-ruby/rack-test dev-ruby/rack:2.2 )"
+
+all_ruby_prepare() {
+	sed -i -e '/[Bb]undler/d' \
+		Rakefile ${PN}.gemspec || die "sed failed"
+	sed -e '/RUBY_VERSION/,/^end/ s:^:#: ; /freeze/ s:^:#:' \
+		-e '2igem "rack", "<3"' \
+		-i spec/helper.rb || die "sed failed"
+	# maruku fails, resorting to default markdown implementation
+	sed -i -e '/maruku/d' .yardopts || die "sed failed"
+
+	sed -i -e '/s.files/d' ${RUBY_FAKEGEM_GEMSPEC} || die
+}
+
+all_ruby_compile() {
+	all_fakegem_compile
+
+	if use doc ; then
+		yard || die "yard failed"
+	fi
+}