blob: 5b508afed3f116f36d2b8c226b8863200ecb9773 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
|
# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/hal/hal-0.5.5.1-r3.ebuild,v 1.2 2006/01/04 01:02:24 vapier Exp $
inherit eutils linux-info debug
DESCRIPTION="Hardware Abstraction Layer"
HOMEPAGE="http://www.freedesktop.org/Software/hal"
SRC_URI="http://freedesktop.org/~david/dist/${P}.tar.gz"
LICENSE="|| ( GPL-2 AFL-2.0 )"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="acpi debug doc pam_console pcmcia"
RDEPEND=">=dev-libs/glib-2.6
>=sys-apps/dbus-0.50
>=sys-fs/udev-071
>=sys-apps/util-linux-2.12i
|| ( >=sys-kernel/linux-headers-2.6 >=sys-kernel/mips-headers-2.6 )
dev-libs/expat
dev-libs/libusb
sys-apps/hotplug
pam_console? ( sys-libs/pam )"
DEPEND="${RDEPEND}
dev-util/pkgconfig
>=dev-util/intltool-0.29
doc? ( app-doc/doxygen app-text/docbook-sgml-utils )"
## HAL Daemon drops privledges so we need group access to read disks
HALDAEMON_GROUPS="haldaemon,disk,cdrom,cdrw,floppy,usb"
function notify_uevent() {
eerror
eerror "You must enable Kernel Userspace Events in your kernel."
eerror "This can be set under 'General Setup'. It is marked as"
eerror "CONFIG_KOBJECT_UEVENT in the config file."
eerror
ebeep 5
die "KOBJECT_UEVENT is not set"
}
pkg_setup() {
linux-info_pkg_setup
kernel_is ge 2 6 13 \
|| die "You need a 2.6.13 or newer kernel to run this package"
if kernel_is lt 2 6 15; then
linux_chkconfig_present KOBJECT_UEVENT || notify_uevent
fi
if use acpi ; then
linux_chkconfig_present PROC_FS \
|| die "ACPI support requires PROC_FS support in kernel"
fi
if use pam_console && ! built_with_use sys-libs/pam pam_console ; then
eerror "You need to build pam with pam_console support"
eerror "Please remerge sys-libs/pam with USE=pam_console"
die "pam without pam_console detected"
fi
if [ -d "${ROOT}"/etc/hal/device.d ]; then
eerror "HAL 0.5.x will not run with the HAL 0.4.x series of"
eerror "/etc/hal/device.d/ so please remove this directory"
eerror "with rm -rf /etc/hal/device.d/ and then re-emerge."
eerror "This is due to configuration protection of /etc/"
die "remove /etc/hal/device.d/"
fi
}
src_unpack() {
unpack "${A}"
cd "${S}"
epatch "${FILESDIR}"/${P}-RBC.patch
# remove pamconsole option
use pam_console || epatch "${FILESDIR}"/${PN}-0.5.1-old_storage_policy.patch
}
src_compile() {
econf \
--with-doc-dir=/usr/share/doc/${PF} \
--with-os-type=gentoo \
--with-pid-file=/var/run/hald.pid \
$(use_enable debug verbose-mode) \
$(use_enable pcmcia pcmcia-support) \
$(use_enable acpi acpi-proc) \
$(use_enable doc docbook-docs) \
$(use_enable doc doxygen-docs) \
|| die "configure failed"
# --disable-acpi-acpid when HAL handles all that acpid handles
emake || die "make failed"
}
src_install() {
make DESTDIR="${D}" install || die
# We install this in a seperate package to avoid gnome-python dep
rm "${D}"/usr/bin/hal-device-manager
# initscript
newinitd "${FILESDIR}"/0.5-hald.rc hald
dodoc AUTHORS COPYING ChangeLog INSTALL NEWS README
# Script to unmount devices if they are yanked out (from upstream)
exeinto /etc/dev.d/default
doexe "${FILESDIR}"/hal-unmount.dev
}
pkg_preinst() {
enewgroup haldaemon || die "Problem adding haldaemon group"
enewuser haldaemon -1 "-1" -1 ${HALDAEMON_GROUPS} || die "Problem adding haldaemon user"
usermod -G ${HALDAEMON_GROUPS} haldaemon
}
pkg_postinst() {
einfo "The HAL daemon needs to be running for certain applications to"
einfo "work. Suggested is to add the init script to your start-up"
einfo "scripts, this should be done like this :"
einfo "\`rc-update add hald default\`"
}
|
GitWeb