kde-apps: Add KDE Release Service 20.04.2

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/kde-apps/kig/Manifest b/kde-apps/kig/Manifest
new file mode 100644
index 0000000000..fe953d2baa
--- /dev/null
+++ b/kde-apps/kig/Manifest
@@ -0,0 +1 @@
+DIST kig-20.04.2.tar.xz 3482912 BLAKE2B 298ccdaeebedd6647ffe6cb53269c90483481633ae5f476578c32a31bd893cf0bace60f28bd2381a3caeb5bc44d85c2197d3842516cccb46735b994d6e9893ed SHA512 54055ceae86d780b6be44b97cd56dfe252db5a8e3b9d9bdd66320a500fbec3769b79731260f2b5a40f5c6cd9deb8c26fa0e2cab5dbb9ccf0b7c0da19c4b31fa5
diff --git a/kde-apps/kig/kig-20.04.2.ebuild b/kde-apps/kig/kig-20.04.2.ebuild
new file mode 100644
index 0000000000..74fde97c6f
--- /dev/null
+++ b/kde-apps/kig/kig-20.04.2.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+PYTHON_COMPAT=( python3_{7,8} )
+KFMIN=5.70.0
+QTMIN=5.14.1
+inherit python-single-r1 ecm kde.org
+
+DESCRIPTION="KDE Interactive Geometry tool"
+HOMEPAGE="https://kde.org/applications/education/org.kde.kig
+https://edu.kde.org/kig/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="geogebra scripting"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	geogebra? ( >=dev-qt/qtxmlpatterns-${QTMIN}:5 )
+	scripting? (
+		$(python_gen_cond_dep '
+			>=dev-libs/boost-1.48:=[python,${PYTHON_MULTI_USEDEP}]
+		')
+	)
+"
+DEPEND="${RDEPEND}
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-4.12.0-boostpython.patch )
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_prepare() {
+	ecm_src_prepare
+	python_fix_shebang .
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package geogebra Qt5XmlPatterns)
+		$(cmake_use_find_package scripting BoostPython)
+	)
+
+	ecm_src_configure
+}