sys-auth/polkit-qt: Import from Gentoo ebuild repo

Package-Manager: Portage-2.3.28, Repoman-2.3.9

3 files changed, 79 insertions, 0 deletions

diff --git a/sys-auth/polkit-qt/Manifest b/sys-auth/polkit-qt/Manifest
new file mode 100644
index 00000000..f8e02f52
--- /dev/null
+++ b/sys-auth/polkit-qt/Manifest
@@ -0,0 +1 @@
+DIST polkit-qt-1-0.112.0_p20160416.tar.xz 64540 BLAKE2B fbc3631585801f42ff92324576a2bd82d61aa5b24317f95e1182c300073a8e746007fa3409127a50d7d3433c5092f56d72e2e579683d08145067d4424c4dfe7e SHA512 90677af780a2bbcb33b6a54702ba96f965eb8561f2636af7aa0146f9b2450f9e89f67e022ffa99742afe50e3d1f570eabfad686e9e08e629a1e662d9f5abf2ea
diff --git a/sys-auth/polkit-qt/metadata.xml b/sys-auth/polkit-qt/metadata.xml
new file mode 100644
index 00000000..6f49eba8
--- /dev/null
+++ b/sys-auth/polkit-qt/metadata.xml
@@ -0,0 +1,5 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<!-- maintainer-needed -->
+</pkgmetadata>
diff --git a/sys-auth/polkit-qt/polkit-qt-0.112.0_p20160416-r1.ebuild b/sys-auth/polkit-qt/polkit-qt-0.112.0_p20160416-r1.ebuild
new file mode 100644
index 00000000..3d97e631
--- /dev/null
+++ b/sys-auth/polkit-qt/polkit-qt-0.112.0_p20160416-r1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+MY_P="${P/qt/qt-1}"
+
+inherit cmake-utils multibuild
+
+DESCRIPTION="PolicyKit Qt API wrapper library"
+HOMEPAGE="https://www.kde.org/"
+SRC_URI="https://dev.gentoo.org/~kensington/distfiles/${MY_P}.tar.xz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 ppc ppc64 x86 ~x86-fbsd"
+IUSE="debug examples qt4"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	>=sys-auth/polkit-0.103
+	examples? ( dev-qt/qtxml:5 )
+	qt4? (
+		dev-qt/qtcore:4[glib]
+		dev-qt/qtdbus:4
+		dev-qt/qtgui:4[glib]
+	)
+"
+DEPEND="${RDEPEND}"
+
+DOCS=( AUTHORS README README.porting TODO )
+
+S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+	MULTIBUILD_VARIANTS=( $(usev qt4) qt5 )
+}
+
+src_configure() {
+	myconfigure() {
+		local mycmakeargs=(
+			-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+			-DBUILD_EXAMPLES=$(usex examples)
+		)
+
+		if [[ ${MULTIBUILD_VARIANT} = qt4 ]] ; then
+			mycmakeargs+=( -DUSE_QT4=ON )
+		fi
+		if [[ ${MULTIBUILD_VARIANT} = qt5 ]] ; then
+			mycmakeargs+=( -DUSE_QT5=ON )
+		fi
+
+		cmake-utils_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake-utils_src_compile
+}
+
+src_test() {
+	multibuild_foreach_variant cmake-utils_src_test
+}
+
+src_install() {
+	multibuild_foreach_variant cmake-utils_src_install
+}