kde-apps/dolphin-plugins-dropbox: 21.04.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 64 insertions, 0 deletions

diff --git a/kde-apps/dolphin-plugins-dropbox/Manifest b/kde-apps/dolphin-plugins-dropbox/Manifest
new file mode 100644
index 0000000000..7f0c6648b4
--- /dev/null
+++ b/kde-apps/dolphin-plugins-dropbox/Manifest
@@ -0,0 +1 @@
+DIST dolphin-plugins-21.04.3.tar.xz 253244 BLAKE2B c5c0e302dfc4eb82e2de1a635824bf8fd2c70bcac65c261253f0e52e7d9242fa339fe2dc619b927b0379477b2c80a22ec210080af8f2370e0a0182af3347df6a SHA512 e4beba0d596782951b149d42e930d76b12a36bea83f35eb0cff9e49b3e02d4b2aa55f4245d4b8708044a49770d477badc964752828eef4caeaefd4f16e5f9dad
diff --git a/kde-apps/dolphin-plugins-dropbox/dolphin-plugins-dropbox-21.04.3.ebuild b/kde-apps/dolphin-plugins-dropbox/dolphin-plugins-dropbox-21.04.3.ebuild
new file mode 100644
index 0000000000..1ae3454402
--- /dev/null
+++ b/kde-apps/dolphin-plugins-dropbox/dolphin-plugins-dropbox-21.04.3.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="false"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="dropbox"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.80.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Dolphin plugin for Dropbox service integration"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	net-misc/dropbox-cli
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# solid, qtdbus only required by mountiso
+	ecm_punt_bogus_dep Qt5 DBus
+	ecm_punt_bogus_dep KF5 Solid
+	# delete non-${PN} translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_mountiso=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}