app-text/xiphos: Version bump

Closes: https://bugs.gentoo.org/658342
Package-Manager: Portage-2.3.40, Repoman-2.3.9

2 files changed, 89 insertions, 0 deletions

diff --git a/app-text/xiphos/Manifest b/app-text/xiphos/Manifest
index 8399d748651a..3bb3026e0888 100644
--- a/app-text/xiphos/Manifest
+++ b/app-text/xiphos/Manifest
@@ -1 +1,2 @@
 DIST xiphos-4.0.6a-20170820.tar.gz 30584893 BLAKE2B a3b76543c8d1c0d03fcc2f567751df49230ef1d35019bec98ef726edb6a519424d0c773d4ff6f7eb3ad714f56af6dac19fc1ac2dc29560b03e3ec3ea9a46ccfd SHA512 a0577521c6b9033b74b3b0a0fd7a88222de00dc2e9db100d66e1bb60bc117173badd26c47d2e896ffa167c52a263c9bf9046d650a9b4ae497bec6164bfb0a29b
+DIST xiphos-4.1.0.tar.gz 30623199 BLAKE2B 3f4e804b346b5f3225458bf3653d033c95fb4cb8148b5e1c7d7ba875637877df1489d43b22e6d47ed1d477545d564da57d864f54e4a4e30c61e4b4c94b3f2066 SHA512 f2da65a0cf10cda5ca471a09d351be8e2e5601857b4cb363ba45865e4595bebbc9b8cfa47660a1106b1521b4059d341c7e8c04c0c712387b913bdf994d1c6400
diff --git a/app-text/xiphos/xiphos-4.1.0.ebuild b/app-text/xiphos/xiphos-4.1.0.ebuild
new file mode 100644
index 000000000000..9824202606e8
--- /dev/null
+++ b/app-text/xiphos/xiphos-4.1.0.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+inherit flag-o-matic gnome2-utils python-single-r1 toolchain-funcs
+
+DESCRIPTION="A bible study frontend for Sword (formerly known as GnomeSword)"
+HOMEPAGE="http://xiphos.org/"
+SRC_URI="https://github.com/crosswire/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2 FDL-1.1 LGPL-2 MIT MPL-1.1"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="dbus debug"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	>=app-text/sword-1.8.0
+	>=dev-libs/glib-2[${PYTHON_USEDEP}]
+	dev-libs/libxml2[${PYTHON_USEDEP}]
+	gnome-base/gconf[${PYTHON_USEDEP}]
+	gnome-extra/gtkhtml:4.0
+	>=gnome-extra/libgsf-1.14
+	net-libs/webkit-gtk:4
+	x11-libs/gtk+:3
+	dbus? ( dev-libs/dbus-glib )
+"
+DEPEND="${RDEPEND}
+	app-text/docbook2X
+	app-text/gnome-doc-utils[${PYTHON_USEDEP}]
+	app-text/rarian
+	dev-libs/libxslt[${PYTHON_USEDEP}]
+	dev-util/intltool
+	>=net-libs/biblesync-1.1.2-r1[-static]
+	virtual/pkgconfig
+	sys-devel/gettext
+"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	sed -i \
+		-e '/FLAGS_DEBUG/s:-g:-Wall:' \
+		-e '/FLAGS_RELEASE/s:-O2:-Wall:' \
+		wscript || die
+	default
+}
+
+src_configure() {
+	append-cppflags -DNO_SWORD_SET_RENDER_NOTE_NUMBERS=1
+
+	tc-export AR CC CPP CXX RANLIB
+
+	CCFLAGS="${CFLAGS}" \
+	LINKFLAGS="${LDFLAGS}" \
+	SGML2MAN="$(type -P docbook2man.pl)" \
+		./waf -v \
+			--prefix=/usr \
+			--gtk=3 \
+			--enable-webkit2 \
+			--debug-level=$(use debug && echo debug || echo release) \
+			$(use dbus || echo --disable-dbus) \
+			configure || die
+}
+
+src_compile() {
+	./waf -v build || die
+}
+
+src_install() {
+	./waf -v --destdir="${D}" install || die
+
+	doman ${PN}.1
+	dodoc AUTHORS ChangeLog RELEASE-NOTES TODO
+
+	dodoc Xiphos.ogg
+	docompress -x /usr/share/doc/${PF}/Xiphos.ogg
+
+	rm -rf "${ED}"/usr/share/doc/${PN}
+}
+
+pkg_preinst() {	gnome2_icon_savelist; }
+pkg_postinst() { gnome2_icon_cache_update; }
+pkg_postrm() { gnome2_icon_cache_update; }