Revision bump, with lots of fixes (see CL). Closes bug #207888.

(Portage version: 2.1.3.19)

1 files changed, 64 insertions, 0 deletions

diff --git a/x11-plugins/wmSpaceWeather/wmSpaceWeather-1.04_p19.ebuild b/x11-plugins/wmSpaceWeather/wmSpaceWeather-1.04_p19.ebuild
new file mode 100644
index 000000000000..19b4940b3bc8
--- /dev/null
+++ b/x11-plugins/wmSpaceWeather/wmSpaceWeather-1.04_p19.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-plugins/wmSpaceWeather/wmSpaceWeather-1.04_p19.ebuild,v 1.1 2008/02/01 14:00:22 s4t4n Exp $
+
+inherit eutils multilib toolchain-funcs
+
+MY_PN="wmspaceweather"
+MY_PV_ORIG="${PV/_p*}"
+MY_PV_PATCH="${PV/_p/-}"
+MY_P_ORIG="${MY_PN}_${MY_PV_ORIG}.orig"
+MY_P_PATCH="${MY_PN}_${MY_PV_PATCH}.diff"
+
+DESCRIPTION="dockapp showing weather at geosynchronous orbit."
+HOMEPAGE="http://packages.debian.org/sid/wmspaceweather"
+SRC_URI="mirror://debian/pool/main/w/${MY_PN}/${MY_P_ORIG}.tar.gz
+	    mirror://debian/pool/main/w/${MY_PN}/${MY_P_PATCH}.gz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~x86 ~amd64 ~mips ~hppa ~ppc ~sparc"
+IUSE=""
+
+CDEPEND="x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXpm"
+DEPEND="${CDEPEND}
+	x11-proto/xproto
+	x11-proto/xextproto"
+RDEPEND="${CDEPEND}
+	net-misc/curl
+	dev-lang/perl"
+
+S="${WORKDIR}/${MY_P_ORIG/_/-}/${PN}"
+
+src_unpack() {
+	unpack ${MY_P_ORIG}.tar.gz
+	epatch "${DISTDIR}"/${MY_P_PATCH}.gz
+
+	# need to apply patches from Debian first, do NOT change the order
+	cd "${S}"
+	mv ../debian/patches "${WORKDIR}"/patch
+	EPATCH_SUFFIX="dpatch" EPATCH_FORCE="yes" \
+		EPATCH_MULTI_MSG="Applying Debian patches ..." epatch
+	epatch "${FILESDIR}"/${P}-gentoo.patch
+	epatch "${FILESDIR}"/${P}-getkp.patch
+}
+
+src_compile() {
+	emake clean || die "make clean failed"
+	emake CC="$(tc-getCC)" LIBDIR="/usr/$(get_libdir)" || die "parallel make failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die install failed
+	dodoc ../{BUGS,CHANGES,HINTS,README}
+}
+
+pkg_postinst() {
+	elog "You need to emerge www-client/mozilla-firefox or www-client/mozilla-firefox-bin"
+	elog "to use the -url functionality - see man ${PN} for more info."
+	elog
+	elog "This version uses curl instead of wget. You may edit /usr/share/wmspaceweather/GetKp"
+	elog "if you don't like it."
+}