dev-libs/liblogging: disable USE=stdlog by default

It's deprecated and no longer used for tests.

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Thomas Deutschmann <whissi@gentoo.org>

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-libs/liblogging/liblogging-1.0.6-r1.ebuild b/dev-libs/liblogging/liblogging-1.0.6-r1.ebuild
new file mode 100644
index 000000000000..74f650adc76c
--- /dev/null
+++ b/dev-libs/liblogging/liblogging-1.0.6-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Liblogging is an easy to use, portable, open source library for system logging"
+HOMEPAGE="http://www.liblogging.org"
+SRC_URI="http://download.rsyslog.com/liblogging/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0/0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~x86"
+IUSE="rfc3195 stdlog systemd"
+
+RDEPEND="systemd? ( sys-apps/systemd )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( ChangeLog )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable rfc3195)
+		$(use_enable stdlog)
+		$(use_enable systemd journal)
+		--disable-static
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}