1 files changed, 88 insertions, 0 deletions
diff --git a/games-strategy/coldwar/coldwar-1.0.1-r1.ebuild b/games-strategy/coldwar/coldwar-1.0.1-r1.ebuild
new file mode 100644
index 000000000000..a1f7d02c3f0f
--- /dev/null
+++ b/games-strategy/coldwar/coldwar-1.0.1-r1.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/coldwar/coldwar-1.0.1-r1.ebuild,v 1.1 2014/06/25 17:25:45 mgorny Exp $
+
+EAPI=5
+
+inherit eutils unpacker cdrom versionator games
+
+PV_MAJOR=$(get_version_component_range 1-2)
+MY_P=${PN}-${PV_MAJOR}-${PV}
+
+DESCRIPTION="Third-person sneaker like Splinter Cell"
+HOMEPAGE="http://linuxgamepublishing.com/info.php?id=coldwar"
+SRC_URI="http://updatefiles.linuxgamepublishing.com/${PN}/${MY_P}-x86.run"
+
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="linguas_de linguas_fr linguas_ru"
+RESTRICT="mirror bindist strip"
+
+RDEPEND="
+	|| (
+		(
+			dev-libs/glib[abi_x86_32(-)]
+			media-libs/libogg[abi_x86_32(-)]
+			media-libs/libvorbis[abi_x86_32(-)]
+			media-libs/openal[abi_x86_32(-)]
+			media-libs/smpeg[abi_x86_32(-)]
+			virtual/opengl[abi_x86_32(-)]
+			x11-libs/libX11[abi_x86_32(-)]
+			x11-libs/libXext[abi_x86_32(-)]
+		)
+		amd64? (
+			(
+				app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
+				app-emulation/emul-linux-x86-opengl[-abi_x86_32(-)]
+				app-emulation/emul-linux-x86-sdl[-abi_x86_32(-)]
+				app-emulation/emul-linux-x86-soundlibs[-abi_x86_32(-)]
+				app-emulation/emul-linux-x86-xlibs[-abi_x86_32(-)]
+			)
+		)
+	)"
+DEPEND=""
+
+S=${WORKDIR}
+
+src_unpack() {
+	cdrom_get_cds bin/Linux/x86/${PN}
+	ln -sfn "${CDROM_ROOT}"/data cd
+	unpack "./cd/data.tar.gz"
+	use linguas_de && unpack "./cd/langpack_de.tar.gz"
+	use linguas_fr && unpack "./cd/langpack_fr.tar.gz"
+	use linguas_ru && unpack "./cd/langpack_ru.tar.gz"
+	rm -f cd
+
+	cp -rf "${CDROM_ROOT}"/bin/Linux/x86/* . || die "cp exes failed"
+	cp -f "${CDROM_ROOT}"/{READ*,icon*} . || die "cp READ* failed"
+
+	mkdir -p patch
+	cd patch
+	unpack_makeself ${MY_P}-x86.run
+	bin/Linux/x86/loki_patch patch.dat "${S}" || die "loki_patch failed"
+	cd "${S}"
+	rm -rf patch
+}
+
+src_install() {
+	dir=${GAMES_PREFIX_OPT}/${PN}
+
+	insinto "${dir}"
+	doins -r *
+
+	exeinto "${dir}"
+	doexe ${PN}
+
+	exeinto "${dir}"/bin
+	doexe bin/{launch*,meng}
+
+	exeinto "${dir}"/lib
+	doexe lib/lib*
+
+	games_make_wrapper ${PN} ./${PN} "${dir}"
+	newicon "${CDROM_ROOT}"/icon.xpm ${PN}.xpm
+	make_desktop_entry ${PN} "Cold War" ${PN}
+
+	prepgamesdirs
+}