kde-apps/ktp-accounts-kcm: 22.04.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 64 insertions, 0 deletions

diff --git a/kde-apps/ktp-accounts-kcm/Manifest b/kde-apps/ktp-accounts-kcm/Manifest
new file mode 100644
index 0000000000..b127f1da06
--- /dev/null
+++ b/kde-apps/ktp-accounts-kcm/Manifest
@@ -0,0 +1 @@
+DIST ktp-accounts-kcm-22.04.3.tar.xz 266764 BLAKE2B 220f036785c0d71ef25dcce8cd6da86dd668cfd4b5ff2fbfac4d0194db80f40ae3985b368094a68cb3773ee6022e4a2956b02c41b858f04259a9e2dc4c908ab4 SHA512 b6a855334e4c4d039bfe17246647e1b37fd5543e5956c61902a7b614c2661b30186f2fade92fd9553d0b5279181f531dc135485d2399237162a433294026e395
diff --git a/kde-apps/ktp-accounts-kcm/ktp-accounts-kcm-22.04.3.ebuild b/kde-apps/ktp-accounts-kcm/ktp-accounts-kcm-22.04.3.ebuild
new file mode 100644
index 0000000000..3b419971d3
--- /dev/null
+++ b/kde-apps/ktp-accounts-kcm/ktp-accounts-kcm-22.04.3.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.92.0
+QTMIN=5.15.4
+inherit ecm kde.org
+
+DESCRIPTION="KDE Telepathy account management kcm"
+HOMEPAGE="https://community.kde.org/KTp"
+
+LICENSE="LGPL-2.1"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="experimental"
+
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/kaccounts-integration-${PVCUT}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	net-libs/accounts-qt
+	net-libs/signond
+	>=net-libs/telepathy-qt-0.9.8
+"
+DEPEND="${COMMON_DEPEND}
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	net-libs/libaccounts-glib
+"
+RDEPEND="${COMMON_DEPEND}
+	>=kde-apps/kaccounts-providers-${PVCUT}:5
+	net-im/telepathy-connection-managers
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DISABLED_PROVIDERS=$(usex experimental)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if use experimental; then
+		ewarn "Experimental providers are enabled."
+		ewarn "Most of them aren't integrated nicely and may require additional steps for account creation."
+		ewarn "Use at your own risk!"
+	fi
+	ecm_pkg_postinst
+}