kde-apps/dolphin-plugins-dropbox: 20.11.80 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 65 insertions, 0 deletions

diff --git a/kde-apps/dolphin-plugins-dropbox/Manifest b/kde-apps/dolphin-plugins-dropbox/Manifest
new file mode 100644
index 0000000000..a25c9e2591
--- /dev/null
+++ b/kde-apps/dolphin-plugins-dropbox/Manifest
@@ -0,0 +1 @@
+DIST dolphin-plugins-20.11.80.tar.xz 236284 BLAKE2B 9973070f61bccf4426ced0f9c1c4cddac105f4de9312f684ad6c94441624a793e0d37d0c807cfb8ce6695445a080e85ed1b846ed40d513b2115005259534fb53 SHA512 4b59c73d77cf6c8fd39aa5c0db6c2bea386f805b6721a1e171ec91019fd99abb32bc55b73294d6138782896d194c5fb2ddc79d92f0072f47fa4d59112a484b40
diff --git a/kde-apps/dolphin-plugins-dropbox/dolphin-plugins-dropbox-20.11.80.ebuild b/kde-apps/dolphin-plugins-dropbox/dolphin-plugins-dropbox-20.11.80.ebuild
new file mode 100644
index 0000000000..d47fedc1e4
--- /dev/null
+++ b/kde-apps/dolphin-plugins-dropbox/dolphin-plugins-dropbox-20.11.80.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="false"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="dropbox"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.75.0
+QTMIN=5.15.1
+inherit ecm kde.org
+
+DESCRIPTION="Dolphin plugin for Dropbox service integration"
+HOMEPAGE="https://apps.kde.org/en/dolphin_plugins"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	!kde-apps/dolphin-plugins:5
+	net-misc/dropbox-cli
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# solid, qtdbus only required by mountiso
+	ecm_punt_bogus_dep Qt5 DBus
+	ecm_punt_bogus_dep KF5 Solid
+	# delete non-${PN} translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_mountiso=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}