blob: 67610e34aa7d7db10f8b747976ea0477d3e0a197 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
|
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/fail2ban/fail2ban-0.9.0-r2.ebuild,v 1.1 2014/08/22 15:15:59 jer Exp $
EAPI=5
PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} pypy pypy2_0 )
PYTHON_REQ_USE="sqlite"
inherit distutils-r1 systemd vcs-snapshot
DESCRIPTION="scans log files and bans IPs that show malicious signs"
HOMEPAGE="http://www.fail2ban.org/"
SRC_URI="https://github.com/${PN}/${PN}/tarball/${PV} -> ${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="selinux"
DEPEND="selinux? ( sec-policy/selinux-fail2ban )"
RDEPEND="net-misc/whois
virtual/mta
virtual/logger
net-firewall/iptables
selinux? ( sec-policy/selinux-fail2ban )"
DOCS=( ChangeLog DEVELOP README.md THANKS TODO doc/run-rootless.txt )
src_prepare() {
# Replace /var/run with /run, but not in the top source directory
sed -i -e 's|/var\(/run/fail2ban\)|\1|g' $( find . -type f -mindepth 2 ) || die
# Do not install /run/fail2ban
epatch "${FILESDIR}"/${P}-empty-run-dir.patch
# Upstream patches
epatch "${FILESDIR}"/${P}-python3-regex.patch
epatch "${FILESDIR}"/${P}-loglevel-int.patch
distutils-r1_src_prepare
}
python_test() {
${EPYTHON} bin/${PN}-testcases
}
src_install() {
distutils-r1_src_install
rm -rf "${D}"/usr/share/doc/${PN}
# not FILESDIR
newconfd files/gentoo-confd ${PN}
newinitd files/gentoo-initd ${PN}
systemd_dounit files/${PN}.service
systemd_dotmpfilesd files/${PN}-tmpfiles.conf
doman man/*.{1,5}
# Use INSTALL_MASK if you do not want to touch /etc/logrotate.d.
# See http://thread.gmane.org/gmane.linux.gentoo.devel/35675
insinto /etc/logrotate.d
newins files/${PN}-logrotate ${PN}
}
pkg_preinst() {
has_version "<${CATEGORY}/${PN}-0.7"
previous_less_than_0_7=$?
}
pkg_postinst() {
if [[ $previous_less_than_0_7 = 0 ]] ; then
elog
elog "Configuration files are now in /etc/fail2ban/"
elog "You probably have to manually update your configuration"
elog "files before restarting Fail2ban!"
elog
elog "Fail2ban is not installed under /usr/lib anymore. The"
elog "new location is under /usr/share."
elog
elog "You are upgrading from version 0.6.x, please see:"
elog "http://www.fail2ban.org/wiki/index.php/HOWTO_Upgrade_from_0.6_to_0.8"
fi
if ! has_version ${CATEGORY}/${PN}; then
if ! has_version dev-python/pyinotify && ! has_version app-admin/gamin; then
elog "For most jail.conf configurations, it is recommended you install either"
elog "dev-python/pyinotify or app-admin/gamin (in order of preference)"
elog "to control how log file modifications are detected"
fi
if ! has_version dev-lang/python[sqlite]; then
elog "If you want to use ${PN}'s persistent database, then reinstall"
elog "dev-lang/python with USE=sqlite"
fi
if has_version sys-apps/systemd[-python]; then
elog "If you want to track logins through sys-apps/systemd's"
elog "journal backend, then reinstall sys-apps/systemd with USE=python"
fi
fi
}
|
GitWeb