dev-libs/appstream: add 0.15.5

~ppc dropped for dev-libs/libxmlb dependency

Closes: https://bugs.gentoo.org/868276
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 80 insertions, 0 deletions

diff --git a/dev-libs/appstream/Manifest b/dev-libs/appstream/Manifest
index e5ea92357c51..f7b1e10350a4 100644
--- a/dev-libs/appstream/Manifest
+++ b/dev-libs/appstream/Manifest
@@ -1 +1,2 @@
 DIST AppStream-0.14.6.tar.xz 2403088 BLAKE2B 1eb85601c1782fc47ff21983517f301dc9493fb60347cfe8072c277cc4415e80bf6c11a93db80b6d7fe1eeda7ff1fa414fd10ce7ef0d7379b415326407d805b8 SHA512 810aa7427df50793f4bed27cc3cb5b72c156f0c582f241e06131aa8eabe82d59c8ac0bcc37a22877f7a19ac4640a9a831f8b567ce3e2d26a41ce999515affdb0
+DIST AppStream-0.15.5.tar.xz 2499336 BLAKE2B a0710d1ef2756480fa814c8b740d066e1b06dffe6a3396a44697876372dc9d0f39088ff141817af549d0cf0ad99221e68305344dfdeb82e246f7cda18c3b63a7 SHA512 83202a8db9a31e4328b2a831b02e65389aad1ba95a4c2b2709084fb843cb3675af6fac73f932a31bb3a6d3ff5db85a863c01528be67d9bbd3b9614a978239771
diff --git a/dev-libs/appstream/appstream-0.15.5.ebuild b/dev-libs/appstream/appstream-0.15.5.ebuild
new file mode 100644
index 000000000000..cd741e46c568
--- /dev/null
+++ b/dev-libs/appstream/appstream-0.15.5.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg-utils
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/ximion/${PN}"
+else
+	MY_PN="AppStream"
+	SRC_URI="https://www.freedesktop.org/software/appstream/releases/${MY_PN}-${PV}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+	S="${WORKDIR}/${MY_PN}-${PV}"
+fi
+
+DESCRIPTION="Cross-distro effort for providing metadata for software in the Linux ecosystem"
+HOMEPAGE="https://www.freedesktop.org/wiki/Distributions/AppStream/"
+
+LICENSE="LGPL-2.1+ GPL-2+"
+# check as_api_level
+SLOT="0/4"
+IUSE="apt doc +introspection qt5 test"
+RESTRICT="test" # bug 691962
+
+RDEPEND="
+	>=dev-libs/glib-2.62:2
+	dev-libs/libxml2:2
+	>=dev-libs/libxmlb-0.3.6:=
+	dev-libs/libyaml
+	dev-libs/snowball-stemmer:=
+	>=net-misc/curl-7.62
+	introspection? ( >=dev-libs/gobject-introspection-1.56:= )
+	qt5? ( dev-qt/qtcore:5 )
+"
+DEPEND="${RDEPEND}
+	test? ( qt5? ( dev-qt/qttest:5 ) )
+"
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-libs/libxslt
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	doc? ( app-text/docbook-xml-dtd:4.5 )
+	test? ( dev-qt/linguist-tools:5 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.14.3-disable-Werror-flags.patch # bug 733774
+)
+
+src_prepare() {
+	default
+	sed -e "/^as_doc_target_dir/s/appstream/${PF}/" -i docs/meson.build || die
+	if ! use test; then
+		sed -e "/^subdir.*tests/s/^/#DONT /" -i {,qt/}meson.build || die # bug 675944
+	fi
+}
+
+src_configure() {
+	xdg_environment_reset
+
+	local emesonargs=(
+		-Dapidocs=false
+		-Ddocs=false
+		-Dcompose=false
+		-Dmaintainer=false
+		-Dstatic-analysis=false
+		-Dstemming=true
+		-Dvapi=false
+		-Dapt-support=$(usex apt true false)
+		-Dinstall-docs=$(usex doc true false)
+		-Dgir=$(usex introspection true false)
+		-Dqt=$(usex qt5 true false)
+	)
+
+	meson_src_configure
+}