net-p2p/ktorrent: 20.11.80 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 101 insertions, 0 deletions

diff --git a/net-p2p/ktorrent/Manifest b/net-p2p/ktorrent/Manifest
new file mode 100644
index 0000000000..19d03669dc
--- /dev/null
+++ b/net-p2p/ktorrent/Manifest
@@ -0,0 +1 @@
+DIST ktorrent-20.11.80.tar.xz 2140692 BLAKE2B af8e28cb3cbdc7f88d85d659b31002518abdc11d07a1a493f5abda5807ee806976ffec74b70a3a0e8a4a6d0d3dec0ed67974da38663f2b9e13dd2245f57eb8d8 SHA512 672f6fa8f16dcce4c17d32f0902a37f296079a843aeb19c1770ff0cc59720792fa64499021b42350d341c48cd0ab0f2889e3dde1a4712c3461f23dcd4f9e6b66
diff --git a/net-p2p/ktorrent/ktorrent-20.11.80.ebuild b/net-p2p/ktorrent/ktorrent-20.11.80.ebuild
new file mode 100644
index 0000000000..8e549e2883
--- /dev/null
+++ b/net-p2p/ktorrent/ktorrent-20.11.80.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="optional"
+ECM_TEST="optional"
+KFMIN=5.74.0
+QTMIN=5.15.1
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Powerful BitTorrent client based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/en/ktorrent"
+
+LICENSE="GPL-2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="+bwscheduler +downloadorder +infowidget +ipfilter +kross +logviewer +magnetgenerator
++mediaplayer rss +scanfolder +shutdown +stats +upnp +webengine +zeroconf"
+
+BDEPEND="sys-devel/gettext"
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=net-libs/libktorrent-2.2.0:5
+	infowidget? ( dev-libs/geoip )
+	kross? (
+		>=kde-frameworks/karchive-${KFMIN}:5
+		>=kde-frameworks/kitemviews-${KFMIN}:5
+		>=kde-frameworks/kross-${KFMIN}:5
+	)
+	mediaplayer? (
+		>=media-libs/phonon-4.11.0
+		>=media-libs/taglib-1.5
+	)
+	rss? (
+		>=dev-qt/qtwebengine-${QTMIN}:5
+		>=kde-frameworks/syndication-${KFMIN}:5
+	)
+	shutdown? ( kde-plasma/libkworkspace:5 )
+	stats? ( >=kde-frameworks/kplotting-${KFMIN}:5 )
+	upnp? ( >=kde-frameworks/kcompletion-${KFMIN}:5 )
+	webengine? ( >=dev-qt/qtwebengine-${QTMIN}:5 )
+	zeroconf? ( >=kde-frameworks/kdnssd-${KFMIN}:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/boost
+"
+RDEPEND="${COMMON_DEPEND}
+	ipfilter? (
+		app-arch/bzip2
+		app-arch/unzip
+		kde-apps/kio-extras:5
+		>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	)
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_BWSCHEDULER_PLUGIN=$(usex bwscheduler)
+		-DENABLE_DOWNLOADORDER_PLUGIN=$(usex downloadorder)
+		-DENABLE_INFOWIDGET_PLUGIN=$(usex infowidget)
+		-DWITH_SYSTEM_GEOIP=$(usex infowidget)
+		-DENABLE_IPFILTER_PLUGIN=$(usex ipfilter)
+		-DENABLE_SCRIPTING_PLUGIN=$(usex kross)
+		-DENABLE_LOGVIEWER_PLUGIN=$(usex logviewer)
+		-DENABLE_MAGNETGENERATOR_PLUGIN=$(usex magnetgenerator)
+		-DENABLE_MEDIAPLAYER_PLUGIN=$(usex mediaplayer)
+		$(cmake_use_find_package rss KF5Syndication)
+		-DENABLE_SCANFOLDER_PLUGIN=$(usex scanfolder)
+		-DENABLE_SHUTDOWN_PLUGIN=$(usex shutdown)
+		-DENABLE_STATS_PLUGIN=$(usex stats)
+		-DENABLE_UPNP_PLUGIN=$(usex upnp)
+		-DENABLE_SEARCH_PLUGIN=$(usex webengine)
+		-DENABLE_ZEROCONF_PLUGIN=$(usex zeroconf)
+	)
+# add back when ported
+# 		-DENABLE_WEBINTERFACE_PLUGIN=$(usex webinterface)
+	ecm_src_configure
+}