1 files changed, 51 insertions, 0 deletions
diff --git a/dev-ruby/rb-inotify/rb-inotify-0.9.2.ebuild b/dev-ruby/rb-inotify/rb-inotify-0.9.2.ebuild
new file mode 100644
index 000000000000..59a0703a6494
--- /dev/null
+++ b/dev-ruby/rb-inotify/rb-inotify-0.9.2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rb-inotify/rb-inotify-0.9.2.ebuild,v 1.1 2013/09/13 18:38:23 mrueg Exp $
+
+EAPI=5
+
+USE_RUBY="ruby18 ruby19 jruby"
+
+RUBY_FAKEGEM_TASK_TEST=""
+
+RUBY_FAKEGEM_TASK_DOC="yard"
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="README.md"
+
+RUBY_FAKEGEM_EXTRAINSTALL="VERSION"
+
+RUBY_FAKEGEM_GEMSPEC="rb-inotify.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A thorough inotify wrapper for Ruby using FFI."
+HOMEPAGE="https://github.com/nex3/rb-inotify"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x64-macos"
+IUSE=""
+
+ruby_add_rdepend "virtual/ruby-ffi"
+
+ruby_add_bdepend "doc? ( dev-ruby/yard )"
+
+all_ruby_prepare() {
+	# Avoid unneeded dependency on jeweler.
+	sed -i -e '/:build/ s:^:#:' -e '/module Jeweler/,/^end/ s:^:#:' -e '/class Jeweler/,/^end/ s:^:#:' Rakefile || die
+
+	# Remove mandatory markup processor from yard options, bug 436112.
+	sed -i -e '/maruku/d' .yardopts || die
+}
+
+each_ruby_prepare() {
+	case ${RUBY} in
+		*jruby)
+			# jruby has a native implementation and should not list ffi
+			# in the gemspec.
+			sed -i -e '/ffi/d' rb-inotify.gemspec || die
+			;;
+		*)
+			;;
+	esac
+}