Bump to latest Linux-PAM version, use a newer Berkeley DB version, move to EAPI=1 and make sure dependencies are satisfied only by the correct slot of berkdb. Thanks to Michael Orlitzky in bug #287298.

(Portage version: 2.2_rc44/cvs/Linux x86_64)

3 files changed, 131 insertions, 6 deletions

diff --git a/sys-auth/pam_userdb/ChangeLog b/sys-auth/pam_userdb/ChangeLog
index 810f146f9d7e..77729ddb2639 100644
--- a/sys-auth/pam_userdb/ChangeLog
+++ b/sys-auth/pam_userdb/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for sys-auth/pam_userdb
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/pam_userdb/ChangeLog,v 1.17 2008/11/26 22:10:26 flameeyes Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/pam_userdb/ChangeLog,v 1.18 2009/10/07 19:59:55 flameeyes Exp $
+
+*pam_userdb-1.1.0 (07 Oct 2009)
+
+  07 Oct 2009; Diego E. Pettenò <flameeyes@gentoo.org>
+  pam_userdb-0.99.8.1.ebuild, +pam_userdb-1.1.0.ebuild:
+  Bump to latest Linux-PAM version, use a newer Berkeley DB version, move to
+  EAPI=1 and make sure dependencies are satisfied only by the correct slot
+  of berkdb. Thanks to Michael Orlitzky in bug #287298.
 
   26 Nov 2008; Diego E. Pettenò <flameeyes@gentoo.org>
   pam_userdb-0.99.8.1.ebuild:
diff --git a/sys-auth/pam_userdb/pam_userdb-0.99.8.1.ebuild b/sys-auth/pam_userdb/pam_userdb-0.99.8.1.ebuild
index dfaf0f67821a..f37197efd8c9 100644
--- a/sys-auth/pam_userdb/pam_userdb-0.99.8.1.ebuild
+++ b/sys-auth/pam_userdb/pam_userdb-0.99.8.1.ebuild
@@ -1,8 +1,10 @@
-# Copyright 1999-2008 Gentoo Foundation
+# Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/pam_userdb/pam_userdb-0.99.8.1.ebuild,v 1.5 2008/11/26 22:10:26 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/pam_userdb/pam_userdb-0.99.8.1.ebuild,v 1.6 2009/10/07 19:59:55 flameeyes Exp $
 
-inherit libtool multilib eutils pam toolchain-funcs flag-o-matic
+EAPI=1
+
+inherit libtool multilib eutils pam toolchain-funcs flag-o-matic versionator
 
 # BDB is internalized to get a non-threaded lib for pam_userdb.so to
 # be built with.  The runtime-only dependency on BDB suggests the user
@@ -28,7 +30,7 @@ RDEPEND="nls? ( virtual/libintl )
 DEPEND="${RDEPEND}
 	nls? ( sys-devel/gettext )"
 RDEPEND="${RDEPEND}
-	>=sys-libs/db-${BDB_VER}"
+	>=sys-libs/db-${BDB_VER}:$(get_version_component_range 1-2 ${BDB_VER})"
 
 S="${WORKDIR}/${MY_P}"
 
diff --git a/sys-auth/pam_userdb/pam_userdb-1.1.0.ebuild b/sys-auth/pam_userdb/pam_userdb-1.1.0.ebuild
new file mode 100644
index 000000000000..cf0b98a402a2
--- /dev/null
+++ b/sys-auth/pam_userdb/pam_userdb-1.1.0.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/pam_userdb/pam_userdb-1.1.0.ebuild,v 1.1 2009/10/07 19:59:55 flameeyes Exp $
+
+EAPI=1
+
+inherit libtool multilib eutils pam toolchain-funcs flag-o-matic versionator
+
+# BDB is internalized to get a non-threaded lib for pam_userdb.so to
+# be built with.  The runtime-only dependency on BDB suggests the user
+# will use the system-installed db_load to create pam_userdb databases.
+BDB_VER="4.6.21"
+
+MY_P="Linux-PAM-${PV}"
+
+HOMEPAGE="http://www.kernel.org/pub/linux/libs/pam/"
+DESCRIPTION="Linux-PAM pam_userdb (Berkeley DB) module"
+
+SRC_URI="mirror://kernel/linux/libs/pam/pre/library/${MY_P}.tar.bz2
+	http://downloads.sleepycat.com/db-${BDB_VER}.tar.gz"
+
+LICENSE="PAM"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="nls elibc_FreeBSD"
+
+RDEPEND="nls? ( virtual/libintl )
+	!<sys-libs/pam-0.99
+	>=sys-libs/pam-1.1.0"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )"
+RDEPEND="${RDEPEND}
+	>=sys-libs/db-${BDB_VER}:$(get_version_component_range 1-2 ${BDB_VER})"
+
+S="${WORKDIR}/${MY_P}"
+
+src_unpack() {
+	unpack ${A}
+
+	elibtoolize
+}
+
+src_compile() {
+	local myconf
+
+	if use hppa || use elibc_FreeBSD; then
+		myconf="${myconf} --disable-pie"
+	fi
+
+	local BDB_DIR="${WORKDIR}/db-${BDB_VER}"
+
+	# BDB is internalized to get a non-threaded lib for pam_userdb.so to
+	# be built with.  To demand-load a shared library which uses threads
+	# into an application which doesn't is a Very Bad Idea!
+	einfo "Building Berkley DB ${BDB_VER}..."
+	cd "${BDB_DIR}/build_unix" || die
+
+	CFLAGS="${CFLAGS} -fPIC" \
+		ECONF_SOURCE="../dist" \
+		econf \
+		--disable-compat185 \
+		--disable-cxx \
+		--disable-diagnostic \
+		--disable-dump185 \
+		--disable-java \
+		--disable-rpc \
+		--disable-tcl \
+		--disable-shared \
+		--disable-o_direct \
+		--with-pic \
+		--with-uniquename="_pam" \
+		--with-mutex="UNIX/fcntl" \
+		--prefix="${S}/modules/pam_userdb" \
+		--includedir="${S}/modules/pam_userdb" \
+		--libdir="${S}/modules/pam_userdb" || die "Bad BDB ./configure"
+
+	emake CC="$(tc-getCC)" || die "BDB build failed"
+	emake install || die
+
+	# We link against libdb_pam (*-dbpam.patch), else stupid libtool goes
+	# and relinks it during install to libdb in /usr/lib
+	cp -f "${S}"/modules/pam_userdb/libdb{,_pam}.a
+
+	# Make sure out static libs are used
+	append-flags -I"{S}/modules/pam_userdb"
+	append-ldflags -L"${S}/modules/pam_userdb"
+
+	cd "${S}"
+	econf \
+		$(use_enable nls) \
+		--enable-db \
+		--enable-securedir=/$(get_libdir)/security \
+		--enable-isadir=/$(get_libdir)/security \
+		--disable-dependency-tracking \
+		--disable-prelude \
+		--with-db-uniquename=_pam \
+		${myconf} || die "econf failed"
+
+	emake -C modules/pam_userdb || die "emake failed"
+}
+
+src_install() {
+	emake -C modules/pam_userdb DESTDIR="${D}" install || die "make install failed"
+
+	dodoc "${S}/modules/pam_userdb/README"
+
+	# No, we don't really need .la files for PAM modules.
+	rm -f "${D}/$(get_libdir)/security/"*.la
+}
+
+pkg_postinst() {
+	elog "Since ${CATEGORY}/${PN}-1.1.0 the internal Berkeley DB version"
+	elog "used is ${BDB_VER}; if you're updating from an older version"
+	elog "you will have to dump and re-load the user database."
+}