1 files changed, 61 insertions, 0 deletions
diff --git a/dev-db/mongodb/mongodb-1.8.0.ebuild b/dev-db/mongodb/mongodb-1.8.0.ebuild
new file mode 100644
index 0000000..3849f20
--- /dev/null
+++ b/dev-db/mongodb/mongodb-1.8.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="2"
+
+SCONS_MIN_VERSION="1.2.0"
+MY_P="${PN}-src-r${PV/_rc/-rc}"
+
+inherit eutils scons-utils versionator
+
+DESCRIPTION="A high-performance, open source, schema-free document-oriented database"
+HOMEPAGE="http://www.mongodb.org"
+SRC_URI="http://downloads.mongodb.org/src/${MY_P}.tar.gz"
+
+LICENSE="AGPL-3 Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	dev-lang/spidermonkey[unicode]
+	dev-libs/boost
+	dev-libs/libpcre
+	net-libs/libpcap
+"
+
+DEPEND="${RDEPEND}
+	sys-libs/readline
+	sys-libs/ncurses
+"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	enewgroup mongodb
+	enewuser mongodb -1 -1 /var/lib/${PN} mongodb
+}
+
+src_compile() {
+	escons all || die "Compile failed"
+}
+
+src_install() {
+	escons --full --nostrip install --prefix="${D}"/usr || die "Install failed"
+
+	for x in /var/{lib,log,run}/${PN}; do
+		dodir "${x}" || die "Install failed"
+		fowners mongodb:mongodb "${x}"
+	done
+
+	doman debian/mongo*.1 || die "Install failed"
+	dodoc README docs/building.md
+
+	newinitd "${FILESDIR}/${PN}.initd" ${PN} || die "Install failed"
+	newconfd "${FILESDIR}/${PN}.confd" ${PN} || die "Install failed"
+}
+
+src_test() {
+	escons smoke --smokedbprefix='testdir' test || die "Tests failed"
+}