net-misc/nextcloud-client: add 3.6.4

Signed-off-by: Florian Schmaus <flow@gentoo.org>

2 files changed, 104 insertions, 0 deletions

diff --git a/net-misc/nextcloud-client/Manifest b/net-misc/nextcloud-client/Manifest
index 03424cb21757..263dbbf4887a 100644
--- a/net-misc/nextcloud-client/Manifest
+++ b/net-misc/nextcloud-client/Manifest
@@ -1,2 +1,3 @@
 DIST nextcloud-client-3.6.1.tar.gz 15346135 BLAKE2B 116a2632ad1c653bb1dbf184c6156ebc469ed8c0bfe209282e8239d4113c46b761f4049daa6833d23d5179c0b2a3f9dd94f506e63c401775da419c92104a069f SHA512 444062440570efd82b8cd9acf85dcc5826552c86c31edc19ae2f87d9fdf23afa501aac03e4b8135bb037feb523fdcbc230339387acbf56c0ca6e5df3e7bae583
 DIST nextcloud-client-3.6.2.tar.gz 15406717 BLAKE2B 1408745e8adfd76507ffba63a20abfc34db155ef3d4f8cff1eb3736c8d1ede4cebc536cecf8f5a843ff0b22b1cf46ffd5e6cdf9c87b2e9960728e030f2f7ae66 SHA512 1baae103c08a981e86aee74550d31a195f639fef830d0a78213f7890b820ddf2cd39fa742b99c9222930a4ef9587acc820678c56527e98ca482689b3bffd14ff
+DIST nextcloud-client-3.6.4.tar.gz 15451930 BLAKE2B 47b379513927d0f7fa20d41be67f75196ffbae6318d947d759f69d9561e27641d71e9a0accd197673f995d4aab90fa30dd1f1faa4dee446545f586ca28599cff SHA512 7a9378e78e1e678e72898d1cca2188ba9f5488f565c72db49d70e9d3d6d8124c8fae7856226fb3b47edcb37cacaadc8f0fbc5ff3b6914e4ebb777a4ebd633513
diff --git a/net-misc/nextcloud-client/nextcloud-client-3.6.4.ebuild b/net-misc/nextcloud-client/nextcloud-client-3.6.4.ebuild
new file mode 100644
index 000000000000..e0406e9984a4
--- /dev/null
+++ b/net-misc/nextcloud-client/nextcloud-client-3.6.4.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake virtualx xdg
+
+DESCRIPTION="Desktop Syncing Client for Nextcloud"
+HOMEPAGE="https://github.com/nextcloud/desktop"
+SRC_URI="https://github.com/nextcloud/desktop/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/desktop-${PV/_/-}"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc dolphin nautilus test webengine"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-db/sqlite-3.34:3
+	>=dev-libs/openssl-1.1.0:0=
+	dev-libs/qtkeychain:=[qt5(+)]
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtquickcontrols2:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwebsockets:5
+	dev-qt/qtwidgets:5
+	net-libs/libcloudproviders
+	sys-libs/zlib
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )
+	webengine? ( dev-qt/qtwebengine:5[widgets] )
+"
+DEPEND="${RDEPEND}
+	dev-qt/qtconcurrent:5
+	dev-qt/qtxml:5
+	|| ( gnome-base/librsvg media-gfx/inkscape )
+	doc? (
+		dev-python/sphinx
+		dev-tex/latexmk
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	test? (
+		dev-qt/qttest:5
+		dev-util/cmocka
+	)
+"
+BDEPEND="
+	dev-qt/linguist-tools:5
+	dolphin? ( kde-frameworks/extra-cmake-modules )
+"
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DBUILD_UPDATER=OFF
+		$(cmake_use_find_package doc Sphinx)
+		$(cmake_use_find_package doc PdfLatex)
+		$(cmake_use_find_package webengine Qt5WebEngine)
+		$(cmake_use_find_package webengine Qt5WebEngineWidgets)
+		-DBUILD_SHELL_INTEGRATION_DOLPHIN=$(usex dolphin)
+		-DBUILD_SHELL_INTEGRATION_NAUTILUS=$(usex nautilus)
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	virtx cmake_src_test
+}
+
+src_compile() {
+	local compile_targets=(all)
+	if use doc; then
+		compile_targets+=(doc doc-man)
+	fi
+	cmake_src_compile ${compile_targets[@]}
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+}