1 files changed, 52 insertions, 0 deletions
diff --git a/sci-libs/clfft/clfft-2.12.2-r1.ebuild b/sci-libs/clfft/clfft-2.12.2-r1.ebuild
new file mode 100644
index 000000000..8be3d24d0
--- /dev/null
+++ b/sci-libs/clfft/clfft-2.12.2-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="clFFT"
+
+DOCS_BUILDER="doxygen"
+DOCS_DIR="../docs"
+DOCS_CONFIG_NAME="${MY_PN}.doxy"
+
+inherit cmake docs
+
+DESCRIPTION="Library containing FFT functions written in OpenCL"
+HOMEPAGE="https://github.com/clMathLibraries/clFFT"
+SRC_URI="https://github.com/clMathLibraries/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="callback-client +client test"
+
+RDEPEND="
+	virtual/opencl
+	dev-libs/boost
+"
+DEPEND="${RDEPEND}"
+BDEPEND="test? (
+	dev-cpp/gtest
+	sci-libs/fftw:3.0
+)"
+
+# The tests only get compiled to an executable named Test, which is not recogniozed by cmake.
+# Therefore src_test() won't execute any test.
+RESTRICT="test"
+
+S="${WORKDIR}/${MY_PN}-${PV}/src"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_CALLBACK_CLIENT="$(usex callback-client)"
+		-DBUILD_CLIENT="$(usex client)"
+		-DBUILD_TEST="$(usex test)"
+		-DBoost_USE_STATIC_LIBS=OFF
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	docs_compile
+	cmake_src_compile
+}