sys-fs/ecryptfs-utils/ecryptfs-utils-33.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/ecryptfs-utils/ecryptfs-utils-33.ebuild,v 1.1 2007/12/14 18:14:21 alonbl Exp $

inherit eutils

DESCRIPTION="eCryptfs userspace utilities"
HOMEPAGE="http://www.ecryptfs.org"
SRC_URI="mirror://sourceforge/ecryptfs/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="suid pam gtk openssl pkcs11 gpg doc"

RDEPEND="sys-apps/keyutils
	dev-libs/libgcrypt
	pam? ( sys-libs/pam )
	openssl? ( dev-libs/openssl )
	pkcs11? (
		dev-libs/openssl
		>=dev-libs/pkcs11-helper-1.04
	)
	gpg? ( app-crypt/gpgme )
	gtk? ( x11-libs/gtk+ )"
# perl required for man generation
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	dev-lang/perl"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${P}-mkdir.patch"
}

src_compile() {
	econf \
		--docdir="/usr/share/doc/${PF}" \
		$(use_enable pam) \
		$(use_enable openssl) \
		$(use_enable pkcs11 pkcs11-helper) \
		$(use_enable gpg) \
		$(use_enable gtk gui) \
		$(use_enable doc docs) \
		|| die
	emake || die
}

src_install(){
	emake DESTDIR="${D}" install || die
	use suid && fperms u+s /sbin/mount.ecryptfs
}

pkg_postinst() {
	if use suid; then
		ewarn
		ewarn "You have chosen to install ${PN} with the binary setuid root. This"
		ewarn "means that if there any undetected vulnerabilities in the binary,"
		ewarn "then local users may be able to gain root access on your machine."
		ewarn
	fi
}