Bump python version to current portage stable.

2 files changed, 322 insertions, 0 deletions

diff --git a/dev-lang/python/Manifest b/dev-lang/python/Manifest
index 770afc7..ada4b4d 100644
--- a/dev-lang/python/Manifest
+++ b/dev-lang/python/Manifest
@@ -24,8 +24,10 @@ DIST Python-2.6.4.tar.bz2 11249486 RMD160 fd33853842110fa3636dd296f2f27646fd2b15
 DIST python-gentoo-patches-2.5.4-r2.tar.bz2 20722 RMD160 86c25ad3647b7a3ca44c8e781a4572187d6c1934 SHA1 a859d75092303ee445cebd7af4221beeed58b74d SHA256 54236f25147bb26e15f6f204975513515410292a343b6dfb2116806aa9123afc
 DIST python-gentoo-patches-2.6.2-r1.tar.bz2 9706 RMD160 8868231a1759cfeb4497c409f4aaf71329c1675f SHA1 0c48800969cf50fa93fc2657f5106d332b9d4c05 SHA256 13b40e4f9ef89b7440606d437daed8617c39219e73aa3605c5157e0f09c703df
 DIST python-gentoo-patches-2.6.2-r5.tar.bz2 12206 RMD160 43f321ac4df2b4c6ccb5777d3627c089d46b9024 SHA1 2e35f77a7216b61a9aac9508eac2ddce882c993a SHA256 f3e1593911130ed4bb5879c13e5afa4edd0a873682e1e8609184ec24cae244e1
+DIST python-gentoo-patches-2.6.4-r1.tar.bz2 12570 RMD160 2a58eb651ce5adc68c4667fb0ddc42cc215ea342 SHA1 c5de0442890bc0753c445a88390d932e629c8648 SHA256 2fe6c8838df2c07d3232ebb26c128dab2787c43a76ddb0b55acec1bed657f9f2
 DIST python-gentoo-patches-2.6.4.tar.bz2 11032 RMD160 83903892ef18880f876e7a140c803c1e8a67e24b SHA1 51d4174b2a4136a11c64ae0007b59e4c2f0e13f2 SHA256 19a66a0855df270c030438f21c29260e7ff69b299830409f6aa9140611b721e2
 EBUILD python-2.5.4-r3.ebuild 9962 RMD160 b9c89cb2974b233ee43ac12971deaa2e3c2549c3 SHA1 b477647a53d9b958146868dabb4e451161e3d91b SHA256 8ad3de1c73110d0fa1233539d58d75e74dd411e8c955bbbd0b5d967f2e49a5a6
 EBUILD python-2.6.2-r1.ebuild 9374 RMD160 e2b6b466ff8cfa363d5af68aadd9189daa9bdbfd SHA1 3d207025be7d8ad30f548a351a695dbec641b227 SHA256 cce9f301cae10a0c8e6ce29a9161f3c72b0cf91d372dfbb18006d28ccbde9b8f
 EBUILD python-2.6.2-r2.ebuild 11162 RMD160 9f3215c3353f41a7427334b22d1dd00c54e852eb SHA1 7c8b87d5abcb511bb0e6c85871e0c4098d0be41c SHA256 2e431e703e3b255f619e45295c529a7abb13898014330d6d2aeea474da36a424
+EBUILD python-2.6.4-r1.ebuild 10108 RMD160 3a3695ec07eb7486ab8225068126ed8f5b3c7fde SHA1 9dcb4f47f31bf297051f621e8cd604a4aa4edddb SHA256 d810ad160594b4003ce57d4e025fe91f2209778f6524c7dccbcd5238d2d79173
 EBUILD python-2.6.4.ebuild 10901 RMD160 b93e3e3c93b83778014b007476f12c2a8014e354 SHA1 4c95cc7084aeab1a576e64f8b682335c7ed0911a SHA256 fc21b47629be944003757b39ad4c846b567708f96a718dc8228d08624a7925ef
