blob: e94fc9d600d3bac711775474946e96b649ba6019 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
|
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $
EAPI=5
inherit eutils games toolchain-funcs flag-o-matic check-reqs
MY_PN="${PN^}"
DESCRIPTION="Fork of Nexuiz, Deathmatch FPS based on DarkPlaces, an advanced Quake 1 engine"
HOMEPAGE="http://www.xonotic.org/"
SRC_URI="http://dl.xonotic.org/${P}.zip"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa ode opengl +s3tc +sdl +server"
REQUIRED_USE="
|| ( opengl sdl server )
"
UIRDEPEND="
media-libs/libogg
media-libs/libtheora[encode]
media-libs/libvorbis
media-libs/libmodplug
x11-libs/libX11
virtual/opengl
media-libs/freetype:2
s3tc? ( media-libs/libtxc_dxtn )
"
RDEPEND="
sys-libs/zlib
virtual/jpeg
media-libs/libpng:0=
net-misc/curl
>=dev-libs/d0_blind_id-0.5
ode? ( dev-games/ode[double-precision] )
opengl? (
${UIRDEPEND}
x11-libs/libXext
x11-libs/libXpm
x11-libs/libXxf86vm
alsa? ( media-libs/alsa-lib )
)
sdl? (
${UIRDEPEND}
media-libs/libsdl[X,audio,joystick,opengl,video,alsa?]
)
"
DEPEND="${RDEPEND}
opengl? (
x11-proto/xextproto
x11-proto/xf86vidmodeproto
x11-proto/xproto
)
"
S="${WORKDIR}/${MY_PN}"
CHECKREQS_DISK_BUILD="2100M"
CHECKREQS_DISK_USR="950M"
pkg_pretend() {
check-reqs_pkg_pretend
}
pkg_setup() {
check-reqs_pkg_setup
games_pkg_setup
}
src_prepare() {
tc-export CC
# Required for DP_PRELOAD_DEPENDENCIES=1
append-ldflags $(no-as-needed)
epatch_user
sed -i \
-e "/^EXE_/s:darkplaces:${PN}:" \
-e "/^OPTIM_RELEASE=/s:$: ${CFLAGS}:" \
-e "/^LDFLAGS_RELEASE=/s:$: ${LDFLAGS}:" \
source/darkplaces/makefile.inc || die
if use !alsa; then
sed -e "/DEFAULT_SNDAPI/s:ALSA:OSS:" \
-i source/darkplaces/makefile || die
fi
}
src_compile() {
local targets=""
local i
use opengl && targets+=" cl-release"
use sdl && targets+=" sdl-release"
use server && targets+=" sv-release"
cd source/darkplaces || die
for i in ${targets}; do
emake STRIP=true \
DP_FS_BASEDIR="${GAMES_DATADIR}/${PN}" \
DP_PRELOAD_DEPENDENCIES=1 \
${i}
done
}
src_install() {
if use opengl; then
dogamesbin source/darkplaces/${PN}-glx
make_desktop_entry ${PN}-glx "${MY_PN} (GLX)"
fi
if use sdl; then
dogamesbin source/darkplaces/${PN}-sdl
make_desktop_entry ${PN}-sdl "${MY_PN} (SDL)"
fi
if use opengl || use sdl; then
newicon misc/logos/icons_png/${PN}_512.png ${PN}.png
fi
use server && dogamesbin source/darkplaces/${PN}-dedicated
dodoc Docs/*.txt
dohtml -r Docs
insinto "${GAMES_DATADIR}/${PN}"
# public key for d0_blind_id
doins key_0.d0pk
use server && doins -r server
doins -r data
prepgamesdirs
}
|
GitWeb