dev-lang/swi-prolog: bump development version

Signed-off-by: Keri Harris <keri@gentoo.org>
Package-Manager: Portage-2.3.76, Repoman-2.3.11

2 files changed, 107 insertions, 0 deletions

diff --git a/dev-lang/swi-prolog/Manifest b/dev-lang/swi-prolog/Manifest
index 611ca7c5adad..de088424d780 100644
--- a/dev-lang/swi-prolog/Manifest
+++ b/dev-lang/swi-prolog/Manifest
@@ -3,3 +3,4 @@ DIST swipl-8.1.14.tar.gz 10772544 BLAKE2B d272b6cd5a096d6422a2afc7fe27354c3c0e45
 DIST swipl-8.1.15.tar.gz 10786301 BLAKE2B e79795f92e269dfc9b8150d63cfac946285a4a433ae2d4445b381ac37fe5bfb9df2f9d1fe48b3531c430a792d74414fdb0219b2ec14b75a974639246402e67fa SHA512 97d2873acb5c5a9806e6c8a99633a093a62cb3f6c693b42265a97d9c3bb0d44b286627a2a962ba031c99be6a19f5a63eada831b625deb8e22dc9423136788f2e
 DIST swipl-8.1.16.tar.gz 10793960 BLAKE2B 4c353fe4b839e50e47c2e063ed38913fb4271fb51974bf88f745769fa8f39e2c731bf687d3f3b8531d0dc31fe7f50e82d24f2f27e7a68cfcbbdb5a6b68f9c347 SHA512 f62b8e3fdead3273e3cb6a58a3087c012dca6c8cc7ede239ad833a59641ded4c275e2b8820b719c6f335b2730bab75ac70df09fba743e8d7d20567dc6b79ac60
 DIST swipl-8.1.17.tar.gz 10858037 BLAKE2B 69d6528e250dfd780c17bd87c2d79f2923a4ed413d44a5b1f77ca28c2077d8000dc991058fe47a7aaaa6310cf015049980463005d53294a71ba610e43b67b0dd SHA512 42a5a529e1ed935501e87cab28ab5b6d3a18283027bb801a7e3d66d41342fe6ee74de70fe9e8a341f360ab145d0a2e49d8937cb661cfec52f9105c4cf06dc735
+DIST swipl-8.1.18.tar.gz 10865862 BLAKE2B 9728593b9ce890fdb8b4bda8667dbfa9323707d86e0491e62ca82098c62d797da3cdc0180aba0509393532f2b095d1626a0b465955036de80b4fff4dbb62cba6 SHA512 c6b29b57e42e464f03e328fcc272c04db7772b45e62a26fec14f7fe2b9d3c494eeb4c090237b942e38f666dea6fc92e1d00dacba83f6ea74d6dd53923fd23816
diff --git a/dev-lang/swi-prolog/swi-prolog-8.1.18.ebuild b/dev-lang/swi-prolog/swi-prolog-8.1.18.ebuild
new file mode 100644
index 000000000000..8b822e794107
--- /dev/null
+++ b/dev-lang/swi-prolog/swi-prolog-8.1.18.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils eutils flag-o-matic multilib
+
+PATCHSET_VER="0"
+
+DESCRIPTION="versatile implementation of the Prolog programming language"
+HOMEPAGE="http://www.swi-prolog.org/"
+SRC_URI="http://www.swi-prolog.org/download/devel/src/swipl-${PV}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="archive berkdb debug doc +gmp java +libedit libressl minimal odbc pcre qt5 readline ssl test uuid X yaml"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-libs/ncurses:=
+	sys-libs/zlib
+	archive? ( app-arch/libarchive )
+	berkdb? ( >=sys-libs/db-4:= )
+	odbc? ( dev-db/unixODBC )
+	pcre? ( dev-libs/libpcre )
+	readline? ( sys-libs/readline:= )
+	libedit? ( dev-libs/libedit )
+	gmp? ( dev-libs/gmp:0 )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+	)
+	java? ( >=virtual/jdk-1.7:= )
+	uuid? ( dev-libs/ossp-uuid )
+	qt5? (
+		dev-qt/qtwidgets:5
+		dev-qt/qtgui:5
+	)
+	X? (
+		virtual/jpeg:0
+		x11-libs/libX11
+		x11-libs/libXft
+		x11-libs/libXinerama
+		x11-libs/libXpm
+		x11-libs/libXt
+		x11-libs/libICE
+		x11-libs/libSM )
+	yaml? ( dev-libs/libyaml )"
+
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	java? ( test? ( =dev-java/junit-3.8* ) )"
+
+S="${WORKDIR}/swipl-${PV}"
+BUILD_DIR="${S}/build"
+CMAKE_USE_DIR="${S}"
+
+src_prepare() {
+	EPATCH_FORCE=yes
+	EPATCH_SUFFIX=patch
+	if [[ -d "${WORKDIR}"/${PV} ]] ; then
+		epatch "${WORKDIR}"/${PV}
+	fi
+
+	sed -i -e "s|\(SWIPL_INSTALL_PREFIX\)   lib/.*)|\1   $(get_libdir)/swipl)|" CMakeLists.txt || die
+
+	eapply_user
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+	use debug && append-flags -DO_DEBUG
+
+	mycmakeargs=(
+		-DSWIPL_INSTALL_PREFIX=$(get_libdir)/swipl
+		-DUSE_GMP=$(usex gmp)
+		-DINSTALL_DOCUMENTATION=$(use doc && usex archive)
+		-DSWIPL_PACKAGES_BASIC=$(usex !minimal)
+		-DSWIPL_PACKAGES_ARCHIVE=$(usex archive)
+		-DSWIPL_PACKAGES_ODBC=$(usex odbc)
+		-DSWIPL_PACKAGES_BDB=$(usex berkdb)
+		-DSWIPL_PACKAGES_PCRE=$(usex pcre)
+		-DSWIPL_PACKAGES_YAML=$(usex yaml)
+		-DSWIPL_PACKAGES_SSL=$(usex ssl)
+		-DSWIPL_PACKAGES_JAVA=$(usex java)
+		-DSWIPL_PACKAGES_QT=$(usex qt5)
+		-DSWIPL_PACKAGES_X=$(usex X)
+		-DSWIPL_PACKAGES_TERM=$(if use libedit || use readline; then echo yes; else echo no; fi)
+		)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile \
+		XDG_CONFIG_DIRS="${HOME}" \
+		XDG_DATA_DIRS="${HOME}"
+}
+
+src_test() {
+	USE_PUBLIC_NETWORK_TESTS=false \
+	USE_ODBC_TESTS=false \
+		cmake-utils_src_test -V
+}