net-analyzer/quidscor/quidscor-1.2.48.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/quidscor/quidscor-1.2.48.ebuild,v 1.9 2014/07/20 13:27:27 jer Exp $

EAPI=5
inherit eutils toolchain-funcs

DESCRIPTION="IDS/VA Correlation engine"
HOMEPAGE="http://quidscor.sourceforge.net/"
SRC_URI="mirror://sourceforge/quidscor/${P}-src.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~ppc ~x86"

DEPEND="
	>=dev-libs/libxml2-2.4
	>=net-misc/curl-7.10
	>=net-analyzer/snort-2.0
"
RDEPEND="${DEPEND}"

src_prepare() {
	epatch \
		"${FILESDIR}"/${P}-curl-types.h.patch \
		"${FILESDIR}"/${P}-strip.patch
	sed -i '/^CFLAGS=/s: -g : :' Makefile || die
	#yes, the fix below is as pathetic as it seems
	echo "#define FALSE 0" >> libqg/libqg.h || die
	echo "#define TRUE 1" >> libqg/libqg.h || die
}

src_compile() {
	emake EXTRA_CFLAGS="${CFLAGS}" CC="$(tc-getCC)"
}

src_install() {
	emake PREFIX=/usr STAGING_PREFIX="${D}" install
	dodoc ChangeLog FAQ MANIFEST README TODO
	# fix ugly install
	cd "${D}"/usr || die
	mv etc .. || die
	rm -r doc || die
}