dev-qt/qtconnectivity: new qt6 module, add 6.5.2 + live

Packaging some extra modules that are likely needed by upcoming
kde6 and were available with Qt5 in ::gentoo, so can be in a good
shape by the time need these for testing.

Please ask if need other modules that are still missing.

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

1 files changed, 66 insertions, 0 deletions

diff --git a/dev-qt/qtconnectivity/qtconnectivity-6.9999.ebuild b/dev-qt/qtconnectivity/qtconnectivity-6.9999.ebuild
new file mode 100644
index 000000000000..ed231522887f
--- /dev/null
+++ b/dev-qt/qtconnectivity/qtconnectivity-6.9999.ebuild
@@ -0,0 +1,66 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Bluetooth and NFC support library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+IUSE="+bluetooth nfc smartcard"
+REQUIRED_USE="|| ( bluetooth nfc )"
+
+RDEPEND="
+	~dev-qt/qtbase-${PV}:6[network]
+	bluetooth? (
+		~dev-qt/qtbase-${PV}:6[dbus]
+		net-wireless/bluez:=
+	)
+	nfc? (
+		smartcard? ( sys-apps/pcsc-lite )
+	)
+"
+DEPEND="${RDEPEND}"
+
+CMAKE_SKIP_TESTS=(
+	# most hardware tests are skipped, but seems(?) this one detects and fails
+	tst_qlowenergycontroller
+)
+
+src_prepare() {
+	qt6-build_src_prepare
+
+	use bluetooth ||
+		sed -i '/add_subdirectory(bluetooth)/d' src/CMakeLists.txt || die
+	use nfc ||
+		sed -i '/add_subdirectory(nfc)/d' src/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(usev nfc $(qt_feature smartcard pcsclite))
+	)
+
+	qt6-build_src_configure
+}
+
+src_install() {
+	qt6-build_src_install
+
+	# broken (unnecessary) symlink due to add_app() being used over add_tool()
+	use !bluetooth || rm -- "${ED}"/usr/bin/sdpscanner6 || die
+
+	if use test; then
+		local delete=( # sigh
+			"${D}${QT6_BINDIR}"/bluetoothtestdevice
+			"${D}${QT6_BINDIR}"/bttestui
+			"${D}${QT6_BINDIR}"/qlecontroller-server
+		)
+		# using -f given not tracking which tests may be skipped or not
+		rm -f -- "${delete[@]}" || die
+	fi
+}