net-libs/libfwbuilder/libfwbuilder-3.0.5.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libfwbuilder/libfwbuilder-3.0.5.ebuild,v 1.1 2009/06/27 17:23:33 patrick Exp $

EAPI="2"

inherit qt4

DESCRIPTION="Firewall Builder 3.0 API library and compiler framework"
HOMEPAGE="http://www.fwbuilder.org/"
SRC_URI="mirror://sourceforge/fwbuilder/${P}.tar.gz"
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="bind snmp stlport"

DEPEND=">=dev-libs/libxml2-2.4.10
	>=dev-libs/libxslt-1.0.7
	snmp? ( net-analyzer/net-snmp )
	stlport? ( dev-libs/STLport )
	bind? ( net-dns/bind )
	x11-libs/qt-core"
RDEPEND="${DEPEND}"

src_prepare() {
	qt4_src_prepare

	sed -i \
		-e '/COPYING/d' -e '/INSTALL/d' \
		doc/doc.pro || die "sed failed"

	sed -i \
		-e '/\.\/runqmake\.sh$/d' \
		configure || die "sed configure failed"
}

src_configure() {
	use snmp || export with_ucdsnmp="no"
	econf \
		--with-docdir="/usr/share/doc/${PF}" \
		$(use_with stlport stlport) \
		$(use_with bind lwres)

	for pro_file in $(find "${S}" -name "*.pro"); do
		eqmake4 "${pro_file}" -o "$(dirname ${pro_file})/Makefile" "CONFIG+=nostrip" || die "running eqmake4 for ${pro_file} failed"
	done
}

src_install() {
	emake INSTALL_ROOT="${D}" install || die "emake install failed"
}