diff --git a/dev-lang/python/python-2.6.4-r1.ebuild b/dev-lang/python/python-2.6.4-r1.ebuild
new file mode 100644
index 0000000..88c5616
--- /dev/null
+++ b/dev-lang/python/python-2.6.4-r1.ebuild
@@ -0,0 +1,320 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/python/python-2.6.4-r1.ebuild,v 1.9 2010/03/20 20:33:28 arfrever Exp $
+
+EAPI="2"
+
+inherit autotools eutils flag-o-matic multilib pax-utils python toolchain-funcs
+
+MY_P="Python-${PV}"
+S="${WORKDIR}/${MY_P}"
+
+PATCHSET_REVISION="1"
+
+DESCRIPTION="Python is an interpreted, interactive, object-oriented programming language."
+HOMEPAGE="http://www.python.org/"
+SRC_URI="http://www.python.org/ftp/python/${PV}/${MY_P}.tar.bz2
+	mirror://gentoo/python-gentoo-patches-${PV}$([[ "${PATCHSET_REVISION}" != "0" ]] && echo "-r${PATCHSET_REVISION}").tar.bz2"
+
+LICENSE="PSF-2.2"
+SLOT="2.6"
+PYTHON_ABI="${SLOT}"
+KEYWORDS="alpha amd64 arm hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~sparc-fbsd ~x86-fbsd"
+IUSE="-berkdb build doc elibc_uclibc examples gdbm ipv6 +ncurses +readline sqlite +ssl +threads tk +wide-unicode wininst +xml"
+
+# NOTE: dev-python/{elementtree,celementtree,pysqlite,ctypes}
+#       do not conflict with the ones in python proper. - liquidx
+
+RDEPEND=">=app-admin/eselect-python-20091230
+		>=sys-libs/zlib-1.1.3
+		virtual/libffi
+		virtual/libintl
+		!build? (
+			berkdb? ( || (
+				sys-libs/db:4.7
+				sys-libs/db:4.6
+				sys-libs/db:4.5
+				sys-libs/db:4.4
+				sys-libs/db:4.3
+				sys-libs/db:4.2
+			) )
+			doc? ( dev-python/python-docs:${SLOT} )
+			gdbm? ( sys-libs/gdbm )
+			ncurses? (
+				>=sys-libs/ncurses-5.2
+				readline? ( >=sys-libs/readline-4.1 )
+			)
+			sqlite? ( >=dev-db/sqlite-3 )
+			ssl? ( dev-libs/openssl )
+			tk? ( >=dev-lang/tk-8.0 )
+			xml? ( >=dev-libs/expat-2 )
+		)"
+DEPEND="${RDEPEND}
+		dev-util/pkgconfig
+		!sys-devel/gcc[libffi]"
+RDEPEND+=" !build? ( app-misc/mime-types )"
+PDEPEND="app-admin/python-updater"
+
+PROVIDE="virtual/python"
+
+pkg_setup() {
+	if use berkdb; then
+		ewarn "\"bsddb\" module is out-of-date and no longer maintained inside dev-lang/python. It has"
+		ewarn "been additionally removed in Python 3. You should use external, still maintained \"bsddb3\""
+		ewarn "module provided by dev-python/bsddb3 which supports both Python 2 and Python 3."
+	fi
+}
+
+src_prepare() {
+	# Ensure that internal copies of expat and libffi aren't used.
+	rm -fr Modules/expat
+	rm -fr Modules/_ctypes/libffi*
+
+	if tc-is-cross-compiler; then
+		epatch "${FILESDIR}/python-2.5-cross-printf.patch"
+		epatch "${FILESDIR}/python-2.6-chflags-cross.patch"
+		epatch "${FILESDIR}/python-2.6-test-cross.patch"
+	else
+		rm "${WORKDIR}/${PV}"/*_all_crosscompile.patch
+	fi
+
+	EPATCH_SUFFIX="patch" epatch "${WORKDIR}/${PV}"
+
+	if tc-is-cross-compiler ; then
+		# Change setup.py to respect the SYSROOT environment variable
+		epatch "${FILESDIR}"/python-2.6.4-cross-setup-sysroot.patch
+	fi
+
+	# Add a libdirname to enable python cross-compiling and add a user specifyable libdir
+	epatch "${FILESDIR}"/python-2.5.2-cross-Makefile.pre.in.patch
+	# Make distutils cross-compile aware
+	epatch "${FILESDIR}"/python-2.5.2-cross-distutils-build_ext.patch
+	epatch "${FILESDIR}"/python-2.6-cross-distutils-sysconfig.patch
+	epatch "${FILESDIR}"/python-2.5.2-cross-distutils-install.patch
+
+	sed -i -e "s:@@GENTOO_LIBDIR@@:$(get_libdir):g" \
+		Lib/distutils/command/install.py \
+		Lib/distutils/sysconfig.py \
+		Lib/site.py \
+		Makefile.pre.in \
+		Modules/Setup.dist \
+		Modules/getpath.c \
+		setup.py || die "sed failed to replace @@GENTOO_LIBDIR@@"
+
+	# Fix os.utime() on hppa. utimes it not supported but unfortunately reported as working - gmsoft (22 May 04)
+	# PLEASE LEAVE THIS FIX FOR NEXT VERSIONS AS IT'S A CRITICAL FIX !!!
+	[[ "${ARCH}" == "hppa" ]] && sed -e "s/utimes //" -i "${S}/configure"
+
+	if ! use wininst; then
+		# Remove Microsoft Windows executables.
+		rm Lib/distutils/command/wininst-*.exe
+	fi
+
+	# Fix OtherFileTests.testStdin() not to assume
+	# that stdin is a tty for bug #248081.
+	sed -e "s:'osf1V5':'osf1V5' and sys.stdin.isatty():" -i Lib/test/test_file.py || die "sed failed"
+
+	eautoreconf
+}
+
+src_configure() {
+	# Disable extraneous modules with extra dependencies.
+	if use build; then
+		export PYTHON_DISABLE_MODULES="dbm _bsddb gdbm _curses _curses_panel readline _sqlite3 _tkinter _elementtree pyexpat"
+		export PYTHON_DISABLE_SSL="1"
+	else
+		# dbm module can be linked against berkdb or gdbm.
+		# Defaults to gdbm when both are enabled, #204343.
+		local disable
+		use berkdb   || use gdbm || disable+=" dbm"
+		use berkdb   || disable+=" _bsddb"
+		use gdbm     || disable+=" gdbm"
+		use ncurses  || disable+=" _curses _curses_panel"
+		use readline || disable+=" readline"
+		use sqlite   || disable+=" _sqlite3"
+		use ssl      || export PYTHON_DISABLE_SSL="1"
+		use tk       || disable+=" _tkinter"
+		use xml      || disable+=" _elementtree pyexpat" # _elementtree uses pyexpat.
+		export PYTHON_DISABLE_MODULES="${disable}"
+
+		if ! use xml; then
+			ewarn "You have configured Python without XML support."
+			ewarn "This is NOT a recommended configuration as you"
+			ewarn "may face problems parsing any XML documents."
+		fi
+	fi
+
+	if [[ -n "${PYTHON_DISABLE_MODULES}" ]]; then
+		einfo "Disabled modules: ${PYTHON_DISABLE_MODULES}"
+	fi
+
+	if [[ "$(gcc-major-version)" -ge 4 ]]; then
+		append-flags -fwrapv
+	fi
+
+	export OPT="${CFLAGS}"
+
+	filter-flags -malign-double
+
+	[[ "${ARCH}" == "alpha" ]] && append-flags -fPIC
+
+	# https://bugs.gentoo.org/show_bug.cgi?id=50309
+	if is-flag -O3; then
+		is-flag -fstack-protector-all && replace-flags -O3 -O2
+		use hardened && replace-flags -O3 -O2
+	fi
+
+	if tc-is-cross-compiler; then
+		OPT="-O1" CFLAGS="" LDFLAGS="" CC="" \
+		./configure --{build,host}=${CBUILD} || die "cross-configure failed"
+		emake python Parser/pgen || die "cross-make failed"
+		mv python hostpython
+		mv Parser/pgen Parser/hostpgen
+		make distclean
+		sed -i \
+			-e "/^HOSTPYTHON/s:=.*:=./hostpython:" \
+			-e "/^HOSTPGEN/s:=.*:=./Parser/hostpgen:" \
+			Makefile.pre.in || die "sed failed"
+	fi
+
+	# Export CXX so it ends up in /usr/lib/python2.X/config/Makefile.
+	tc-export CXX
+
+	# Set LDFLAGS so we link modules with -lpython2.6 correctly.
+	# Needed on FreeBSD unless Python 2.6 is already installed.
+	# Please query BSD team before removing this!
+	append-ldflags "-L."
+
+	econf \
+		--with-fpectl \
+		--enable-shared \
+		$(use_enable ipv6) \
+		$(use_with threads) \
+		$(use wide-unicode && echo "--enable-unicode=ucs4" || echo "--enable-unicode=ucs2") \
+		--infodir='${prefix}/share/info' \
+		--mandir='${prefix}/share/man' \
+		--with-libc="" \
+		--with-system-ffi
+}
+
+src_test() {
+	# Tests won't work when cross compiling.
+	if tc-is-cross-compiler; then
+		elog "Disabling tests due to crosscompiling."
+		return
+	fi
+
+	# Byte compiling should be enabled here.
+	# Otherwise test_import fails.
+	python_enable_pyc
+
+	# Skip all tests that fail during emerge but pass without emerge:
+	# (See bug #67970)
+	local skip_tests="distutils httpservers minidom pyexpat sax tcl"
+
+	# test_ctypes fails with PAX kernel (bug #234498).
+	host-is-pax && skip_tests+=" ctypes"
+
+	for test in ${skip_tests}; do
+		mv "${S}/Lib/test/test_${test}.py" "${T}"
+	done
+
+	# Rerun failed tests in verbose mode (regrtest -w).
+	EXTRATESTOPTS="-w" make test || die "make test failed"
+
+	for test in ${skip_tests}; do
+		mv "${T}/test_${test}.py" "${S}/Lib/test/test_${test}.py"
+	done
+
+	elog "The following tests have been skipped:"
+	for test in ${skip_tests}; do
+		elog "test_${test}.py"
+	done
+
+	elog "If you'd like to run them, you may:"
+	elog "cd $(python_get_libdir)/test"
+	elog "and run the tests separately."
+
+	python_disable_pyc
+}
+
+src_install() {
+	emake DESTDIR="${D}" altinstall maninstall || die "emake altinstall maninstall failed"
+
+	mv "${D}usr/bin/python${SLOT}-config" "${D}usr/bin/python-config-${SLOT}"
+
+	# Fix collisions between different slots of Python.
+	mv "${D}usr/bin/2to3" "${D}usr/bin/2to3-${SLOT}"
+	mv "${D}usr/bin/pydoc" "${D}usr/bin/pydoc${SLOT}"
+	mv "${D}usr/bin/idle" "${D}usr/bin/idle${SLOT}"
+	mv "${D}usr/share/man/man1/python.1" "${D}usr/share/man/man1/python${SLOT}.1"
+	rm -f "${D}usr/bin/smtpd.py"
+
+	# Fix the OPT variable so that it doesn't have any flags listed in it.
+	# Prevents the problem with compiling things with conflicting flags later.
+	sed -e "s:^OPT=.*:OPT=\t\t-DNDEBUG:" -i "${D}$(python_get_libdir)/config/Makefile"
+
+	if use build; then
+		rm -fr "${D}usr/bin/idle${SLOT}" "${D}$(python_get_libdir)/"{bsddb,idlelib,lib-tk,sqlite3,test}
+	else
+		use elibc_uclibc && rm -fr "${D}$(python_get_libdir)/"{bsddb/test,test}
+		use berkdb || rm -fr "${D}$(python_get_libdir)/"{bsddb,test/test_bsddb*}
+		use sqlite || rm -fr "${D}$(python_get_libdir)/"{sqlite3,test/test_sqlite*}
+		use tk || rm -fr "${D}usr/bin/idle${SLOT}" "${D}$(python_get_libdir)/"{idlelib,lib-tk}
+	fi
+
+	use threads || rm -fr "${D}$(python_get_libdir)/multiprocessing"
+
+	prep_ml_includes $(python_get_includedir)
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins -r "${S}/Tools" || die "doins failed"
+	fi
+
+	newinitd "${FILESDIR}/pydoc.init" pydoc-${SLOT}
+	newconfd "${FILESDIR}/pydoc.conf" pydoc-${SLOT}
+
+	# Don't install empty directory.
+	rmdir "${D}$(python_get_libdir)/lib-old"
+}
+
+pkg_preinst() {
+	if has_version "<${CATEGORY}/${PN}-${SLOT}" && ! has_version ">=${CATEGORY}/${PN}-${SLOT}_alpha"; then
+		python_updater_warning="1"
+	fi
+}
+
+eselect_python_update() {
+	local eselect_python_options=
+	[[ "$(eselect python show)" == "python2."* ]] && eselect_python_options="--python2"
+
+	# Create python2 symlink.
+	eselect python update --python2 > /dev/null
+
+	eselect python update ${eselect_python_options}
+}
+
+pkg_postinst() {
+	eselect_python_update
+
+	python_mod_optimize -x "(site-packages|test)" $(python_get_libdir)
+
+	if [[ "${python_updater_warning}" == "1" ]]; then
+		ewarn
+		ewarn "\e[1;31m************************************************************************\e[0m"
+		ewarn
+		ewarn "You have just upgraded from an older version of Python."
+		ewarn "You should run 'python-updater \${options}' to rebuild Python modules."
+		ewarn
+		ewarn "\e[1;31m************************************************************************\e[0m"
+		ewarn
+		ebeep 12
+	fi
+}
+
+pkg_postrm() {
+	eselect_python_update
+
+	python_mod_cleanup $(python_get_libdir)
+}