dev-util/objconv/objconv-2.32_pre20131127.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/objconv/objconv-2.32_pre20131127.ebuild,v 1.1 2014/07/28 14:29:15 slyfox Exp $

EAPI=5

inherit toolchain-funcs unpacker

DESCRIPTION="object code file converted (COFF, ELF, OMF, MACHO)"
HOMEPAGE="http://agner.org/optimize/#objconv"
# original URL is "http://agner.org/optimize/objconv.zip", but it's unversioned.
# I copy those to distfiles time to time
SRC_URI="http://dev.gentoo.org/~slyfox/distfiles/${P}.zip"
LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~amd64 ~x86"

RDEPEND=""
DEPEND=""

S=${WORKDIR}/${P}

src_unpack() {
	unpacker_src_unpack
	mkdir "${S}" || die
	pushd "${S}" || die
	unpack_zip ../source.zip
}

src_prepare() {
	# project has extremenly poor build system (see build.sh)
	local sources=$(echo *.cpp)

	{
		echo "objconv: ${sources//.cpp/.o}"
		echo "	\$(CXX) -o \$@ \$^ \$(LDFLAGS)"
	} > Makefile || die

	tc-export CXX
}

src_install() {
	dobin objconv
	dodoc ../objconv-instructions.pdf
}