1 files changed, 48 insertions, 0 deletions
diff --git a/app-emacs/ess/ess-5.11.ebuild b/app-emacs/ess/ess-5.11.ebuild
new file mode 100644
index 000000000000..5dbc29ebc589
--- /dev/null
+++ b/app-emacs/ess/ess-5.11.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emacs/ess/ess-5.11.ebuild,v 1.1 2010/07/29 08:20:41 fauli Exp $
+
+EAPI=3
+
+inherit elisp
+
+DESCRIPTION="Emacs Speaks Statistics"
+HOMEPAGE="http://ess.r-project.org/"
+SRC_URI="http://ess.r-project.org/downloads/ess/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-macos"
+IUSE=""
+
+DEPEND="app-text/texi2html
+	virtual/latex-base"
+RDEPEND=""
+
+SITEFILE="50${PN}-gentoo.el"
+
+src_compile() {
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake PREFIX="${ED}/usr" \
+		INFODIR="${ED}/usr/share/info" \
+		LISPDIR="${ED}${SITELISP}/ess" \
+		DOCDIR="${ED}/usr/share/doc/${PF}" \
+		install || die "emake install failed"
+
+	elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
+
+	# Most documentation is installed by the package's build system
+	rm -f "${ED}${SITELISP}/ess/lisp/ChangeLog"
+	dodoc ChangeLog *NEWS doc/{TODO,ess-intro.pdf} || die "dodoc failed"
+	newdoc lisp/ChangeLog ChangeLog-lisp || die "newdoc failed"
+	prepalldocs
+}
+
+pkg_postinst() {
+	elisp-site-regen
+	elog "Please see /usr/share/doc/${PF} for the complete documentation."
+	elog "Usage hints are in ${SITELISP}/${PN}/ess-site.el ."
+}