app-crypt/eid-mw: update 5.1.18

Signed-off-by: Amy Liffey <amynka@gentoo.org>

3 files changed, 117 insertions, 0 deletions

diff --git a/app-crypt/eid-mw/Manifest b/app-crypt/eid-mw/Manifest
index 637aeca4c155..c48adf78962f 100644
--- a/app-crypt/eid-mw/Manifest
+++ b/app-crypt/eid-mw/Manifest
@@ -1 +1,2 @@
 DIST eid-mw-5.1.15.tar.gz 16296281 BLAKE2B 12efbc884ff250d5497ace6b9670e4dac934a8aa87e2e77d4c083d3e0325c7b0a57dd137506f62a6e3ada57459b5b23e7d5e0d86a80616a64e05948560ce265b SHA512 4cf352ba912db6252f864430bacc895d29b478d3ec13ef3716089e5cb6019b2db2de08a99775dcd71a4ac9f13f3e3c6e1013f36bb2d458bbb0e851f7b45451e5
+DIST eid-mw-5.1.18.tar.gz 16299966 BLAKE2B 417b92ad366f32da42c112828d9d01c5beee59045750b4fc69bbcfdea338e1e5d2db00765cae5dab5d22f36122437aa113a968620aefa013f893aebb74208d76 SHA512 1e6e9056fdadbeae623039f1a0e8e6b6e4e80ab313e0fed31824035a32b3173a042f18c254c06bb57d918afbf5162eb23990b51bb0c525e7929128466c74b4d7
diff --git a/app-crypt/eid-mw/eid-mw-5.1.18.ebuild b/app-crypt/eid-mw/eid-mw-5.1.18.ebuild
new file mode 100644
index 000000000000..bd390d5174b7
--- /dev/null
+++ b/app-crypt/eid-mw/eid-mw-5.1.18.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools desktop gnome2-utils
+
+DESCRIPTION="Electronic Identity Card middleware supplied by the Belgian Federal Government"
+HOMEPAGE="https://eid.belgium.be"
+SRC_URI="https://codeload.github.com/fedict/${PN}/tar.gz/v${PV} -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="+dialogs +gtk p11-kit"
+
+RDEPEND="sys-apps/pcsc-lite
+	gtk? (
+		x11-libs/gdk-pixbuf[jpeg]
+		x11-libs/gtk+:3
+		dev-libs/libxml2
+		net-misc/curl[ssl]
+		net-libs/libproxy
+		app-crypt/pinentry[gtk]
+	)
+	p11-kit? ( app-crypt/p11-kit )"
+
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="dialogs? ( gtk )"
+
+src_prepare() {
+	default
+
+	# Buggy internal versioning when autoreconf a tarball release.
+	# Weird numbering is required otherwise we get a seg fault in
+	# about-eid-mw program.
+	echo "${PV}-v${PV}" > .version
+
+	# xpi module : we don't want it anymore
+	sed -i -e '/SUBDIRS/ s:plugins_tools/xpi ::' Makefile.am || die
+	sed -i -e '/plugins_tools\/xpi/ d' configure.ac || die
+
+	# hardcoded lsb_info
+	sed -i \
+		-e "s:get_lsb_info('i'):strdup(_(\"Gentoo\")):" \
+		-e "s:get_lsb_info('r'):strdup(_(\"n/a\")):" \
+		-e "s:get_lsb_info('c'):strdup(_(\"n/a\")):" \
+		plugins_tools/aboutmw/gtk/about-main.c || die
+
+	# Fix libdir for manifestdir
+	sed -i \
+		-e "/pkcs11_manifestdir/ s:prefix)/lib:libdir):" \
+		-e "/managed_storage_manifestdir/ s:prefix)/lib:libdir):" \
+		cardcomm/pkcs11/src/Makefile.am || die
+
+	# See bug #811270 (remove uml build)
+	sed -i \
+		-e 's:cardlayer/uml::' \
+		cardcomm/pkcs11/src/Makefile.am || die
+	sed -i \
+		-e 's:uml::' \
+		plugins_tools/eid-viewer/Makefile.am || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable dialogs) \
+		$(use_enable p11-kit p11kit) \
+		$(use_with gtk gtkvers '3') \
+		--with-gnu-ld
+}
+
+src_install() {
+	default
+	find "${ED}" -type f -name '*.la' -delete || die
+	if use gtk; then
+		domenu plugins_tools/eid-viewer/eid-viewer.desktop
+		doicon plugins_tools/eid-viewer/gtk/eid-viewer.png
+	fi
+}
+
+pkg_postinst() {
+	if use gtk; then
+		gnome2_schemas_update
+		xdg_desktop_database_update
+		xdg_icon_cache_update
+
+		local peimpl=$(eselect --brief --colour=no pinentry show)
+		case "${peimpl}" in
+		*gnome*|*qt*) ;;
+		*)	ewarn "The pinentry front-end currently selected is not supported by eid-mw."
+			ewarn "You may be prompted for your pin code in an inaccessible shell!!"
+			ewarn "Please select pinentry-gnome3 as default pinentry provider:"
+			ewarn " # eselect pinentry set pinentry-gnome3"
+		;;
+		esac
+	fi
+}
+
+pkg_postrm() {
+	if use gtk; then
+		gnome2_schemas_update
+		xdg_desktop_database_update
+		xdg_icon_cache_update
+	fi
+}
diff --git a/app-crypt/eid-mw/eid-mw-9999.ebuild b/app-crypt/eid-mw/eid-mw-9999.ebuild
index 67d72f68ad1e..3c461d2daa95 100644
--- a/app-crypt/eid-mw/eid-mw-9999.ebuild
+++ b/app-crypt/eid-mw/eid-mw-9999.ebuild
@@ -43,6 +43,12 @@ src_prepare() {
 		-e "s:get_lsb_info('c'):strdup(_(\"n/a\")):" \
 		plugins_tools/aboutmw/gtk/about-main.c || die
 
+	# Fix libdir for manifestdir
+	sed -i \
+		-e "/pkcs11_manifestdir/ s:prefix)/lib:libdir):" \
+		-e "/managed_storage_manifestdir/ s:prefix)/lib:libdir):" \
+		cardcomm/pkcs11/src/Makefile.am || die
+
 	# See bug #811270 (remove uml build)
 	sed -i \
 		-e 's:cardlayer/uml::' \