blob: a4a215d4a21767142e7682c14ff9b0afa77d15ee (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/eventmachine/eventmachine-1.0.3-r1.ebuild,v 1.2 2013/12/22 19:18:13 blueness Exp $
EAPI=5
# jruby → has shims for Java handling but tests fail badly, remaining
# stuck; avoid that for now.
USE_RUBY="ruby18 ruby19 ruby20"
RUBY_FAKEGEM_TASK_DOC="yard"
RUBY_FAKEGEM_DOCDIR="rdoc"
RUBY_FAKEGEM_EXTRADOC="docs/*.md README.md"
inherit ruby-fakegem
DESCRIPTION="EventMachine is a fast, simple event-processing library for Ruby programs."
HOMEPAGE="http://rubyeventmachine.com"
LICENSE="|| ( GPL-2 Ruby )"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
IUSE=""
DEPEND="${DEPEND}
dev-libs/openssl"
RDEPEND="${RDEPEND}
dev-libs/openssl"
ruby_add_bdepend "doc? ( dev-ruby/yard )"
all_ruby_prepare() {
# Remove package tasks to avoid dependency on rake-compiler.
rm rakelib/package.rake || die
# fix test issue - upstream b96b736b39261f7d74f013633cc7cd619afa20c4
sed -i -e 's/DEBUG/BROADCAST/g' tests/test_set_sock_opt.rb || die
# Remove the resolver tests since they require network access and
# the localhost test fails with an IPv6 localhost.
rm tests/test_resolver.rb || die
}
each_ruby_configure() {
for extdir in ext ext/fastfilereader; do
pushd $extdir
${RUBY} extconf.rb || die "extconf.rb failed for ${extdir}"
popd
done
}
each_ruby_compile() {
for extdir in ext ext/fastfilereader; do
pushd $extdir
# both extensions use C++, so use the CXXFLAGS not the CFLAGS
emake V=1 CFLAGS="${CXXFLAGS} -fPIC" archflag="${LDFLAGS}" || die "emake failed for ${extdir}"
popd
cp $extdir/*.so lib/ || die "Unable to copy extensions for ${extdir}"
done
}
each_ruby_test() {
${RUBY} -Ilib -S testrb tests/test_*.rb || die
}
all_ruby_install() {
all_fakegem_install
insinto /usr/share/doc/${PF}/
doins -r examples || die "Failed to install examples"
}
|
GitWeb
