1 files changed, 50 insertions, 0 deletions
diff --git a/x11-libs/libQGLViewer/libQGLViewer-2.5.3.ebuild b/x11-libs/libQGLViewer/libQGLViewer-2.5.3.ebuild
new file mode 100644
index 000000000000..9a4bc4390f21
--- /dev/null
+++ b/x11-libs/libQGLViewer/libQGLViewer-2.5.3.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libQGLViewer/libQGLViewer-2.5.3.ebuild,v 1.1 2014/10/28 17:30:52 aballier Exp $
+
+EAPI="5"
+
+inherit qt4-r2 multilib flag-o-matic
+
+DESCRIPTION="C++ library based on Qt that eases the creation of OpenGL 3D viewers"
+HOMEPAGE="http://www.libqglviewer.com"
+SRC_URI="http://www.libqglviewer.com/src/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="designer examples"
+
+DEPEND="virtual/opengl
+	dev-qt/qtgui:4"
+RDEPEND="${DEPEND}
+	designer? ( dev-qt/designer:4 )"
+
+src_configure() {
+	append-ldflags "-L${S}/QGLViewer"
+	sed -e 's#designerPlugin##' -i ${P}.pro || die
+	use examples || sed -e 's#examples examples/contribs##' -i ${P}.pro || die
+	eqmake4 ${P}.pro \
+		PREFIX="${EPREFIX}/usr" \
+		LIB_DIR="${EPREFIX}/usr/$(get_libdir)" \
+		DOC_DIR="${EPREFIX}/usr/share/doc/${PF}/html"
+	if use designer ; then
+		cd "${S}/designerPlugin"
+		eqmake4 designerPlugin.pro
+	fi
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+	dodoc README
+
+	if use designer ; then
+		cd "${S}/designerPlugin"
+		emake INSTALL_ROOT="${D}" install
+	fi
+
+	if use examples ; then
+		exeinto /usr/bin/${PN}-examples
+		doexe $(find "${S}/examples" -type f -executable ! -name '*.vcproj')
+	fi
+}