proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

4 files changed, 114 insertions, 0 deletions

diff --git a/dev-go/go-text/Manifest b/dev-go/go-text/Manifest
new file mode 100644
index 000000000000..98f67bf03717
--- /dev/null
+++ b/dev-go/go-text/Manifest
@@ -0,0 +1 @@
+DIST go-text-0_pre20150604.tar.gz 3719061 SHA256 71017417b42ea4e68ac77303782c83b627bfbceed041a1467ddc6319c78923ad SHA512 1bbc5bff271243ee31e346a79abf9dd128907cea82fa1eaba11be62780bd1f6b6b76a2ae9476fbe350224f450e75d12efcffd67521b49d6bec44ce2bb085f0d3 WHIRLPOOL e953d99d661537c8838757ae507f2adda3319ef22ce687a39533351201c5bb7206701db4b54f7c0e4d6df803b378a4f587a2015646825b4c3dfad97696baed2e
diff --git a/dev-go/go-text/go-text-0_pre20150604.ebuild b/dev-go/go-text/go-text-0_pre20150604.ebuild
new file mode 100644
index 000000000000..f89899eb35af
--- /dev/null
+++ b/dev-go/go-text/go-text-0_pre20150604.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KEYWORDS="~amd64"
+DESCRIPTION="Go text processing support"
+MY_PN=${PN##*-}
+GO_PN=golang.org/x/${MY_PN}
+HOMEPAGE="https://godoc.org/${GO_PN}"
+EGIT_COMMIT="df923bbb63f8ea3a26bb743e2a497abd0ab585f7"
+SRC_URI="https://github.com/golang/${MY_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+LICENSE="BSD"
+SLOT="0"
+IUSE=""
+DEPEND=">=dev-lang/go-1.4"
+RDEPEND=""
+S="${WORKDIR}/src/${GO_PN}"
+EGIT_CHECKOUT_DIR="${S}"
+STRIP_MASK="*.a"
+
+src_unpack() {
+	default
+	mkdir -p src/${GO_PN%/*} || die
+	mv ${MY_PN}-${EGIT_COMMIT} src/${GO_PN} || die
+}
+
+src_compile() {
+	# Create a writable GOROOT in order to avoid sandbox violations.
+	GOROOT="${WORKDIR}/goroot"
+	cp -sR "${EPREFIX}"/usr/lib/go "${GOROOT}" || die
+	rm -rf "${GOROOT}/src/${GO_PN}" \
+		"${GOROOT}/pkg/linux_${ARCH}/${GO_PN}" || die
+	GOROOT="${GOROOT}" GOPATH=${WORKDIR} go install -v -x -work ${GO_PN}/... || die
+}
+
+src_test() {
+	# Create go symlink for TestLinking in display/dict_test.go
+	mkdir -p "${GOROOT}/bin"
+	ln -s /usr/bin/go  "${GOROOT}/bin/go" || die
+
+	GOROOT="${GOROOT}" GOPATH=${WORKDIR} \
+		go test -x -v ${GO_PN}/... || die $?
+}
+
+src_install() {
+	exeinto /usr/lib/go/bin
+	doexe "${WORKDIR}"/bin/*
+	insinto /usr/lib/go
+	find "${WORKDIR}"/{pkg,src} -name '.git*' -exec rm -rf {} \; 2>/dev/null
+	insopts -m0644 -p # preserve timestamps for bug 551486
+	doins -r "${WORKDIR}"/{pkg,src}
+}
diff --git a/dev-go/go-text/go-text-9999.ebuild b/dev-go/go-text/go-text-9999.ebuild
new file mode 100644
index 000000000000..11e63f09d777
--- /dev/null
+++ b/dev-go/go-text/go-text-9999.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+EGO_PN=golang.org/x/text/...
+EGO_SRC=golang.org/x/text
+
+if [[ ${PV} = *9999* ]]; then
+	inherit golang-vcs
+else
+	KEYWORDS="~amd64"
+	EGIT_COMMIT="df923bbb63f8ea3a26bb743e2a497abd0ab585f7"
+	SRC_URI="https://github.com/golang/text/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+	inherit golang-vcs-snapshot
+fi
+inherit golang-build
+
+DESCRIPTION="Go text processing support"
+HOMEPAGE="https://godoc.org/golang.org/x/text"
+LICENSE="BSD"
+SLOT="0/${PV}"
+IUSE=""
+DEPEND=""
+RDEPEND=""
+
+src_test() {
+	# Create a writable GOROOT in order to avoid sandbox violations.
+	cp -sR "$(go env GOROOT)" "${T}/goroot" || die
+	if [ -d "${T}/goroot/src/${EGO_SRC}" ]; then
+		rm -rf "${T}/goroot/src/${EGO_SRC}" || die
+	fi
+	if [ -d "${T}/goroot/pkg/$(go env GOOS)_$(go env GOARCH)/${EGO_SRC}" ]; then
+		rm -rf "${T}/goroot/pkg/$(go env GOOS)_$(go env GOARCH)/${EGO_SRC}" ||
+			die
+	fi
+
+	# Create go symlink for TestLinking in display/dict_test.go
+	mkdir -p "${T}/goroot/bin"
+	ln -s /usr/bin/go  "${T}/goroot/bin/go" || die
+
+	GOROOT="${T}/goroot" golang-build_src_test
+}
+
+src_install() {
+	golang-build_src_install
+	dobin bin/*
+}
diff --git a/dev-go/go-text/metadata.xml b/dev-go/go-text/metadata.xml
new file mode 100644
index 000000000000..d8ef7c04ca7d
--- /dev/null
+++ b/dev-go/go-text/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer>
+    <email>zmedico@gentoo.org</email>
+  </maintainer>
+  <upstream>
+    <remote-id type="github">golang/text</remote-id>
+  </upstream>
+</pkgmetadata>