blob: cbe301197fa8652aba3959a4bf90e9e264b56beb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
|
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/k3b-2.0.1-r1.ebuild,v 1.1 2010/12/13 14:04:16 scarabeus Exp $
EAPI=3
CMAKE_MIN_VERSION=2.8.0
MULTIMEDIA_REQUIRED=always
WEBKIT_REQUIRED=always
KMNAME="extragear/multimedia"
# Translations are only in the tarballs, not in the svn repo
if [[ ${PV} != *9999* ]]; then
KDE_LINGUAS="ast be bg ca ca@valencia cs csb da de el en_GB eo es et eu fi fr ga
gl he hi hne hr hu is it ja km ko ku lt mai nb nds nl nn oc pa pl pt pt_BR ro ru
se sk sl sv th tr uk zh_CN zh_TW"
SRC_URI="mirror://sourceforge/${PN}/${P/_}.tar.bz2"
DOCS=( FAQ PERMISSIONS README RELEASE_HOWTO )
S=${WORKDIR}/${P/_*}
else
DOCS=( FAQ.txt PERMISSIONS.txt README.txt )
fi
inherit kde4-base
DESCRIPTION="The CD/DVD Kreator for KDE"
HOMEPAGE="http://www.k3b.org/"
LICENSE="GPL-2 FDL-1.2"
SLOT="4"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="debug dvd emovix encode ffmpeg flac mad lame musepack musicbrainz sndfile sox taglib vcd vorbis +wav"
DEPEND="
$(add_kdebase_dep libkcddb)
media-libs/libsamplerate
dvd? ( media-libs/libdvdread )
ffmpeg? ( >=media-video/ffmpeg-0.5 )
flac? ( >=media-libs/flac-1.2[cxx] )
encode? ( lame? ( media-sound/lame ) )
mad? ( media-libs/libmad )
musepack? ( >=media-sound/musepack-tools-444 )
musicbrainz? ( media-libs/musicbrainz:1 )
sndfile? ( media-libs/libsndfile )
taglib? ( >=media-libs/taglib-1.5 )
vorbis? ( media-libs/libvorbis )
"
RDEPEND="${DEPEND}
app-cdr/cdrdao
media-sound/cdparanoia
sys-apps/hal
virtual/cdrtools
dvd? (
>=app-cdr/dvd+rw-tools-7
encode? ( media-video/transcode[dvd] )
)
emovix? ( media-video/emovix )
encode? ( sox? ( media-sound/sox ) )
vcd? ( media-video/vcdimager )
"
DOCS+=( ChangeLog )
PATCHES=( "${FILESDIR}/${PV}-fix-crash-with-qt-4.7.0.patch" )
src_configure() {
mycmakeargs=(
-DK3B_BUILD_K3BSETUP=OFF
$(cmake-utils_use debug K3B_DEBUG)
$(cmake-utils_use musicbrainz K3B_ENABLE_MUSICBRAINZ)
$(cmake-utils_use dvd K3B_ENABLE_DVD_RIPPING)
$(cmake-utils_use taglib K3B_ENABLE_TAGLIB)
-DK3B_BUILD_API_DOCS=OFF
$(cmake-utils_use ffmpeg K3B_BUILD_FFMPEG_DECODER_PLUGIN)
$(cmake-utils_use vorbis K3B_BUILD_OGGVORBIS_DECODER_PLUGIN)
$(cmake-utils_use mad K3B_BUILD_MAD_DECODER_PLUGIN)
$(cmake-utils_use musepack K3B_BUILD_MUSE_DECODER_PLUGIN)
$(cmake-utils_use flac K3B_BUILD_FLAC_DECODER_PLUGIN)
$(cmake-utils_use sndfile K3B_BUILD_SNDFILE_DECODER_PLUGIN)
$(cmake-utils_use wav K3B_BUILD_WAVE_DECODER_PLUGIN)
$(cmake-utils_use encode K3B_BUILD_EXTERNAL_ENCODER_PLUGIN)
)
if use encode; then
mycmakeargs+=(
$(cmake-utils_use vorbis K3B_BUILD_OGGVORBIS_ENCODER_PLUGIN)
$(cmake-utils_use lame K3B_BUILD_LAME_ENCODER_PLUGIN)
$(cmake-utils_use sox K3B_BUILD_SOX_ENCODER_PLUGIN)
)
fi
kde4-base_src_configure
}
pkg_postinst() {
kde4-base_pkg_postinst
echo
elog "We don't install k3bsetup anymore because Gentoo doesn't need it."
elog "If you get warnings on start-up, uncheck the \"Check system"
elog "configuration\" option in the \"Misc\" settings window."
echo
local group=cdrom
use kernel_linux || group=operator
elog "Make sure you have proper read/write permissions on the cdrom device(s)."
elog "Usually, it is sufficient to be in the ${group} group."
echo
}
|
GitWeb