net-p2p/ktorrent: 22.07.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 95 insertions, 0 deletions

diff --git a/net-p2p/ktorrent/Manifest b/net-p2p/ktorrent/Manifest
index 994839dddf..a298b12ef7 100644
--- a/net-p2p/ktorrent/Manifest
+++ b/net-p2p/ktorrent/Manifest
@@ -1 +1,2 @@
 DIST ktorrent-22.07.80.tar.xz 2055060 BLAKE2B 5c5099bbeb55e35b3b845104ec8d8dc0f5fbe3b60dfe328597cdb58709ba6fb975506aab0db0409597128eba7cc307d07095b71fb1794f0ff3725c5a1ac441d8 SHA512 1a2e76cf8e0e5e14db3171fcfd44f2112f6b3b3ad9f024490602405c67a58379d158a95b24c26a994b8a6c777bde74842589f442fd2a1ec88c0aad84c946e5e3
+DIST ktorrent-22.07.90.tar.xz 2055112 BLAKE2B 9a5a581c68f940836bf5bfc63b2457bf33d0b9f8034530010a7c8307c284896e376e1f77bd3f3bc4b832727c0f0b2045eb87184138bcb02bb877cf58ed630be7 SHA512 edd33634671a68742b9364221a38d0192c280c9853292086c8dfb73f80cd7a394431014ede21b7ea5080930ff0ff76e1de596d75b2c6c6d7672b571ccdaebae6
diff --git a/net-p2p/ktorrent/ktorrent-22.07.90.ebuild b/net-p2p/ktorrent/ktorrent-22.07.90.ebuild
new file mode 100644
index 0000000000..026478e001
--- /dev/null
+++ b/net-p2p/ktorrent/ktorrent-22.07.90.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="optional"
+KFMIN=5.96.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm gear.kde.org
+
+DESCRIPTION="Powerful BitTorrent client based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/ktorrent/"
+
+LICENSE="GPL-2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="+bwscheduler +downloadorder +infowidget +ipfilter +logviewer +magnetgenerator
++mediaplayer rss +scanfolder +shutdown +stats +upnp +webengine +zeroconf"
+
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=net-libs/libktorrent-${PVCUT}:5
+	infowidget? ( dev-libs/geoip )
+	mediaplayer? (
+		>=media-libs/phonon-4.11.0
+		>=media-libs/taglib-1.5
+	)
+	rss? (
+		>=dev-qt/qtwebengine-${QTMIN}:5
+		>=kde-frameworks/syndication-${KFMIN}:5
+	)
+	shutdown? ( kde-plasma/libkworkspace:5 )
+	stats? ( >=kde-frameworks/kplotting-${KFMIN}:5 )
+	upnp? ( >=kde-frameworks/kcompletion-${KFMIN}:5 )
+	webengine? ( >=dev-qt/qtwebengine-${QTMIN}:5 )
+	zeroconf? ( >=kde-frameworks/kdnssd-${KFMIN}:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/boost-1.71
+"
+RDEPEND="${COMMON_DEPEND}
+	ipfilter? (
+		app-arch/bzip2
+		app-arch/unzip
+		kde-apps/kio-extras:5
+		>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	)
+"
+BDEPEND="sys-devel/gettext"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_BWSCHEDULER_PLUGIN=$(usex bwscheduler)
+		-DENABLE_DOWNLOADORDER_PLUGIN=$(usex downloadorder)
+		-DENABLE_INFOWIDGET_PLUGIN=$(usex infowidget)
+		-DENABLE_IPFILTER_PLUGIN=$(usex ipfilter)
+		-DENABLE_LOGVIEWER_PLUGIN=$(usex logviewer)
+		-DENABLE_MAGNETGENERATOR_PLUGIN=$(usex magnetgenerator)
+		-DENABLE_MEDIAPLAYER_PLUGIN=$(usex mediaplayer)
+		$(cmake_use_find_package rss KF5Syndication)
+		-DENABLE_SCANFOLDER_PLUGIN=$(usex scanfolder)
+		-DENABLE_SHUTDOWN_PLUGIN=$(usex shutdown)
+		-DENABLE_STATS_PLUGIN=$(usex stats)
+		-DENABLE_UPNP_PLUGIN=$(usex upnp)
+		-DENABLE_SEARCH_PLUGIN=$(usex webengine)
+		-DENABLE_ZEROCONF_PLUGIN=$(usex zeroconf)
+	)
+# add back when ported
+# 		-DENABLE_WEBINTERFACE_PLUGIN=$(usex webinterface)
+	ecm_src_configure
+}