dev-python/pillow: bump to v5.2.0

* Drop python 3.4
* Use pytest instead of nose
* No need to remove Script/* anymore: upstream removed them
* No need for --disable-raqm anymore: it's dynamically linked now
* Fix examples install

Package-Manager: Portage-2.3.40, Repoman-2.3.9

2 files changed, 85 insertions, 0 deletions

diff --git a/dev-python/pillow/Manifest b/dev-python/pillow/Manifest
index 827ac450d969..a65e09da7b0c 100644
--- a/dev-python/pillow/Manifest
+++ b/dev-python/pillow/Manifest
@@ -1,2 +1,3 @@
 DIST Pillow-3.4.2.zip 11042238 BLAKE2B 334af6eeadb3203b51572eca6ad9c196f3eeac14da0f1aedc351db692b33d413fdf5bc5c8564d2f53c324d9485dbdbda664b75a570b779e24f238c21829b4a39 SHA512 5e05206db5bc1b4177384f7e91ee79015c6e1bbdc7c31c997da054391b9b5ec7c1ebdec258a33f598986533894f3324b03d0b4b385b94e72a0517a3437553b39
 DIST Pillow-4.3.0.tar.gz 13874155 BLAKE2B c2258efe2727adeb7ba370fe30ef9bbabe952a1f6690e7904352884951e648d2c0e2037143b7c71a802ea1a04a2f7827a001621480036e43f6c01a96de3edcf7 SHA512 5811252802bd01ac86157235d42138685e746723df48b67ec7c7ebd3f172532b40cf86ca9d3d792e82f03986303a084bf3491c0d511dc068dea1bc631afdeabb
+DIST Pillow-5.2.0.tar.gz 14499068 BLAKE2B 7111eb8e2911cc197b66bbc06a13459484e2c4a1f5037e4bcf702ea350763b2b758cbeef9749aeb29f1ab64d33081131f7e46a3fbb33fee48e70660f8f75eddb SHA512 2f19512d0573bd4696a5b4d54ff21473492f92705d33bd0994ccd085028d209bfb0031e2b95947c1e8fc9d0b0956cdf1f705c1fbaff39390791cac1708bff22c
diff --git a/dev-python/pillow/pillow-5.2.0.ebuild b/dev-python/pillow/pillow-5.2.0.ebuild
new file mode 100644
index 000000000000..097bd53eced6
--- /dev/null
+++ b/dev-python/pillow/pillow-5.2.0.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{5,6} )
+PYTHON_REQ_USE='tk?,threads(+)'
+
+inherit distutils-r1 eutils virtualx
+
+MY_PN=Pillow
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Python Imaging Library (fork)"
+HOMEPAGE="https://python-pillow.org/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="HPND"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples imagequant jpeg jpeg2k lcms test tiff tk truetype webp zlib"
+
+REQUIRED_USE="test? ( jpeg tiff )"
+
+RDEPEND="
+	dev-python/olefile[${PYTHON_USEDEP}]
+	imagequant? ( media-gfx/libimagequant:0 )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( media-libs/openjpeg:2= )
+	lcms? ( media-libs/lcms:2= )
+	tiff? ( media-libs/tiff:0=[jpeg,zlib] )
+	truetype? ( media-libs/freetype:2= )
+	webp? ( media-libs/libwebp:0= )
+	zlib? ( sys-libs/zlib:0= )"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)
+	test? (	dev-python/nose[${PYTHON_USEDEP}] )
+"
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile() {
+	local args=(
+		--disable-platform-guessing
+		$(use_enable truetype freetype)
+		$(use_enable jpeg)
+		$(use_enable jpeg2k jpeg2000)
+		$(use_enable lcms)
+		$(use_enable tiff)
+		$(use_enable imagequant)
+		$(use_enable webp)
+		$(use_enable webp webpmux)
+		$(use_enable zlib)
+	)
+	distutils-r1_python_compile build_ext "${args[@]}"
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	"${PYTHON}" selftest.py --installed || die "selftest failed with ${EPYTHON}"
+	virtx pytest -vx Tests/test_*.py
+}
+
+python_install() {
+	python_doheader src/libImaging/*.h
+	distutils-r1_python_install
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	if use examples ; then
+		docinto example
+		dodoc docs/example/*
+		docompress -x /usr/share/doc/${PF}/example
+	fi
+	distutils-r1_python_install_all
+}