dev-vcs/datalad: add 0.19.6

Signed-off-by: Horea Christian <chr@chymera.eu>

2 files changed, 75 insertions, 0 deletions

diff --git a/dev-vcs/datalad/Manifest b/dev-vcs/datalad/Manifest
index 78bcf187d..2cbe5a4db 100644
--- a/dev-vcs/datalad/Manifest
+++ b/dev-vcs/datalad/Manifest
@@ -1,3 +1,4 @@
 DIST datalad-0.18.0.tar.gz 1425155 BLAKE2B 8d7cbf7f56b1de82c74fa823b2d4512112f1b4c4be106cac433c8db696b2e7f77da758c0bb62b7cb9fe0fbb08d49431dda2818d08d5c60b5052154895c335b33 SHA512 0df8276edc3872c73fee7286ea4e578648a6fb2a630fa49a4f8945e0d6ff88353d9b11d29d942c0ce22ed17a8223e71f99d8b519a6a8afbc2ac9e6da89d95ee5
 DIST datalad-0.18.1.tar.gz 1425820 BLAKE2B 574e864feb500062f829dfea3f9c8c51f9ad2e0e68e70966c2a5ea315fafffb259de9a0f57427c0aae1ee93c24ec9a3a91ef42637d109d912cf5b6c41ac07b11 SHA512 19f011428fe66d9f21410ae33276133f26cf2b1a367c23a83c56ab48a0e038837ba18163e12ab2d74eba7d0ec9ce2e660a21494ddba0da3a2df6da2c043c4aad
 DIST datalad-0.18.3.tar.gz 1435282 BLAKE2B 8077c0a639920e914b30598ded435ad74564f3947a187f5d57752cd22e0d435838db9bdd797a6d8d8cc54282e1303f5ca5d673d3674da09c678a47f35e8ef3f6 SHA512 06f5a73caaacffb35f11852f69ee48c485ebd1cce55e1440eb8686d8614a29809b01de2d129a48591fd66c02a59af9dcd064b0e7ead698842cc7f79d12af729c
+DIST datalad-0.19.6.tar.gz 1429377 BLAKE2B 1f7e3f91e6d305b4a1e9e9bd8f649e32b4a87cddb98eea68f7e1920832562604c0d2477c47dbb22f05dc2bdaf7645c5d943fdefae53b1ec9e418fb240ec3b18d SHA512 546f17be597121f2508140919360200f261553df415b67c709961e293ba95fa6cec6b13e7b54fcfc18b602a479565331b0146fb196b57ade3e6bf697f1054e07
diff --git a/dev-vcs/datalad/datalad-0.19.6.ebuild b/dev-vcs/datalad/datalad-0.19.6.ebuild
new file mode 100644
index 000000000..cd90c1db2
--- /dev/null
+++ b/dev-vcs/datalad/datalad-0.19.6.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+inherit distutils-r1
+
+DESCRIPTION="Keep code, data, containers under control with git and git-annex"
+HOMEPAGE="https://github.com/datalad/datalad"
+SRC_URI="https://github.com/datalad/datalad/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test +downloaders +metadata +publish misc"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	app-arch/p7zip
+	app-arch/patool[${PYTHON_USEDEP}]
+	dev-python/annexremote[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	dev-python/fasteners[${PYTHON_USEDEP}]
+	dev-python/humanize[${PYTHON_USEDEP}]
+	dev-python/iso8601[${PYTHON_USEDEP}]
+	dev-python/looseversion[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/tqdm[${PYTHON_USEDEP}]
+	dev-python/wraps[${PYTHON_USEDEP}]
+	dev-vcs/git-annex
+	downloaders? (
+		dev-python/boto[${PYTHON_USEDEP}]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		dev-python/keyrings-alt[${PYTHON_USEDEP}]
+		dev-python/msgpack[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+	)
+	metadata? (
+		dev-python/simplejson[${PYTHON_USEDEP}]
+		dev-python/whoosh[${PYTHON_USEDEP}]
+	)
+	misc? (
+		dev-python/argcomplete[${PYTHON_USEDEP}]
+		dev-python/pyperclip[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+	)
+	publish? (
+		dev-vcs/python-gitlab[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	dev-python/packaging[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/httpretty[${PYTHON_USEDEP}]
+		dev-python/mypy[${PYTHON_USEDEP}]
+		dev-python/vcrpy[${PYTHON_USEDEP}]
+	)
+"
+# Also wants test dep:
+# dev-python/types-requests
+# dev-python/types-python-dateutil
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x DATALAD_TESTS_NONETWORK=1
+	# see test groups in "tox.ini"
+	epytest -k "not turtle and not slow and not usecase"
+}